skyboxのshaderをSkybox/Proceduralにして,Directional lightを回転させて昼夜を表現してるのですが夜の時skyboxが完全に真っ暗になるのですが青色にしたい

Question

skyboxのshaderをSkybox/ProceduralにしてDirectional lightを回転させて昼夜を表現してるのですが夜の時skyboxが完全に真っ暗になるのですが青色にしたいです誰か意見をくださるとありがたいです。

一応朝の時も載せておきます

こっちが本題の夜の時、空を黒じゃなくて青色にしたい

そのSkyboxのshaderの設定

[

Answer 1

Proceduralをカスタマイズして、空の光を上乗せしてやるのはどうでしょうか。
ダウンロードアーカイブからビルトインシェーダーをダウンロードして、「DefaultResourcesExtra」フォルダ内の「Skybox-Procedural.shader」を複製して別名を付けたものをプロジェクトにインポートし、下記のような変更を加えたところ...

// Unity built-in shader source. Copyright (c) 2016 Unity Technologies. MIT license (see license.txt)

// シェーダー名を変えて、元のProceduralと区別が付くようにする
Shader "Skybox/Procedural (Additional Skylight)" {
Properties {
    [KeywordEnum(None, Simple, High Quality)] _SunDisk ("Sun", Int) = 2
    _SunSize ("Sun Size", Range(0,1)) = 0.04
    _SunSizeConvergence("Sun Size Convergence", Range(1,10)) = 5

    _AtmosphereThickness ("Atmosphere Thickness", Range(0,5)) = 1.0
    _SkyTint ("Sky Tint", Color) = (.5, .5, .5, 1)
    _GroundColor ("Ground", Color) = (.369, .349, .341, 1)

    _Exposure("Exposure", Range(0, 8)) = 1.3

    // 上乗せする光を表すプロパティを追加する
    [Header(Additional Skylight)]
    [HDR] _Skylight ("Sky", Color) = (0.0, 0.25, 0.5, 1.0)
    [HDR] _Equatorlight ("Equator", Color) = (0.0, 0.0, 0.125, 1.0)
    [HDR] _Groundlight ("Ground", Color) = (0.0, 0.0, 0.0, 1.0)
}

SubShader {
    Tags { "Queue"="Background" "RenderType"="Background" "PreviewType"="Skybox" }
    Cull Off ZWrite Off

    Pass {

        CGPROGRAM
        
        // (ここにすごく長い光計算コードが続きますが、そこは全部読み飛ばしてfragの直前まで省略しました)

        // 追加したプロパティと対応するユニフォーム変数を追加し...
        half3 _Skylight;
        half3 _Equatorlight;
        half3 _Groundlight;

        half4 frag (v2f IN) : SV_Target
        {
            half3 col = half3(0.0, 0.0, 0.0);

        // if y > 1 [eyeRay.y < -SKY_GROUND_THRESHOLD] - ground
        // if y >= 0 and < 1 [eyeRay.y <= 0 and > -SKY_GROUND_THRESHOLD] - horizon
        // if y < 0 [eyeRay.y > 0] - sky
        #if SKYBOX_SUNDISK == SKYBOX_SUNDISK_HQ
            half3 ray = normalize(IN.vertex.xyz);
            half y = ray.y / SKY_GROUND_THRESHOLD;
        #elif SKYBOX_SUNDISK == SKYBOX_SUNDISK_SIMPLE
            half3 ray = IN.rayDir.xyz;
            half y = ray.y / SKY_GROUND_THRESHOLD;
        #else
            half y = IN.skyGroundFactor;
        #endif

            // if we did precalculate color in vprog: just do lerp between them
            col = lerp(IN.skyColor, IN.groundColor, saturate(y));

        #if SKYBOX_SUNDISK != SKYBOX_SUNDISK_NONE
            if(y < 0.0)
            {
                col += IN.sunColor * calcSunAttenuation(_WorldSpaceLightPos0.xyz, -ray);
            }
        #endif

            // この位置で光の上乗せを行う
            half h = y * SKY_GROUND_THRESHOLD;
            col += lerp(0.0, _Skylight, saturate(-h));
            col += lerp(0.0, _Equatorlight, saturate(1.0 - abs(h)));
            col += lerp(0.0, _Groundlight, saturate(h));

        #if defined(UNITY_COLORSPACE_GAMMA) && !SKYBOX_COLOR_IN_TARGET_COLOR_SPACE
            col = LINEAR_2_OUTPUT(col);
        #endif

            return half4(col,1.0);

        }
        ENDCG
    }
}


Fallback Off
CustomEditor "SkyboxProceduralShaderGUI"
}

下図のように、真夜中でも青っぽい雰囲気になりました。

夜中だけ上乗せを行う場合

先のコードで書き足した場所のうち、プロパティ宣言部は

    // 上乗せする色を表すプロパティを追加する
    [Header(Additional Skylight)]
    [HDR] _Skylight ("Sky", Color) = (0.0, 0.25, 0.5, 1.0)
    [HDR] _Equatorlight ("Equator", Color) = (0.0, 0.0, 0.125, 1.0)
    [HDR] _Groundlight ("Ground", Color) = (0.0, 0.0, 0.0, 1.0)
    [Toggle] _NighttimeOnly ("Nighttime Only", Float) = 1.0
    _TwilightAngle ("Twilight Angle", Range(-90.0, 90.0)) = -10.0
    _TwilightRange ("Twilight Range", Range(0.0, 180.0)) = 5.0

ユニフォーム変数宣言部は

        // 追加したプロパティと対応するユニフォーム変数を追加し...
        half3 _Skylight;
        half3 _Equatorlight;
        half3 _Groundlight;
        half _NighttimeOnly;
        half _TwilightAngle;
        half _TwilightRange;

上乗せ処理部は

            // この位置で色の上乗せを行う
            half h = y * SKY_GROUND_THRESHOLD;
            half3 additionalLight = lerp(0.0, _Skylight, saturate(-h)) + lerp(0.0, _Equatorlight, saturate(1.0 - abs(h))) + lerp(0.0, _Groundlight, saturate(h));
            half lightAngle = asin(clamp(_WorldSpaceLightPos0.y, -1.0, 1.0)) * 180.0 * UNITY_INV_PI;
            col += additionalLight * lerp(1.0, saturate((_TwilightAngle + _TwilightRange - lightAngle) * 0.5 / _TwilightRange), _NighttimeOnly);

という風に書き換えてみました。Directional Lightの角度をもとに昼夜を判断すればいいんじゃないかと思ったのですが、いかがでしょうか?

Comments

[hosituka]

回答ありがとうございます。　度重なる質問で申し訳ないのですが朝の色から夕焼け色そして青みたいな感じって出来ませんでしょうか自分で考えられず申し訳ございません

[Bongo]

修正案を考えてみました。「Nighttime Only」をオンにすると夜中だけ上乗せを行うようにしています。
「Twilight Angle」が昼夜の境界となる太陽の角度で、そこから上下に「Twilight Range」の幅でなめらかに切り替える方針で行きました。
デフォルト値はいいかげんに決めましたので、お好みの具合で夕焼け色が残るよう自由に調整してしまってください。

[hosituka]

出来ました、素晴らしい回答をありがとうございました。