ArduinoMegaでanalogReadが0しか返しません

Question

前提・実現したいこと

ArduinoMegaでVVVFインバーターを作って、電車のモーター音を再現しています。

発生している問題・エラーメッセージ

analogRead()がずっと0を返しています。

該当のソースコード

/*
	ピン配置
	U 46
	V 45
	W 44
	B.B 22
*/
#include <avr/pgmspace.h>
#include <avr/io.h>
#include <avr/interrupt.h>
#define plus +(1-Vout)*0.5
#define threePhaseMODE 1
#define tableLegth 256
#define Shift 4194304
#define opereator_type uint64_t
const byte MaxFrequency = 250;
volatile bool nutral_mode = false;
volatile bool phaseMode, Hitachi;
volatile byte macroMODE = 0;
volatile byte Type = 1;
/*
  0 オリジナルGTO「オクターブ」
  1 東洋IGBT		(京急2100形)
  2 日立IGBT		(ＪＲE531系)
  3 SiemensIGBT	(京急1000形)
  4 SiemensGTO	(京急1000形)
  5 三菱GTO		(ＪＲ209系)
  6 SiemensIGBT	(Desiro)
  7 日立GTO		(東急9000系)
  8 日立GTO		(西武6000系)
  9 東洋IGBT		(東京メトロ16000系)
  10日立IGBT		(ＪＲE231系1000番台)
  11東洋GTO		(京急600形)
  12オリジナルIGBT「オクターブ」
  13オリジナルIGBT「ランダム変調」
  14オリジナルGTO　「多変調」
  15オリジナルGTO「大きな木」
*/
boolean pulseMode, ModeBuffer;
volatile double Kfrq, KfrqT, Vout, Vout_To, Hz, HzS, hzss, Discom, HzTo;
volatile int pulse, PulseBuffer;
float stepper, StepBuffer;
int analog;
double Vout_U, Vout_V, Vout_W;
volatile uint16_t U, V, W, Top, Top2;
volatile int32_t SynU, SynV, SynW;
int RANDOMT;
bool H, SendTrigger;
const volatile uint8_t U_table[] PROGMEM = {/*sinU相*/};
const volatile uint8_t V_table[] PROGMEM = {/*sinV相*/};
const volatile uint8_t W_table[] PROGMEM = {/*sinW相*/};

const volatile bool sqU_table[] PROGMEM = {/*矩形U相*/};
const volatile bool sqV_table[] PROGMEM = {/*矩形V相*/};
const volatile bool sqW_table[] PROGMEM = {/*矩形W相*/}

const volatile uint8_t Mu_table[] PROGMEM = {/*広域3パルス比較波U相*/};
const volatile uint8_t Mv_table[] PROGMEM = {/*広域3パルス比較波V相*/};
const volatile uint8_t Mw_table[] PROGMEM = {/*広域3パルス比較波W相*/};
opereator_type sin_operator, SinBuffer;
opereator_type sin_operator_adder;
volatile char soundwave;

const byte XPulse_table_U[2][28][114] PROGMEM = {/*同期モードテーブルU相*/};
const byte XPulse_table_W[2][28][114] PROGMEM = {/*同期モードテーブルV相*/};
const byte XPulse_table_V[2][28][114] PROGMEM = {/*同期モードテーブルW相*/};

#define Ut pgm_read_byte_near(&sqU_table[(sin_operator/Shift)])
#define Vt pgm_read_byte_near(&sqV_table[(sin_operator/Shift)])
#define Wt pgm_read_byte_near(&sqW_table[(sin_operator/Shift)])
#define Mut pgm_read_byte_near(&Mu_table[(sin_operator/Shift)])
#define Mvt pgm_read_byte_near(&Mv_table[(sin_operator/Shift)])
#define Mwt pgm_read_byte_near(&Mw_table[(sin_operator/Shift)])

