Yahooショッピング 注文APIの公開鍵認証を実装したい

Question

実現したいこと

Yahooショッピング 注文APIにて、「公開鍵で暗号化した認証情報をAPIリクエストヘッダに付加してリクエスト」をVB.NETにて実装

認証手順
１．公開鍵ファイルを作成
公開鍵の内容はYahooショッピング管理コンソールにて発行
内容をコピーし、public.keyというファイル名でファイル作成
＜公開鍵内容例＞
-----BEGIN PUBLIC KEY-----
ABCfMA0GCSqGSIb...6txJ/YUbwIDACBA
-----END PUBLIC KEY-----
２．認証情報の作成
ストアアカウントとunixtimestampを:で結合した情報を作成
３．認証情報を公開鍵で暗号化
認証情報を公開鍵で暗号化(PKCS1PADDING)し、BASE64エンコード
４．暗号化した認証情報をAPIリクエストヘッダに付加してリクエスト

前提

・認証情報がなくてもエラーとはならない。
・APIリクエスト・レスポンスは、認証なしでも問題なくできている。

発生している問題・エラーメッセージ

・下記のコードを実行した場合、
レスポンスヘッダー取得「X-SWS-Authorize-Status」にて、「unauthorized」のレスポンスが返る。
※成功すれば、「authorized」が返る

該当のソースコード

           ' UTF-8でエンコードする
            Dim enc As Encoding = New UTF8Encoding()

            'WebAPI暗号鍵処理
            'ストアクリエイターPro上で発行した公開鍵のパス
            Dim keyFilePath As String = String.Format("{0}/key/{1}", sCurrentDir, PUBLICKEYFILENM)

            '現在日時取得（unixtimestamp取得）
            Dim unixTime As Long = GetUnixTime(DateTime.Now)
　　　　⇒GetUnixTimeメソッドは最下部に記載

            '認証情報作成(ストアアカウントとunixtimestampを:で結合する)
            Dim authenticationValue As String = String.Format("{0}:{1}", STOREACCOUNT, unixTime)

            'pem形式の公開鍵読み込み
            '読み込むファイル
            Dim textFile As String = keyFilePath
            'テキストファイルの中身をすべて読み込む
            Dim publicKeyPem As String = System.IO.File.ReadAllText(textFile, enc)

            '不要部分を削除
            publicKeyPem = Replace(publicKeyPem, "-----BEGIN PUBLIC KEY-----" & vbCrLf, String.Empty)
            publicKeyPem = Replace(publicKeyPem, "-----END PUBLIC KEY-----", String.Empty)
            publicKeyPem = Replace(publicKeyPem, vbLf, String.Empty)

            '公開鍵と秘密鍵を取得
            Dim privateKey As String = publicKeyPem
            Dim publicKey As String = publicKeyPem
            CreateKeys(PublicKey, privateKey)
　　　　⇒CreateKeysメソッドは最下部に記載

            '認証情報の暗号化
            Dim encodedAuthenticationValue As String = Encrypt(authenticationValue, publicKey)
　　　　⇒Encryptメソッドは最下部に記載
            
            'POST送信する文字列を作成
            Dim postData As String = _
                GetRequestXMLData_OrderList(iGetOrderMaxCnt, sIsSeen, Format(Now.AddDays(-iOrderGetPeriod), "yyyyMMddHHmmss"), Format(Now, "yyyyMMddHHmmss"), "1,2", STOREACCOUNT)
　　　　⇒GetRequestXMLData_OrderListメソッドは今回の問題点とは関係ないため未記載

            'バイト型配列に変換
            Dim postDataBytes As Byte() = _
                System.Text.Encoding.UTF8.GetBytes(postData)

            'TLS1.2での通信対応
            ServicePointManager.SecurityProtocol = DirectCast(3072, SecurityProtocolType)

            'WebRequestの作成
            Dim req As System.Net.HttpWebRequest = _
                System.Net.HttpWebRequest.Create(YAHOOAPI_ORDERLISTURL)

            'アクセストークン取得
            sAccessToken = Get_AccessToken()
