音声の停止若しくはアニメーションを無限リピートする方法を教えていただきたいです。

Question

音付きの簡単なアニメーションをprocessingで作成しています。
ボールが跳ねるのに合わせて音をつけているのですがボールが左側に帰ってきた時点で音を止めるか若しくはボールが枠外から出ずに永遠と跳ね返り続けるように修正したいです。現時点でエラーは出ていません。
何かいい方法がありましたら教えていただきたいです。修正版のコードを載せていただけたら嬉しいです。面倒だと思いますがどなたかお願いします!

コード　（初心者なのでかなりつたないコードになってます、ご容赦ください。）
import processing.sound.*;

SoundFile sound;

float g = 0.15;
float x;
float y;
float spd_x;
float spd_y;

void setup(){
size( 1000, 400 );
x = -200;
y = height;
spd_x = 3;
spd_y = -10;
sound = new SoundFile(this, "sound.mp3");
}

void draw(){
background(255);

spd_y += g;

x += spd_x;
y += spd_y;
fill(0);
ellipse(x, y, 60, 60);

if( y > height ){
spd_y = -spd_y;
sound.play();
}

else if( x > width) {
spd_x = -spd_x;

}

}

作業環境
Windows10
processing-3.5.4

Answer 1

ボールが左側に帰ってきた時点で音を止めるか若しくはボールが枠外から出ずに永遠と跳ね返り続けるように修正したいです。

どちらにするにしても、初期位置が枠外なところが扱いにくい原因だと思います。
初期位置が枠内に収まるように調整すれば、音を止めるのは簡単ですよね？（xがマイナスであれば止めるだけ）
跳ね返り続けるのもx < 0という条件を付け足すだけです。

import processing.sound.*;

SoundFile sound;

float g = 0.15;
float x = 0;
float y = 60;
float spd_x = 3;
float spd_y= 0;

void setup() {
  size(1000, 400);
  sound = new SoundFile(this, "sound.mp3");
}

void draw() {
  background(255);

  spd_y += g;
  x += spd_x;
  y += spd_y;

  fill(0);
  ellipse(x, y, 60, 60);

  if (height < y) {
    spd_y = -spd_y;
    //sound.stop();
    sound.play();
  }
  if (x < 0 || width < x) {
    spd_x = -spd_x;
  }
}

---

とは言えこのままですと、跳ね返りが小さくなった時に枠外に沈みます。
このあたりの調整は難しいうえ、例えばボールを増やそうとした途端破綻します。

個人的にはこういった処理は便利なライブラリがあるので、任せられるところはどんどん任せたらいいと思っています（が、なぜか質問者受けが悪いです^^;

fisicaを使用しました。
導入法はProcessing - processingで図形を選択して動かす方法｜teratailを参照。

import processing.sound.*;
import fisica.*;

SoundFile sound;
FWorld world;

void setup() {
  size(1000, 400);

  sound = new SoundFile(this, "sound.mp3");

  Fisica.init(this);
  world = new FWorld();
  world.setEdges(); // 壁
  world.setGravity(0, 500); // 重力

  FCircle ball = new FCircle(60);
  ball.setDamping(0); // 減衰
  ball.setFill(0); // 色
  ball.setFriction(0); // 摩擦
  ball.setNoStroke(); // 線無し
  ball.setPosition(60, 60); // 位置
  ball.setRestitution(0.99); // 反発
  ball.setVelocity(200, 0); // 速度
  world.add(ball);
}

void draw() {
  background(255);

  world.step(); // 物理演算
  world.draw(); // 描画
}

void contactStarted(FContact c) { // 接触
  //sound.stop();
  sound.play();
}

void mouseClicked() { // マウスクリックで増殖
  FCircle ball = new FCircle(60);
  ball.setDamping(0);
  ball.setFill(random(256), random(256), random(256));
  ball.setFriction(0);
  ball.setNoStroke();
  ball.setPosition(mouseX, mouseY);
  ball.setRestitution(0.99);
  ball.setVelocity(random(400) - 200, 0);
  world.add(ball);
}

注）各数値に特に根拠はありません。元コードに似るように現物合わせしただけです。