VBAの二次元配列のコード ワークシートの内容を二次元配列に格納

Question

二次元配列にワークシートの内容を格納する方法

ここに質問の内容を詳しく書いてください。
まずDim 変数名(最大インデックス番号) As 型となるところで、変数が（２，２）から始まるため、（）内がわかりません。

発生している問題・エラーメッセージ

エラーメッセージ
```インデックスが有効な範囲にありません

### 該当のソースコード![イメージ説明](856264f35e6b9effaca5d2b72fd8c9de.png)

```ここに言語名を入力VBA
ソースコード

試したこと

ここに問題に対して試したことを記載してください。>
（）内を1 To 5としてみたが上記のエラーメッセージが表示された

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。これが課題の全容です。

Comments

[hatena19]

ソースコードは画像ではなく、コピーして貼り付けてください。
また、貼り付けたコードは選択してからメニューの <code> ボタンを押してコードブロックに入れてください。

Answer 1

Sub sample()

    Dim score(1 To 5, 1 To 3)
    Dim avgAry(1 To 5)
    Dim sdAry(1 To 5)
    Dim minAry(1 To 5)
    Dim maxAry(1 To 5)
    
    Dim i, j
    For i = 1 To 5
    For j = 1 To 3
        score(i, j) = Cells(i + 1, j + 1).Value
    Next j, i
    
    For i = 1 To 5
        Dim sm, mn, mx, sd
        sm = 0
        mn = 100
        mx = 0
        sd = 0
        
        For j = 1 To 3
            sm = sm + score(i, j)
            If score(i, j) < mn Then mn = score(i, j)
            If score(i, j) > mx Then mx = score(i, j)
        Next
        
        avgAry(i) = sm / 3
        minAry(i) = mn
        maxAry(i) = mx
        
        For j = 1 To 3
            sd = sd + (score(i, j) - avgAry(i)) ^ 2
        Next
        sdAry(i) = Sqr(sd / 3)
    Next
End Sub

Sub sample2()
    Dim arr As Variant
    arr = Range("B2:D6").Value
    
    Dim avgAry(1 To 5)
    Dim sdAry(1 To 5)
    Dim minAry(1 To 5)
    Dim maxAry(1 To 5)
    
    With WorksheetFunction
        Dim i
        For i = 1 To 5
            avgAry(i) = .Average(.Index(arr, i, 0))
            sdAry(i)  = .StDev_P(.Index(arr, i, 0))
            minAry(i) = .Min(.Index(arr, i, 0))
            maxAry(i) = .Max(.Index(arr, i, 0))
        Next
    End With
End Sub