ユーザーフォーム自体をクラス化

Question

下記の記事を見て、同一ユーザーフォーム内のコントロールに共通するイベントをまとめるやり方を知りました。
https://excel-ubara.com/excelvba3/EXCELFORM023.html

現在、処理が似ているユーザーフォームが複数あります。

ただ微妙に処理が違うので、それぞれ別のユーザーフォームを作成しておりますが、何とか一つのクラスモジュールにできないか試行しております。

まずは複数のユーザーフォーム内で設定しているinitializeイベントのコードが重複していたので、ユーザーフォームそのものをクラス内でプロパティとして宣言し、initializeイベントを作ってみましたが、機能しません。

withEventで設定できないコントロールとして、exit,enterなどがありますが、msforms.userformもできないという理解でよろしいでしょうか？

下記のような感じで簡単に呼び出しています。

UserForm1は実際のユーザーフォームモジュールです。
(formClass.form.show ができなかったので、とりあえず、userForm1.showにしています。)

'formClassモジュール
Option Explicit
 
Private WithEvents pForm  As MSForms.UserForm

Public Property Set form(ByVal aForm As MSForms.UserForm)
    Set pForm = aForm
End Property

Private Sub pForm_Initialize()

MsgBox "あいうえお"
    
End Sub

'標準モジュール
Sub useClassUserForm()

Dim formClass As formClass

Set formClass = New formClass

Set formClass.form = UserForm1

UserForm1.Show

end sub

Answer 1

userform の Initialize も withEvent では参照できないようです。

1つ、考えられる方法は Class の Initialize を使う方法。

formClassモジュール

Option Explicit

Private WithEvents pForm  As MSForms.UserForm

Public Property Set form(ByVal aForm As MSForms.UserForm)
    Set pForm = aForm
End Property

Private Sub Class_Initialize()
    MsgBox "Class_Initialize"
End Sub

標準モジュール

Sub useClassUserForm()

   Dim formClass As formClass
   Set formClass = New formClass 'ここで Class_Initialize 発動
   Set formClass.form = UserForm1
   UserForm1.Show

end sub

ただし、上記のように Newした時点で呼び出されるので、Class_Initialize から UserForm1 にアクセスできません。

呼び出し時に、ユーザーフォームの設定も同時にしたいというような用途には使えません。

その場合は、疑似Initializeメソッドを作ってしまうという方法が考えられます。
この引数でユーザーフォームを渡して参照できるようにします。

formClassモジュール

Option Explicit

Private WithEvents pForm As MSForms.UserForm

'疑似Initialize
Public Sub Init(ByVal aForm As MSForms.UserForm)
    Set pForm = aForm
    
    MsgBox "疑似Initialize"
    pForm.Caption = "あいうえお" 'Captionを設定してみた

End Sub

Private Sub Class_Initialize()
    MsgBox "Class_Initialize"
End Sub

標準モジュール

Sub useClassUserForm()

    Dim formClass As New formClass
    formClass.Init UserForm1  'ここで 疑似Initialize 発動
    UserForm1.Show

End Sub

あるいは、ユーザーフォームのInitializeでクラスに登録するという方法でもいいでしょう。
私ならこちらの方法にします。

UserForm1モジュール

Private Sub UserForm_Initialize()

    Dim formClass As New formClass
    formClass.Init Me

End Sub

標準モジュールから呼び出すときは、Showするだけですみます。

Sub useClassUserForm()

    UserForm1.Show

End Sub

Comments

[Tetsuya3456]

色々な方法を提示して下さり、ありがとうございます。
自分でも一旦試してみます！

[Tetsuya3456]

このやり方でいけました。ありがとうございます！