void setVout(uint8_t SoundType) {
  //省略
}
void setKfrq(uint8_t SoundType) {
  //省略
}
void setType() {
  Type += 1;
  Type = Type % 17;
}
void Sp_Up(void) {//周波数あげる
  macroMODE = 0;
  if (Vout < Vout_To) {
    Vout += 0.001;


    nutral_mode = true;
  } else {

    HzS = hzss;

    nutral_mode = false;
  }
}
void Sp_Dn(void) {//周波数下げ下げマン
  macroMODE = 1;
  if (Vout < Vout_To) {
    Vout += 0.001;

    nutral_mode = true;
  } else {
    if (Hz > 0) {
      HzS = hzss * -1;
    } else {
      HzS = 0;
    }
    nutral_mode = false;
  }
}
void SerialSendToMain(uint8_t SenderNum, uint8_t SendContent) {//デバッグ用
  if (!SendTrigger) {
    Serial.flush();
    Serial.write(SenderNum);
    SendTrigger = true;
  } else {
    if (Serial.available() >= 1) {
      if (Serial.read() == SenderNum) {
        Serial.write(SendContent);
        SendTrigger = false;
      }
    }
  }
}
//タイマ割り込み
ISR(TIMER2_COMPA_vect) {//SINオペレーター更新
  sin_operator +=  (opereator_type)(sin_operator_adder);
  sin_operator &= (tableLegth * Shift) - 1;
}
ISR(TIMER4_COMPA_vect) {//速度制御
  Hz += HzS * 10;
}
ISR(TIMER3_COMPA_vect) {//1パルス
  PORTL =  (Ut * 8) | (Vt * 16) | (Wt * 32);
}
ISR(TIMER5_CAPT_vect) {//マルチパルス
  sin_operator += (opereator_type)(sin_operator_adder);
  sin_operator &= (tableLegth * Shift) - 1;
  stepper = sin_operator / sin_operator_adder;
  if ((int)stepper % 2 == 0)sin_operator += (opereator_type)(sin_operator_adder);
  SynU = (Top * (((pgm_read_byte_near(&XPulse_table_U[Hitachi][(int)((pulse - 3) * 0.5)][(int)stepper]) * Vout) / 256)plus));
  SynV = (Top * (((pgm_read_byte_near(&XPulse_table_V[Hitachi][(int)((pulse - 3) * 0.5)][(int)stepper]) * Vout) / 256)plus));
  SynW = (Top * (((pgm_read_byte_near(&XPulse_table_W[Hitachi][(int)((pulse - 3) * 0.5)][(int)stepper]) * Vout) / 256)plus));

  OCR5A = (SynU < Top && SynU > 0) * SynU + (SynU > Top) * Top;
  OCR5B = (SynV < Top && SynV > 0) * SynV + (SynV > Top) * Top;
  OCR5C = (SynW < Top && SynW > 0) * SynW + (SynW > Top) * Top;
  TCCR5A = 0b10101000;
}
ISR(TIMER5_OVF_vect) {//マルチパルス
  sin_operator += (opereator_type)(sin_operator_adder);
  sin_operator &= (tableLegth * Shift) - 1;
  stepper = sin_operator / sin_operator_adder;
  if ((int)stepper % 2 == 1)sin_operator += (opereator_type)(sin_operator_adder);
  SynU = (Top * (((pgm_read_byte_near(&XPulse_table_U[Hitachi][(int)((pulse - 3) * 0.5)][(int)stepper]) * Vout) / 256)plus));
  SynV = (Top * (((pgm_read_byte_near(&XPulse_table_V[Hitachi][(int)((pulse - 3) * 0.5)][(int)stepper]) * Vout) / 256)plus));
  SynW = (Top * (((pgm_read_byte_near(&XPulse_table_W[Hitachi][(int)((pulse - 3) * 0.5)][(int)stepper]) * Vout) / 256)plus));

  OCR5A = (SynU < Top && SynU > 0) * SynU + (SynU > Top) * Top;
  OCR5B = (SynV < Top && SynV > 0) * SynV + (SynV > Top) * Top;
  OCR5C = (SynW < Top && SynW > 0) * SynW + (SynW > Top) * Top;
  TCCR5A = 0b10101010;
}
ISR(TIMER5_COMPA_vect) { //TOP値更新
  Top = (uint16_t)(1000000 / Kfrq);
  ICR5 = Top;
  if (soundwave < 1) {
    soundwave++;
  } else {
    soundwave = -1;
  }
}
int main() {
  cli();
  Hz = 0;
  HzS = 0;
  pinMode (12, INPUT);
  pinMode (13, INPUT);
  pinMode (22, OUTPUT);
  pinMode (44, OUTPUT);
  pinMode (45, OUTPUT);
  pinMode (46, OUTPUT);
  attachInterrupt(4, setType, FALLING);
  analogReference(DEFAULT);
  TCCR4A = 0b00000011;
  TCCR4B = 0b00011001;
  TIMSK4 = 0b00000010;
  sei();
  bool SETUP = true;
  Serial.begin(9600);
  while (true) {//LOOP


    if (Vout > 0 && Hz > 0 && Kfrq > 0) { //波形出力あり
      if (pulseMode) {
        if (pulse == 1) {//1パルスモード
          TIMSK5 = 0;
          TCCR5A = 0;
          TCCR5B = 0;
          if (Vout >= 0.01) {
            TCCR3A = 0b00000011;
            TCCR3B = 0b00011001;
            OCR3A = 350;
            TIMSK3 = 0b00000010;
            digitalWrite(22, HIGH);
          } else {
            TIMSK3 = 0;
            digitalWrite(22, LOW);
          }
          TCCR2A = 0b10000010;
          TCCR2B = 0b00000010;
          OCR2A = (1000000 / 10000) - 1;
          TIMSK2 = 0b00010010;
          sin_operator_adder = (opereator_type)((tableLegth * Shift) * Hz / 20000);
          Top = (uint16_t)(1000000 / Kfrq);
        } else {//マルチパルスモード
          digitalWrite(22, HIGH);
          TIMSK5 = 0b00100011;//同期モード用割り込み
          TCCR5B = 0b00010010;//メインタイマ指定
          TIMSK3 = 0;//1パルスモードなし
          TIMSK2 = 0;//SINオペーレーター通常更新なし
          Kfrq = Hz * pulse;
          Top = (uint16_t)(1000000 / Kfrq);
          sin_operator_adder = (tableLegth * Shift) / (pulse * 2);
        }
      } else {//非同期モード
        TIMSK3 = 0;
        TCCR2A = 0b10000010;
        TCCR2B = 0b00000010;
        OCR2A = (1000000 / 10000) - 1;
        TIMSK2 = 0b00010010;
        sin_operator_adder = (opereator_type)((tableLegth * Shift) * Hz / 20000);
        TCCR5A = 0b10101010;
        TCCR5B = 0b00010010;
        TIMSK5 = 0b00000010;
        OCR5A = (uint16_t)(Top * (((pgm_read_byte_near(&U_table[(sin_operator / Shift)]) * Vout) / 255)plus));
        OCR5B = (uint16_t)(Top * (((pgm_read_byte_near(&V_table[(sin_operator / Shift)]) * Vout) / 255)plus));
        OCR5C = (uint16_t)(Top * (((pgm_read_byte_near(&W_table[(sin_operator / Shift)]) * Vout) / 255)plus));
        digitalWrite(22, HIGH);
      }
    } else { //波形出力なし
      digitalWrite(22, LOW);
      TIMSK3 = 0;
      TCCR5A = 0;
      TCCR5B = 0;
    }
    TCCR4A = 0b00000011;
    TCCR4B = 0b00011001;
    TIMSK4 = 0b00000010;
    OCR4A = (8000000 / 1000) - 1;//速度制御
    analog = analogRead(A0);
    //analog = 1023;
    HzTo = analog / 4;
    Serial.println(analogRead(A0), DEC);//デバッグ
    if (round(Hz) == round(HzTo)) {

    } else {
      if (HzTo > Hz) {
        Sp_Up();
      } else {
        Sp_Dn();
      }
    }
    if (SETUP) {
      if (Hz > -1) {
        Hz -= 0.1;
      } else {
        SETUP = false;
      }
    }

    /*if (digitalRead(13))Sp_Up();
      if (digitalRead(12))Sp_Dn();
      if (digitalRead(13) && digitalRead(12)) {
    	HzS = 0;
    	macroMODE = 0;
      }*/


      SerialSendToMain(1,round(Hz));
    RANDOMT = (int)random(-50, 50);
    setKfrq(Type);
    setVout(Type);
  }
  return 0;
}

