processingで図形をクリックしたらランダムな場所にまた図形を表示する方法

Question

前提・実現したいこと

processingでエイム練習のようなものを作ろうとしているんですが、円をクリックしたらつぎの円がまたランダムな場所に円を表示するようにする方法がわからなくて困ってます。

発生している問題・エラーメッセージ

エラーメッセージ

該当のソースコード

float x,y;
int i=0;
int j=1;
int q=150;
void setup(){
  size(1000,800);
   //noLoop();
   noSmooth();
   background( #ffffff );
}
void draw(){
   
   fill(0,0,255);
    if(i<j){
    
    x= random(75,925);
    y= random(75,725);
    
      ellipse(x,y,75,75);
      
    }
  }
    
void mouseClicked(){
  if( dist(x,y,mouseX,mouseY) <= 75){
    background(#ffffff);
    j++;
    
  }
    }
 

試したこと

一応自身が調べれる範囲でサイトで調べました。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Answer 1

aoisora28さんがi・j・qを、どう使うつもりなのか読み取れませんでした。
他人にもわかりやすいように、意味のある変数名にするかコメントを書きましょう。

円をクリックしたらつぎの円

「クリックしたら」なのですから、x・yの代入はmouseClicked()でやればいいでしょう。

ellipse(x,y,75,75);は、デフォルトでは楕円の幅・高さ（≒直径）です。
if( dist(x,y,mouseX,mouseY) <= 75)は、円の当たり判定でしょうが75は半径です（円の中心とマウス位置の距離）

つまり当たり判定が倍の距離になっています。

float x, y; // 円の中心座標
final int radius = 38; // 円の半径

void setup() {
  size(1000, 800);
  x = random(0 + radius, width - radius);
  y = random(0 + radius, height - radius);
}

void draw() {
  background(255);

  fill(0, 0, 255);
  ellipse(x, y, radius * 2, radius * 2); // ellipseMode(RADIUS); とすれば*2は不要
}

void mouseClicked() {
  if (dist(x, y, mouseX, mouseY) <= radius) {
    x = random(0 + radius, width - radius);
    y = random(0 + radius, height - radius);
  } else {
    // ミス！
  }
}

dist() \ Language (API) \ Processing 3+
ellipseMode() \ Language (API) \ Processing 3+

回数を表示したり時間を計ったりと、やることはまだまだありますね。
頑張ってください。