buwindowsバッチ サブルーチンから値を返却する

Question

windowsバッチで下記のbefore.csvからafter.csvのように変換をしたいと考えています。

「AFTER_XXXのCSVの一つ目の値とBEFORE_XXXの要素が一致している場合」
として汎用的に処理を書きたいと思っています。
下記のイメージで出来ると思ったのですが、
サブルーチンからうまく値を取得できません。
ご教授いただければ幸いです。
(AFTER_XXXはconfファイルへ外だしする予定の為、名称が変わった場合に改修を容易にしたいという背景です。)

rem test.bat

@echo off

setlocal enabledelayedexpansion

set BEFORE_CSV=before.csv
set AFTER_CSV=after.csv
set BEFORE_STRING_TOKYO=東京
set AFTER_STRING_TOKYO=東京,1,2
set BEFORE_STRING_OSAKA=大阪
set AFTER_STRING_OSAKA=大阪,10,20

if exist %AFTER_CSV% del %AFTER_CSV%

rem CSVから値を取得する
for /f "delims=," %%i in ("%AFTER_STRING_TOKYO%") do (
  set TOKYO=%%i
)
for /f "delims=," %%i in ("%AFTER_STRING_OSAKA%") do (
  set OSAKA=%%i
)

(
for /f "delims= eol=#" %%a in (%BEFORE_CSV%) do (
  set line=%%a
  for /f "delims=," %%b in ("%%a") do (
    if "%%b"=="%TOKYO%" (
      echo !line:%BEFORE_STRING_TOKYO%=%AFTER_STRING_TOKYO%!
    ) else if "%%b"=="%OSAKA%" (
      echo !line:%BEFORE_STRING_OSAKA%=%AFTER_STRING_OSAKA%!
    ) else (
      echo %%a
    )
  )
)
)>%AFTER_CSV%

rem csvの1項目目を取得する
:returnFirstColumn
setlocal

for /f "delims=," %%i in ("%1") do (
  set val=%%i
)
endlocal && set %2=!val!
exit /b

上記の処理でひとまず動くのですが、
下記のイメージでサブルーチン化したいと考えています。

rem test.bat

～中略～
call :returnFirstColumn %AFTER_TOKYO% TOKYO
call :returnFirstColumn %AFTER_OSAKA% OSAKA
～中略～
    if "%%b"=="%TOKYO%" (
～中略～
rem csvの1項目目を取得する
:returnFirstColumn
setlocal

for /f "delims=," %%i in ("%1") do (
  set val=%%i
)
endlocal && set %2=!val!
exit /b

#before.csv
東京,3,4
大阪,30,40

#after.csv
東京,1,2,3,4
大阪,10,20,30,40

Answer 1

1．まず、あちこちにある空白の欠如による文法エラーを直しましょう。

2．下記のように変数名の混乱があります。

set BEFORE_STRING_TOKYO=東京
set AFTER_STRING_TOKYO=東京,1,2
set BEFORE_STRING_OSAKA=大阪
set AFTER_STRING_OSAKA=大阪,10,20
～～～
call :returnFirstColumn %AFTER_TOKYO% TOKYO
call :returnFirstColumn %AFTER_OSAKA% OSAKA

これらを直してもまだ他に問題があるかも。

#コメントに対応した追記

@echo off
setlocal enabledelayedexpansion

set BEFORE_CSV=before.csv
set AFTER_CSV=after.csv
set BEFORE_STRING_TOKYO=東京
set AFTER_STRING_TOKYO=東京,1,2
set BEFORE_STRING_OSAKA=大阪
set AFTER_STRING_OSAKA=大阪,10,20

if exist %AFTER_CSV% del %AFTER_CSV%

rem CSVから値を取得する
call :returnFirstColumn "%AFTER_STRING_TOKYO%" TOKYO
call :returnFirstColumn "%AFTER_STRING_OSAKA%" OSAKA

(
for /f "delims= eol=#" %%a in (%BEFORE_CSV%) do (
  set line=%%a
  for /f "delims=," %%b in ("%%a") do (
    if "%%b"=="%TOKYO%" (
      echo !line:%BEFORE_STRING_TOKYO%=%AFTER_STRING_TOKYO%!
    ) else if "%%b"=="%OSAKA%" (
      echo !line:%BEFORE_STRING_OSAKA%=%AFTER_STRING_OSAKA%!
    ) else (
      echo %%a
    )
  )
)
)>%AFTER_CSV%
exit /b

rem csvの1項目目を取得する
:returnFirstColumn
for /f "delims=," %%i in (%1) do (
  set %2=%%i
)
exit /b

でしょうか。

引用符に囲まれたりエスケープされたりしていないカンマは、ほとんどの場所で区切り文字になるので、
1つの引数としてサブルーチンに引き渡したければ、
call :returnFirstColumn "%AFTER_STRING_TOKYO%" TOKYO
のように引用符で囲む必要があります。

Comments

[anko__]

ご丁寧にご確認ありがとうございます。
自分の方でひとまず動くように確認いたしました。

そのうえで処理を切り出して
サブルーチン化したいと考えておりますが、
構文が間違っており、うまく値を取得することが出来ません。

バッチ初心者の為、雑な質問になってしまい
申し訳ございませんが、お力添え頂けると幸いです。
よろしくお願い致します。

[otn]

サブルーチンの機能に何を求めているのか不明です。

[anko__]

サブルーチン＝メソッドだと認識してます。
そのため、処理の切り出しが出来ればと思ったのですが、Windowsバッチではそのような書き方は一般的でないということでしょうか？

[otn]

そういう意味の質問じゃなくて、具体的に何の機能をサブルーチンとして切り出したいのか？
ということです。

[anko__]

下記の処理で繰り返し記述している箇所になります。

rem CSVから値を取得する
for /f "delims=," %%i in ("%AFTER_STRING_TOKYO%") do (
set TOKYO=%%i
)
for /f "delims=," %%i in ("%AFTER_STRING_OSAKA%") do (
set OSAKA=%%i
)

下記のイメージで切り出せればと思っております。

call :returnFirstColumn %AFTER_TOKYO% TOKYO
call :returnFirstColumn %AFTER_OSAKA% OSAKA
～中略～
if "%%b"=="%TOKYO%" (
～中略～
rem csvの1項目目を取得する
:returnFirstColumn
setlocal

for /f "delims=," %%i in ("%1") do (
set val=%%i
)
endlocal && set %2=!val!
exit /b

[anko__]

ありがとうございます。
引用符や空白の有無によって、かなり動作が変わるということを知らず、
迷走していました。
とても助かりました。