　　　　⇒Get_AccessTokenメソッドは今回の問題点とは関係ないため未記載
            
            'ヘッダ指定
            req.Headers.Add("Authorization: Bearer " & sAccessToken)
            req.Headers.Add("X-sws-signature: " & encodedAuthenticationValue) '暗号化した認証情報
            req.Headers.Add("X-sws-signature-version: 1") '取得した公開鍵のバージョン
            
            'メソッドにPOSTを指定
            req.Method = "POST"
            'ContentTypeを"application/x-www-form-urlencoded"にする
            req.ContentType = "application/x-www-form-urlencoded"

            'POST送信するデータの長さを指定
            req.ContentLength = postDataBytes.Length

            'データをPOST送信するためのStreamを取得
            Dim reqStream As System.IO.Stream = req.GetRequestStream()
            '送信するデータを書き込む
            reqStream.Write(postDataBytes, 0, postDataBytes.Length)
            reqStream.Close()

            'サーバーからの応答を受信するためのWebResponseを取得
            Dim res As System.Net.HttpWebResponse = req.GetResponse()
            'レスポンスヘッダー取得「X-SWS-Authorize-Status」
            For i As Integer = 0 To res.Headers.Count - 1
                If res.Headers.Keys(i) = "X-Sws-Authorize-Status" Then
                    If res.Headers(i) <> "authorized" Then
                        'エラー
                    End If
                    Exit For
                End If
            Next
            
            '応答データを受信するためのStreamを取得
            Dim resStream As System.IO.Stream = res.GetResponseStream()
            '受信して表示
            Dim sr As New System.IO.StreamReader(resStream, enc)
            Dim sInfo As String = sr.ReadToEnd()

            '閉じる
            sr.Close()

    ''' <summary>
    ''' UNIXTIMESTAMP取得
    ''' </summary>
    ''' <param name="targetTime"></param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Shared Function GetUnixTime(ByVal targetTime As DateTime) As Long
        ' UNIXエポックを表すDateTimeオブジェクトを取得
        Dim UNIX_EPOCH As DateTime = New DateTime(1970, 1, 1, 0, 0, 0, 0)

        ' UTC時間に変換
        targetTime = targetTime.ToUniversalTime()

        ' UNIXエポックからの経過時間を取得
        Dim elapsedTime As TimeSpan = targetTime - UNIX_EPOCH

        ' 経過秒数に変換
        Return CType(elapsedTime.TotalSeconds, Long)

    End Function

    ''' <summary>
    ''' 公開鍵と秘密鍵を作成して返す
    ''' </summary>
    ''' <param name="publicKey">作成された公開鍵(XML形式)</param>
    ''' <param name="privateKey">作成された秘密鍵(XML形式)</param>
    Public Shared Sub CreateKeys(ByRef publicKey As String, _
                                 ByRef privateKey As String)
        'RSACryptoServiceProviderオブジェクトの作成
        Dim rsa As New System.Security.Cryptography.RSACryptoServiceProvider()

        '公開鍵をXML形式で取得
        publicKey = rsa.ToXmlString(False)
        '秘密鍵をXML形式で取得
        privateKey = rsa.ToXmlString(True)
    End Sub

    ''' <summary>
    ''' 公開鍵を使って文字列を暗号化する
    ''' </summary>
    ''' <param name="str">暗号化する文字列</param>
    ''' <param name="publicKey">暗号化に使用する公開鍵(XML形式)</param>
    ''' <returns>暗号化された文字列</returns>
    Public Shared Function Encrypt(ByVal str As String, _
                                   ByVal publicKey As String) As String
        'RSACryptoServiceProviderオブジェクトの作成
        Dim rsa As New System.Security.Cryptography.RSACryptoServiceProvider()

        '公開鍵を指定
        rsa.FromXmlString(publicKey)

        '暗号化する文字列をバイト配列に
        Dim data As Byte() = System.Text.Encoding.UTF8.GetBytes(str)
        '暗号化する
        '（XP以降の場合のみ2項目にTrueを指定し、OAEPパディングを使用できる）
        Dim encryptedData As Byte() = rsa.Encrypt(data, False)

        'Base64で結果を文字列に変換
        Return System.Convert.ToBase64String(encryptedData)
    End Function

様々なサイトを参考にしましたが、手詰まり状態です。
お気づきの点等ありましたらご指摘・ご教授頂けるとありがたいです。
※VB.NETは”.Net Framework4.0”を使用

参考サイト

公開鍵暗号方法で暗号化する

Comments

[8524ba23]

参考にしたサイトを質問本文に追記ください。

Answer 1

コードをみる限り、公開鍵ファイルの内容が正しく利用されておらずランダムなキーで暗号化しているように思います。
RSA.ImportFromPemでPEM形式の文字列から読み込むと正しい鍵で暗号化できると思います。
以下、Chat-GPTが回答したC#でのサンプルコードです（動作未確認です）。

using System;
using System.Security.Cryptography;
using System.Text;

class Program
{
    static void Main()
    {
        // PEM形式の公開鍵を文字列から読み込む
        string publicKeyPem = @"-----BEGIN PUBLIC KEY-----
                                MIIBIjANBgkqhkiG9w0BAQEFAAOCAQ8AMIIBCgKCAQEA5e1RvIu42W23S3yJ/FNV
                                wQx7DZz7Lqyq1NifUj6z2tm4og3nYsz5fhrKXbTixum+Oj5pOzTdN2JwIhRNCNXG
                                CYS9ftH09s3pPEUJaxpEFw7KUg0mjBGM4UDgIQjElDQIjMzCmmlnkOYNfu3gz+51
                                0OD6A4L/OdfbnoFsFawL4Kh9NV65zUKhlgX5SBBpPS9EpS0gs5+kMfUv+a6yZpBQ
                                V3FlQ+IyY2K7x1sSi4AEJzKMGTU/JiGmZYnh8IT9fGRH6Ndn25ZxnOnv/bHyR+p2
                                hQHygIt4fL3lf9TibTQtUMgfnzFDr67O3SZnCBmc8Qz30JTtqxCbNAp7r1oDlS9Q
                                BQIDAQAB
                                -----END PUBLIC KEY-----";

        string inputText = "Hello, encryption!";

        using (RSA rsa = RSA.Create())
        {
            // PEM形式の公開鍵をインポート
            rsa.ImportFromPem(publicKeyPem);

            // 公開鍵を使用して文字列を暗号化
            byte[] encryptedBytes = rsa.Encrypt(Encoding.UTF8.GetBytes(inputText), RSAEncryptionPadding.Pkcs1);
            Console.WriteLine("Encrypted Text: " + Convert.ToBase64String(encryptedBytes));
        }
    }
}

また、Importing RSA public keys in downlevel .NET and .NET Framework versionsに古い.NETでの代替手段（コード）が示されています。
おおまかにPEM（テキスト）からDER（バイナリ）を作ってRSAPublicKeyというものでインポートするようですが、これが利用できるかもしれません。

Comments

[hal2023]

回答ありがとうございます。

VB.NET(.Net Framework4.0)では、
```
rsa.ImportFromPem
```
が使用できず、公開鍵のPEM形式のインポートができておりません。

プログラム言語 or .NetFrameworkの限界かと思っております。
環境の変更はできませんので、どのように対応しようか悩んでおります。

[8524ba23]

質問に代替手段について追記しました。
なお、すでに参考にされたサイトがあれば質問本文への追記願います。
後に同じような問題を解決したい人の役に立つかもしれないので。

[hal2023]

本件の問題点、参考サイト提示の教示ありがとうございます。
本件解決いたしましたので、感謝申し上げます。

Answer 2

本件、解決いたしました。
事例共有のため、以下に記載いたします。

BouncyCastleライブラリを使用することで実現いたしました。
外部より「BouncyCastle.Crypto.dll」をダウンロードし、インポートしています。

Imports Org.BouncyCastle.OpenSsl
Imports Org.BouncyCastle.Crypto
Imports Org.BouncyCastle.Crypto.Engines
Imports Org.BouncyCastle.Crypto.Encodings

        ' UTF-8でエンコードする
        Dim enc As Encoding = New UTF8Encoding()

        '暗号化処理 ------------------------------------------------------------------- start
        'WebAPI暗号鍵処理
        'ストアクリエイターPro上で発行した公開鍵のパス
        Dim keyFilePath As String = String.Format("{0}/key/{1}", sCurrentDir, PUBLICKEYFILENM)

        '現在日時取得（unixtimestamp取得）
        Dim unixTime As Long = GetUnixTime(DateTime.Now)

        '認証情報作成(ストアアカウントとunixtimestampを:で結合する)
        Dim authenticationValue As String = String.Format("{0}:{1}", STOREACCOUNT, unixTime)
        Dim authenticationByte As Byte() = System.Text.Encoding.UTF8.GetBytes(authenticationValue)

        'pem形式の公開鍵読み込み
        '読み込むファイル
        Dim textFile As String = keyFilePath
        'テキストファイルの中身を読み込む
        Dim publicKeyPem As StreamReader = New StreamReader(textFile, enc)

        'PEMフォーマットの公開鍵を読み込んで KeyParam を生成
        Dim publicKeyReader As New PemReader(publicKeyPem)
        Dim publicKeyParam As AsymmetricKeyParameter = publicKeyReader.ReadObject()

        'RSA暗号標準オブジェクト(PKCS#1)を生成
        Dim rsa As New Pkcs1Encoding(New RsaEngine())
        'RSA暗号オブジェクトを初期化（第１引数 true は「暗号化」を示す）
        rsa.Init(True, publicKeyParam)

        '対象のバイト列を渡し暗号化した結果のバイト列を受け取る
        Dim encrypted As Byte() = rsa.ProcessBlock(authenticationByte, 0, authenticationByte.Length)

        'Base64で結果を文字列に変換
        Dim encodedAuthenticationValue As String = System.Convert.ToBase64String(encrypted)
        '暗号化処理 ------------------------------------------------------------------- end

            'POST送信する文字列を作成
            Dim postData As String = _
                GetRequestXMLData_OrderInfo(sOrderId(0), STOREACCOUNT)

            'バイト型配列に変換
            Dim postDataBytes As Byte() = _
                System.Text.Encoding.ASCII.GetBytes(postData)

            'TLS1.2での通信対応
            ServicePointManager.SecurityProtocol = DirectCast(3072, SecurityProtocolType)

            'WebRequestの作成
            Dim req As System.Net.HttpWebRequest = _
                System.Net.HttpWebRequest.Create(YAHOOAPI_ORDERINFOURL)

            'ヘッダ指定
            req.Headers.Add("Authorization: Bearer " & sAccessToken)
            req.Headers.Add("X-sws-signature: " & encodedAuthenticationValue) '暗号化した認証情報
            req.Headers.Add("X-sws-signature-version: 1") '取得した公開鍵のバージョン

           ---------- 以下、質問内容と同じコードのため省略 -------------

参考サイト

https://qiita.com/snaka/items/0829c37494b61353445e

開発環境

VisualStudio2010
VB.NET

動作環境

.Net Framework4.0

開発、作業に関して

・Windowsフォームアプリケーションよりexeファイルを作成
・VisualStudio2010使用のため、ライブラリをNuGetできず、他Ver.VSにてDLしたdllファイルをインポート