シェーダーによる動画の透過処理で全体的に暗くなってしまう。

前提・実現したいこと

http://patio.work/archives/1208
上の記事を参照にして動画を透過処理したいです。
しかし、透過処理には成功するのですが、動画が下の画像のように暗くなってしまいます。

↓元動画

※画像ではあえて透過していません。ちなみに緑の部分を透過しています。

該当のソースコード

シェーダーのコードです。

Shader "Onoty3D/ChromaKey" {
    Properties{
        _KeyColor("Key Color", Color) = (0,1,0)
        _Near("Near", Range(0, 2)) = 0.2
        _MainTex("Base (RGB) Trans (A)", 2D) = "white" {}
    }

        SubShader{
            Tags{ "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }
            LOD 200

            CGPROGRAM
                #pragma surface surf Lambert alpha

                sampler2D _MainTex;
                fixed3 _KeyColor;
                fixed _Near;

                struct Input {
                    float2 uv_MainTex;
                };

                void surf(Input IN, inout SurfaceOutput o) {
                    fixed4 c = tex2D(_MainTex, IN.uv_MainTex);
                    clip(distance(_KeyColor, c) - _Near);
                    o.Albedo = c.rgb;
                    o.Alpha = c.a;
                }
            ENDCG
    }

        Fallback "Transparent/Diffuse"
}

行動規範の内容に同意します

回答1件

ベストアンサー

もしかして2Dゲーム向けのプロジェクトでしょうかね?
ご提示のシェーダーコードはランバートライティングを施すようになっている様子ですが、2D用プロジェクトだとデフォルトではシーン内にライトが設置されないはずです。そのため環境光だけで照らされた状態になり、薄暗くなってしまったのかもしれません。そういった心当たりはありますでしょうか?

もしライティングが不要であれば、下記のようにUnlitシェーダーのテンプレートをベースにした形にしてしまってはいかがでしょう。

ShaderLab
1Shader "Onoty3D/ChromaKey (Unlit)" {
2    Properties{
3        _KeyColor("Key Color", Color) = (0,1,0)
4        _Near("Near", Range(0, 2)) = 0.2
5        _MainTex("Base (RGB) Trans (A)", 2D) = "white" {}
6    }
7
8    SubShader
9    {
10        Tags{ "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }
11        LOD 200
12
13        Pass
14        {
15            CGPROGRAM
16            #pragma vertex vert
17            #pragma fragment frag
18
19            #include "UnityCG.cginc"
20
21            struct appdata
22            {
23                float4 vertex : POSITION;
24                float2 uv : TEXCOORD0;
25            };
26
27            struct v2f
28            {
29                float2 uv : TEXCOORD0;
30                float4 vertex : SV_POSITION;
31            };
32
33            sampler2D _MainTex;
34            float4 _MainTex_ST;
35            fixed3 _KeyColor;
36            fixed _Near;
37
38            v2f vert(appdata v)
39            {
40                v2f o;
41                o.vertex = UnityObjectToClipPos(v.vertex);
42                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
43                return o;
44            }
45
46            fixed4 frag(v2f i) : SV_Target
47            {
48                fixed4 c = tex2D(_MainTex, i.uv);
49                clip(distance(_KeyColor, c) - _Near);
50                return c;
51            }
52            ENDCG
53        }
54    }
55
56    Fallback "Unlit/Transparent"
57}