[Excel VBA] 複数のCSVファイルを結合してデータを取り出すプログラム

Question

現在、Excel VBAで2つの外部のデータベース（今回はCSVファイルとします）を結合して、データを取得、Excelシート内に書き込みを行うプログラムを構築中です。

使用ファイル1：VBA_TEST.xlsm（ファイルパス：C:\Users\User\Desktop\VBA_TEST\VBA_TEST.xlsm）
使用ファイル2：名前.csv（ファイルパス：C:\Users\User\Desktop\VBA_TEST\Child\名前.csv）
使用ファイル3：職業マスター.csv（ファイルパス：C:\Users\User\Desktop\VBA_TEST\職業マスター.csv）

2つのCSVファイルが異なるフォルダーに保存されているため、SQLにて正しくデータベースを取得することができません。
もし、2つのCSVファイルが同じフォルダーの場合は以下のVBAコードで正しく結合することができました。
修正箇所をご教示していただければ幸いです。
よろしくお願い致します。

以下がVBAのコードです。

Option Explicit
Sub TestVBA()
Dim objCn As New ADODB.Connection
Dim objRS As ADODB.Recordset
Dim strSQL As String

Dim file_path As String
file_path = "C:\Users\User\Desktop\VBA_TEST\Child"

'コネクション
With objCn
.Provider = "Microsoft.ACE.OLEDB.12.0"
.Properties("Extended Properties") = "Text;HDR=Yes"
.Open file_path
End With

'SQL作成
strSQL = ""
strSQL = strSQL & " SELECT"
strSQL = strSQL & " L.ID, L.名前,"
strSQL = strSQL & " R.職業"
strSQL = strSQL & " FROM "
strSQL = strSQL & "名前.csv" & " L"
strSQL = strSQL & " LEFT OUTER JOIN "
strSQL = strSQL & "職業マスター.csv" & " R"
strSQL = strSQL & " ON"
strSQL = strSQL & " L.職業ID = R.ID"

'SQL実行
Set objRS = objCn.Execute(strSQL)

'レコードセットをシート出力
With ThisWorkbook.Sheets(1)
.Cells(1, 1).CopyFromRecordset objRS
End With
End Sub

以下がCSVファイルのデータセットです。

「名前.csv」

「職業マスター.csv」

Answer 1

IN句を利用するのが手っ取り早い気がします。
以下参考
ADOでの異なる種類のファイルへのSQL (FROM ... IN ... / INTO ... IN ...)

Comments

[S.Kasagawa]

回答ありがとうございます。
IN句を利用してコードを以下のように書き換えましたが、From句でエラーが起こりました。
IN句の書き方が間違っているのでしょうか。

*参考にした構文
set rs_text = cnn_xl.execute("SELECT * FROM [DATA.txt] IN 'C:\Temp\VBS\Ado\Data\' 'Text;'")

以下、修正したコードの一部を載せます。
-------------------------
' 修正したコードの一部の抜粋

Dim file_path As String
file_path = "C:\Users\User\Desktop\VBA_TEST"

'コネクション
With objCn
.Provider = "Microsoft.ACE.OLEDB.12.0"
.Properties("Extended Properties") = "Text;HDR=Yes"
.Open file_path
End With

'SQL作成
strSQL = ""
strSQL = strSQL & " SELECT"
strSQL = strSQL & " L.ID, L.名前,"
strSQL = strSQL & " R.職業"
strSQL = strSQL & " FROM "
strSQL = strSQL & "名前.csv" & " L"
strSQL = strSQL & " IN 'C:\Users\User\Desktop\VBA_TEST\Child\名前.csv' 'Test;'"
strSQL = strSQL & " LEFT OUTER JOIN"
strSQL = strSQL & " 職業マスター.csv" & " R"
strSQL = strSQL & " ON"
strSQL = strSQL & " L.職業ID = R.ID"
-------------------------

Answer 2

これで動きませんか？

Option Explicit
Sub TestVBA()
    Dim objCn As New ADODB.Connection
    Dim objRS As ADODB.Recordset
    Dim strSQL As String
    
    'コネクション
    With objCn
        .Provider = "Microsoft.ACE.OLEDB.12.0"
        .Properties("Extended Properties") = "EXCEL 12.0"
        .Open ThisWorkbook.FullName
    End With
    
    'SQL作成
    strSQL = "SELECT * FROM [TEXT;DATABASE=C:\Users\User\Desktop\VBA_TEST\Child].[名前.csv]"
'    strSQL = "SELECT * FROM [TEXT;DATABASE=C:\Users\User\Desktop\VBA_TEST].[職業マスター.csv]"
    
    'SQL実行
    Set objRS = objCn.Execute(strSQL)
    
    'レコードセットをシート出力
    With ThisWorkbook.Sheets(1)
        .Cells(1, 1).CopyFromRecordset objRS
    End With
End Sub

参考
EXCELでEXCELファイルおよびACCESSのデータに対してSQLを実行する方法