VBA:グラフの横軸ラベルの設定について

Question

問題とやりたいこと

・横軸のラベルがインデックス表示になってしまいます。本来は、1列目を横軸として設定したいです。
下図の「BEFORE」が今回出力されるもので、本来は「AFFTER」のように横軸ラベル1列目を指定したいです。

やってみたこと

ネットでいろいろ調べてもこのトラブルは一切紹介されておらず、いずれのサイト様も、「何の設定もなくグラフ表示とともに
AFFTERの状態」でした。わたしの環境がおかしいのでしょうか。。
以上、お忙しいところ恐れ入りますが、ご教示のほどお願い致します。

###CODE
以下のコードは、worksheets("Sheet1")が存在するxlsmファイルにコピペ実行で再現可能です。

Sub create_table()

     Dim r As Long
     Dim c As Long
     Dim i As Long
     Dim ii As Long
     Dim iii As Long
     Dim fields As Variant
    
    '表作成
     fields = Array("年度", "売上高", 2017, 93979736, 2018, 90201580, 2019, 85474370, 2020, 71076570, 2021, 10782320)
     r = 6
     c = 2
     With ThisWorkbook.Worksheets("Sheet1")
        For ii = 1 To r
            For i = 1 To c
                .Cells(ii, i).Value = fields(iii)
            iii = iii + 1
            Next i
        Next ii
     
     End With
　　'ここからグラフ作成
    Call make_chart

End Sub

Sub make_chart()
     Dim Po As Range
     
     Set Po = ActiveSheet.Cells(8, 2)
     
     With ActiveSheet.Shapes.AddChart.Chart
         .ChartType = xlLine
         .SetSourceData Range(ActiveSheet.Cells(1, 1), ActiveSheet.Cells(6, 2))
         .FullSeriesCollection(1).Delete
         .Axes(xlCategory, xlPrimary).HasTitle = True
         .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "年度"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "金額"
        .HasTitle = True
        .ChartTitle.Text = "年度別売上推移"
        .Parent.Top = Po.Top
        .Parent.Left = Po.Left
        
    End With

End Sub

Answer 1

.FullSeriesCollection(1).Delete をコメントアウトしてみてください
A列の値のグラフが横軸近くに出現すると思います。

VBAは疎いのでこれを消している理由はわかりませんが、結果的には不要と思われます。

原因としてはA列が.FullSeriesCollection(1).Deleteが消されていたことと（<-追記 原因追加）、
A列が日付ではなく数値として認識されていたので、項目軸ラベルとして認識されなかったようです。
下記のやり方がうまいやり方なのかわかりませんが、日付として入力することで想定通りの結果がえられると思います。
A1セルは変換の必要がないのでifを使って A2列以下のA列という条件で、4桁の数値を日付に変換しています。

Sub create_table()

     Dim r As Long
     Dim c As Long
     Dim i As Long
     Dim ii As Long
     Dim iii As Long
     Dim fields As Variant

    '表作成
     fields = Array("年度", "売上高", 2017, 93979736, 2018, 90201580, 2019, 85474370, 2020, 71076570, 2021, 10782320)
     r = 6
     c = 2
     With ThisWorkbook.Worksheets("Sheet1")
        For ii = 1 To r
            For i = 1 To c
                If i = 1 And ii > 1 Then
                    .Cells(ii, i).NumberFormatLocal = "yyyy"
                    .Cells(ii, i) = Format(Str(fields(iii)) + "/" + "01" + "/" + "01", "yyyy/mm/dd")
                Else
                    .Cells(ii, i).Value = fields(iii)
                End If
                
                
            iii = iii + 1
            Next i
        Next ii

     End With
    'ここからグラフ作成
    Call make_chart

End Sub

こちらは .FullSeriesCollection(1).Delete をコメントアウトしただけです。

Sub make_chart()
     Dim Po As Range

     Set Po = ActiveSheet.Cells(10, 4)

     With ActiveSheet.Shapes.AddChart.Chart
     
        .ChartType = xlLine
         .SetSourceData Range(ActiveSheet.Cells(1, 1), ActiveSheet.Cells(6, 2))
         '.FullSeriesCollection(1).Delete
         .Axes(xlCategory, xlPrimary).HasTitle = True
         .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "年度"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "金額"
        .HasTitle = True
        .ChartTitle.Text = "年度別売上推移"
        .Parent.Top = Po.Top
        .Parent.Left = Po.Left
        

    End With

End Sub

結果こうなりました（追記 図追加）

Comments

[masafumi55]

とても丁寧なご回答誠にありがとうございます。返信がおそくなり申し訳ありません。

　グラフ作成ははじめてだったので、わたしのコードにわたし自身理解が追い付いていないので、一つ目の原因である「.FullSeriesCollection(1).Delete」をいれてしまったことについては、わたし自身謎でした。今回の丁寧なご説明の中で理解を深めることができ感謝いたします。
(某サイト様参照させていただきました。https://mamemametochan.com/excel-41/)

　もう一方の原因であった、1列の型の問題についても大変勉強になりました。まったく予想外の原因だったのでこれは生涯わからなかったでしょう。コードの修正もお手数おかけいたしました。

以上、問題を解決していただき大変恐縮です。誠に誠にありがとうございました！