VBA Applicationメソッドを特定のブックのみ作動させる方法教えてください！

Question

いま、エクセルのセル上の切り取りをさせないようにコードを貼り付けたのですが
他のブックを開いているときも同じように切り取りできなくなります。

特定のブックのみ切り取りできないようにするためには、
どうしたらいいですか？

参考コードはこちらになります。

よろしければ参考サイトも掲載願います。

Option Explicit
 
'**
' オープン
'**
Public Sub Auto_Open()
    ' コピペの制御
    Call CopyPasteCommandControl(False)
End Sub
'**
' クローズ
'**
Public Sub Auto_Close()
    ' コピペの制御
    Call CopyPasteCommandControl(True)
End Sub
'**
' コピー＆ペーストの制御
' 引数 true:利用可, false: 利用不可
'**
Public Sub CopyPasteCommandControl(Enabled As Boolean)
    Dim Cmd As Variant
    Dim CmdNames As Variant
    CmdNames = Array("Worksheet Menu Bar", "Cell", "Column", "Row")
    'ショートカット制御
    If Enabled = False Then
        Application.OnKey "^x", ""
    Else
        Application.OnKey "^x"
    End If
     
    'コマンドボタン制御
    For Each Cmd In CmdNames
        If Cmd = "Worksheet Menu Bar" Then
            With Application.CommandBars(Cmd).Controls(2)
                .Controls(5).Enabled = Enabled
            End With
        Else
            With Application.CommandBars(Cmd)
               .FindControl(, 21).Enabled = Enabled 'Cut
            End With
        End If
    Next Cmd
 End Sub

Answer 1

Auto_Open()、Auto_Close()は削除して、
ブックのアクティブ時、非アクティブ時で制御するようにすればどうでしょう。

ThisWorkbookモジュール

Private Sub Workbook_Activate()
    ' コピペの制御
    Call CopyPasteCommandControl(False)
End Sub

Private Sub Workbook_Deactivate()
    ' コピペの制御
    Call CopyPasteCommandControl(True)
End Sub

Comments

[AbcdPpap]

大変すばらしいアイデアで助かりました！
ブック間でうまく切り替えられました！！ありがとうございます！！