試したこと

新たにanalogRead()を読み取るだけのプログラムを作り、試したら正常に動作したため、ピンが壊れているということはなさそうです。また、ピンを変えても結果は同じで、ずっと0を返します。

補足

特殊なPWMを出すため、TIMER2,TIMER3,TIMER4,TIMER5のレジスタを編集しています。
波形テーブルの宣言と、モーター音指定プログラムは省略しています。

Comments

[thkana]

setup()/loop()もなくてmain()がある、これ本当にArduinoのプログラムですか?
AVRのCプログラムとしてもコンパイル通らないし...(変数の未定義等ぽろぽろと)
これを見せてどうしろとおっしゃるのでしょう。

[thkana]

おっと、Arduino IDEもmain()を通すのか。まぁ、いずれにしろコンパイルは通らない。

[VVVF_IR]

波形生成テーブルがあまりにも長すぎるため定義を省略しています。つまり宣言されていません。
波形テーブルの宣言の部分のみを追加しました。テーブルの中身は省略しているためコンパイルは通らないと思います。(テーブルの中身も書くと、文字数制限に引っかかるのです…)

[thkana]

動くはずのない、つまりプログラムたり得ないものからデバッグをしろ、と回答者にリクエストしているということですか?

[thkana]

質問するときのヒント( https://teratail.com/help/question-tips#questionTips3-5-1 )に
「最も良いのは、現象を再現するためのミニマムなプログラムを改めて作ることです。」とあります。現象が再現するのですから当然動くプログラムということですが。
これを実行するつもりはありませんか?

[VVVF_IR]

こちらのファイルなら正常にコンパイルできるはずです。わざわざダウンロードさせてしまって申し訳ありません…。
https://drive.google.com/drive/folders/1XE7HGNnix-GVbXoA2g6t6yjVFGFpjxYF?usp=sharing

Answer 1

こちらの手元で「現象を再現するためのミニマムなプログラム」にまで絞り込んでみたところ、こうなりました。

int main() {
  analogReference(DEFAULT);
  Serial.begin(9600);
  while (true) {//LOOP
    Serial.println(analogRead(A0), DEC);//デバッグ
  }
  return 0;
}

まぁどう見ても「analogRead()を読み取るだけのプログラム」ですが、なぜあなたの手元では動いたのにこちらでは動かないのでしょう。もしかして、setup()-loop()のArduino式プログラムで「動いた」と言っていたのでしょうか。そうだとすると、ArduinoIDE内でC++に展開する時に付け加えられる
init();
が効いているのでは...という予想がたちます。では、

int main() {
  init(); //追加
  analogReference(DEFAULT);
  Serial.begin(9600);
  while (true) {//LOOP
    Serial.println(analogRead(A0), DEC);//デバッグ
  }
  return 0;
}

としてみましょう。はい動きました。他にも初期化が行われていないペリフェラルがあるのかも知れませんが、私の知るところではありません。
逆に、init()を使いたくないというのなら、init()の中を覗いてADCの初期化っぽいところを取り込んでみるとこんなところでしょうか。

//マクロ追加
#ifndef sbi
#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit))
#endif

int main() {
  //追加
  sbi(ADCSRA, ADPS2);
  sbi(ADCSRA, ADPS1);
  sbi(ADCSRA, ADPS0);
  sbi(ADCSRA, ADEN);
  //ここまで
  analogReference(DEFAULT);
  Serial.begin(9600);
  while (true) {//LOOP
    Serial.println(analogRead(A0), DEC);//デバッグ
  }
  return 0;
}

Comments

[VVVF_IR]

おお!直りました!!
なるほど、初期化が抜けていたんですね。軽量化のためにmain()を使ったのですが、そんな落とし穴があったんですね。
ありがとうございました!!助かりました!!

[thkana]

> 軽量化のためにmain()を使った
フルのプログラムをコンパイルしたときのメモリの使用量とかみてませんでしたけど、逼迫してましたか?
mainにしたときにどれだけの「軽量化」が期待できるかというとかなり限定的だと思うのですが。

[VVVF_IR]

loop()はわざわざmain()からコールされているのでその分処理速度が遅いのです。僕はなるべく高速な処理を実現したかったため、main()を使いました。(まあ確かにかなり限定的かもしれませんが…)

[thkana]

> その分処理速度が遅い
定量的に「どれだけ遅い」のでしょうか。それがプログラムの動作に影響するのですか。
(もちろん影響する場合もあるでしょうが...)
loop()の関数コールを気にするのに、digitalWriteのオーバーヘッドは許容できるのですか?

[VVVF_IR]

プログラム書いてる途中からわざわざデータシート見るのが面倒になってきて、digitalWriteを使いました。(圧倒的ダメ人間)
使ってみたところ、特に動作には影響はありませんでした。そのため、そのまま残しています。
そのときmain()をloopに戻しても良かったのでしょうが、その必要性は感じなかったため、戻しませんでした。

Answer 2

9 東洋IGBT (東京メトロ16000系)

10日立IGBT (ＪＲE231系1000番台)
opereator_type sin_operator, SinBuffer;
opereator_type sin_operator_adder;
volatile char soundwave;

ここんところ、コメントの閉じ記号がないため、以降のコードがコメントアウトされてしまってますが、
実際はどーなってるでしょうか

Comments

[VVVF_IR]

すみません、省略するときに消してしましました。いま修正します。