Excel VBA 複数のコントロール（テキストボックス）で同じ処理をする（同じ関数を呼び出す）

Question

Excel VBAで複数のコントロール（テキストボックス）で同じ処理（入力された値が日付かどうか判定し、違う場合は再入力を促す）をしています。
２点質問があります。
１．checkdate(textboxA)の「textboxA」の部分を「Me」などのように
どのテキストボックスでも同じ表記に変更することはできますでしょうか。
２．クラスという考え方があるそうですが、今回の場合、利用できますでしょうか。

Private Sub textboxA_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
    Cancel = checkdate(textboxA)
End Sub

Private Function checkdate(ByVal ctrl As MSForms.Control) As Boolean
    checkdate = False
    If ctrl Like "########" Then ctrl = Format(ctrl, "@@@@/@@/@@")
    If Not (IsDate(ctrl)) Then
        MsgBox "日付を入力してください。"
        checkdate = True
        Exit Function
    End If
    ctrl = CDate(ctrl)
End Function

Answer 1

BeforeUpdateイベントが発生するコントロールは必ずアクティブなはずですから、Me.ActiveControl でいいでしょう。

Private Sub textboxA_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
    Cancel = checkdate(Me.ActiveControl)
End Sub

---

BeforeUpdateイベントから呼び出すことに限定するなら下記のように記述してもいいでしょう。

Private Sub textboxA_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
    checkdate Cancel
End Sub

Private Sub checkdate(ByRef Cancel As MSForms.ReturnBoolean)
    Dim s As String
    s = Me.ActiveControl.Value
    If s Like "########" Then s = Format(s, "@@@@/@@/@@")
    If Not (IsDate(s)) Then
        MsgBox "日付を入力してください。"
        Cancel = True
        Exit Sub
    End If
    Me.ActiveControl.Value = Format(s, "yyyy/mm/dd")
End Sub

イベントの共通化について

クラスを利用してイベントを共通化する方法は有効です。
「VBA クラスモジュール イベントの共通化」あたりをキーワードに検索する多数の解説ページが見つかりますので、そこから分かり安そうなサイトを選らんで学習するといいでしょう。

補足

前の質問のExcel VBA テキストボックスに入力された値を日付型に変更するで補足しようと思っていたのですが、ここでしときます。

ユーザーフォームのテキストボックスの値はString型です。CDateで日付型に変換して設定してもString型になります。
確認用コード

    Me.TextBox1.Value = CDate("2021/11/10")
    MsgBox TypeName(Me.TextBox1.Value)

日付型をString型に自動で変換してくれるわけですが、そのとき、OSのコントロールパネルの日付書式設定に従いますので端末によっては異なる結果になる可能性があります。常に同じ結果にしたいなら、Format関数で書式設定するのがいいでしょう。

    Me.TextBox1.Value = Format("令和3年11月10日","yyyy/mm/dd")

Comments

[mnbwqz]

ご回答ありがとうございます。
教えていただきました通り、Me.ActiveControlに変更しました。

補足ありがとうございます。
現在うまく表示されているので、気づかない点でした。
>OSのコントロールパネルの日付書式設定に従いますので端末によっては異なる結果になる可能性があります。常に同じ結果にしたいなら、Format関数で書式設定するのがいいでしょう。