Excel VBA テキストボックスに入力された値を日付型に変更する

Question

Excel VBA でtextboxAに入力された値を日付型にしたいと思っています。
下記ではIsdate関数を２回使用していますが、
１回の使用で済む方法はないでしょうか。

20210109
2021/1/9
2021/01/09

の３つの値で日付型にできると良いです。
またtextboxA入力後にチェックしていますが、
日付でない値を入力した場合に、
フォーカスをtextboxAに戻すことができません。
こちらの方法も教えていただけると助かります。
よろしくお願いします。

Private Sub textboxA_AfterUpdate()    
    If Not (IsDate(textboxA)) Then
        If Len(textboxA) = 8 Then textboxA = Format(textboxA, "@@@@/@@/@@")
        If Not (IsDate(textboxA)) Then
            MsgBox "日付を入力してください。"
            textboxA.SetFocus
            Exit Sub
        End If
    End If
    textboxA = CDate(textboxA)
End Sub

Answer 1

例えば、

    Dim s As String
    s = Me.textboxA.Value
    If s Like "########" Then s = Format(s, "@@@@/@@/@@")
    If Not IsDate(s) Then
        MsgBox "日付を入力してください。"
        textboxA.SetFocus
        Exit Sub
    End If
    Me.textboxA.Value = CDate(s)

---

AfterUpdateでは SetFocus でフォーカスを戻せません。このイベントの後で次のフォーカスへ移動しますので。BeforeUpdate（またはExit）でイベント自体をキャンセルすること(Cancel = True)で、フォーカスが移動しなくなります。

Private Sub textboxA_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
    Dim s As String
    s = Me.textboxA.Value
    If s Like "########" Then s = Format(s, "@@@@/@@/@@")
    If Not IsDate(s) Then
        MsgBox "日付を入力してください。"
        Cancel = True
        Exit Sub
    End If
    textboxA = CDate(s)
End Sub

Comments

[mnbwqz]

ありがとうございます！
条件分岐の数が一つ減らせました。
AfterUpdate() イベントで処理を発生させる場合フォーカスが戻りません。
Change()イベントは一文字入力ごとにイベント発生するので
今回の場合使用できません。
対処方法はコード長くなりますでしょうか。

[jinoji]

TextBoxA_Exit(ByVal Cancel As MSForms.ReturnBoolean)でCancel = Trueにするとかどうですか？

[hatena19]

ExitイベントかBeforeUpdateイベントで Cancel＝Trueがいいでしょう。

[mnbwqz]

ありがとうございます。
Exitイベント・BeforeUpdateイベントいずれの場合も、
Exit Subの上の行にCancel = Trueを書くと、
フォーカスが次に移動しないようで、
BackSpaceキーでtextboxAの文字の消去はできます。
しかし、カーソルが点滅せずそのままでは文字が入力できず、
textboxAをクリックしないと入力できません。

→フォームを新しく作成し、コントロール類をコピー、コードもコピーしたところ、カーソルも表示されるようになりました。

[hatena19]

回答にコードを追記しましたので、参考にしてください。