VBAでPowerPointの文字配置（内部の余白）を変更する方法が知りたい

Question

###前提・実現したいこと
ExcelVBAで、PowerPointのスライドを操作しています。
（ExcelVBAでやっている理由は、Excelのデータを使う部分があるためです。）

PowerPointでは、文字配置の「内部の余白」は、
上下左右ともデフォルトが「0.03cm」になっています。
これを、指定した1つのオブジェクトに対し「0.05cm」の設定にしたいです。

（なお、オブジェクトの指定方法はわかっています。）

###試したこと
Webで検索しましたが、全く手がかりが見つかりませんでした。

手動でやると、文字配置の「内部の余白」の設定上で、
上下左右の全ての欄に「.05」を入力しなければなりません。
さらに、F4キーでの繰り返しを利用することができません。

どうぞよろしくお願いいたします。

Answer 1

既読かもしれませんが、以下のサイトが参考になりそうです。
⇒参考サイト

Sub pptEdit()
 
    Dim ppApp As New PowerPoint.Application
    ppApp.Visible = True
     
    Dim ppPrs As PowerPoint.Presentation
    Set ppPrs = ppApp.Presentations.Open(ThisWorkbook.Path & "\a.pptx")
     
    Dim ppSld As PowerPoint.Slide 'スライドオブジェクト
    Set ppSld = ppPrs.Slides(1) '1ページ目のスライドをセット
     
    Dim ppShp As PowerPoint.Shape
    Set ppShp = ppSld.Shapes(1)
    
    'テキストの操作
    ppShp.TextFrame.TextRange.Text = "abcdefghij"
    ppShp.TextFrame.TextRange.Characters(2, 3).Font.Size = 18
    '余白の設定
    ppShp.TextFrame.MarginLeft = 0.5
    ppShp.TextFrame.MarginRight = 0.5
    ppShp.TextFrame.MarginTop = 0.5
    ppShp.TextFrame.MarginBottom  = 0.5
    
    'ppApp.Quit
    'Set ppApp = Nothing
 
End Sub

Comments

[miyu21]

jawaさん、ご回答ありがとうございます。
返信が遅くなりまして、大変申し訳ありません。

試してみたのですが、「指定された値は境界を超えています」というエラーが出ました。
タイトルや普通のテキストボックスは変更できましたが、表は無理のようです。

いろいろ試し、TextRange.BoundLeft プロパティにたどり着きましたが、読み取り専用のため、値の取得しかできませんでした。
https://msdn.microsoft.com/ja-jp/library/office/ff939061.aspx

コードを書き込むことができず申し訳ありません。
他にも何かございましたら、どうぞよろしくお願いいたします。

[jawa]

表オブジェクトでしたか・・。
表オブジェクトとなると、表そのものに対する余白設定ではなく中のセルに対して余白設定する、ということになるのでしょうか。

以下のように表オブジェクト内の各セルに対しての設定することはできそうです。
```
Dim ppShp As PowerPoint.Shape
Set ppShp = ppSld.Shapes(2)

Dim ppTbl As PowerPoint.Table
Set ppTbl = ppShp.Table

Dim ppRow As PowerPoint.Row
Dim ppCell As PowerPoint.Cell

For Each ppRow In ppTbl
For Each ppCell In ppRow.Cells
ppCell.Shape.TextFrame2.MarginLeft = 0
ppCell.Shape.TextFrame2.MarginBottom = 0
Next ppCell
Next ppRow
```

表全体への一括設定ができればラクなのでしょうが、そんなプロパティが見当たらなかったので、面倒ですがループ処理としました(^-^;
お試しください。

[miyu21]

再度のご回答、ありがとうございます。
（表である旨を書き漏らしておりました。
本当に申し訳ありませんでした。）

jawaさんが教えてくださったコードを実行してみたのですが、
どうしてもひとつ目のFor Eachでエラーになってしまいました。
ですが、なんとかやりたかったことを実現することができました。
本当にありがとうございました。

（コメントだとマークダウンが使えないようですので、
自己解決のところにコードを記載します。）

Answer 2

jawaさんに教えていただいたコードを元に書きました。
コメントですとマークダウンが使えないため、こちらに書きます。

Dim ppApp As PowerPoint.Application
Dim ppSld As PowerPoint.Slide
Dim ppShp As PowerPoint.Shape
Dim i As Integer
Dim j As Integer

Set ppApp = CreateObject("PowerPoint.Application")
Set ppSld = ppApp.ActivePresentation.Slides(1)
Set ppShp = ppSld.Shapes(3)

With ppShp
  If .HasTable Then
    For i = 1 To .Table.Columns.Count
      For j = 1 To .Table.Rows.Count
        With .Table.Cell(j, i).Shape.TextFrame2
          .MarginLeft = 1.5
          .MarginRight = 1.5
          .MarginTop = 1.5
          .MarginBottom = 1.5
        End With
      Next j
    Next i
  Else
    MsgBox "表ではありません"
  End If
End With

Answer 3

ShapeオブジェクトのTextFrame2.MarginLeft、MarginRight、MarginTop、MarginBottomで変更できませんか？

Comments

[miyu21]

q1701さん、ご回答ありがとうございます。
返信が遅くなりまして、大変申し訳ありません。

jawaさんの返信の方にも書きました通り、うまくいきませんでした。
引き続き、何か情報がありましたら、どうぞよろしくお願いいたします。