ディレクトリ内の画像をファイルの制作日の順で並び変える方法

Question

ディレクトリ内に画像を複数保存し、一覧表示させるようにしています。
現在はファイル名でのソートを行い、数字が大きい方が上(デジカメのナンバリングで新しい写真が上に来るように)になるように設定しています。

opendir(DIR, "$dir$in{'vno'}");
my @files = sort { $b cmp $a } readdir(DIR);
while (my $pname = shift @files ) {

if (substr($pname,-4,4) eq ".jpg")  { # ディレクトリを抜いてjpgだけ出力

print<<"EOM";
<li><a href="./images/works/$in{'vno'}/$pname" class="fb" rel="g1"><IMG SRC="./images/works/$in{'vno'}/$pname" class="test"></a></li>
EOM
}
 }
closedir(DIR);

しかしこの方法だと、別のデジカメで撮影した時などファイル名がきちんと並んでいないと場合によっては撮影順になってくれません。
これを、撮影日(FTPでアップした日付?)でソートすることは可能でしょうか?
その場合どのように書き換えたらよいですか?

Answer 1

モジュールが使えるかどうか分かりませんので、標準関数だけでできるバージョンを書きます。

stat関数を使って、ファイルの属性を取得します。
この時、ファイル名とファイルの作成日時をセットにしたものをレコードにします。
ソート時は、これを使ってソートし、最後にファイル名だけに戻してあげます。

ちなみに、パソコンでファイルを日付順にする場合は、更新日にすることが多いです。
その場合は、$st[10]の代わりに$st[9]を使います。

# ディレクトリーを変数に
my $dir = "$dir$in{'vno'}";

opendir DIR, $dir;

# ファイル一覧の配列
my @tmp1 = readdir DIR;

# ファイル名とファイルの作成日時をレコード（リストの参照）にした配列
my @tmp2 =  map { my @st = stat "$dir/$_"; [ $_, $st[10] ] } @tmp1;

# 作成日の古い順にソート
my @tmp3 =  sort { $a->[1] <=> $b->[1] } @tmp2;

# ファイル名だけに戻す
my @files = map { $_->[0] } @tmp3;

あと、readdirとソートのところはループと分離して、ループはforeachを使って、
こんな感じにするともっと見やすくなると思いますよ。

my $dir = "$dir$in{'vno'}";

opendir DIR, $dir;
my @jpeg_files = grep { $_ =~ /.jpe?g$/i } readdir DIR;
closedir DIR;

my @sorted_files =
  map { $_->[0] }
  sort { $a->[1] <=> $b->[1] }
  map { my @st = stat "$dir/$_"; [ $_, $st[10] ] } @jpeg_files;

foreach my $pname (@sorted_files) {
  print <<"EOM";
  ...
EOM
}

Comments

[terataka]

ありがとうございます。
下の方法を採用して、無事希望通りになりました!
すごくシンプルになった分、私が内容をあまり理解できてないのが後々心配ですが…w