processingでexcelファイルを作成する際にprocessing内でのセルの削除の方法

Question

file.println(a);

この関数を使って、csvファイルをprocessingで作成しています。
出力は上の関数でできるのですが、一回出力したものをセルから削除することはできません。
その場合の削除方法があれば教えていただきたいです。

Comments

[TN8001]

第三者にわかるように質問してください。

fileってなんですか？
aってなんですか？
セルってなんですか？
「セルから削除する」とはどういう状態ですか？

[TN8001]

お忙しいようで返答がないですが、用意したコードを取っておくのも面倒なので回答しておきます。

質問は編集できるので、以下も訂正していただきたいです。

通常Excelファイルというと、.xlsxとか.xls等をいいます。
Excelファイルを直接編集するのでなければ、タイトルは不適切です。Excelタグも不要です。

ProcessingではJava以外にもJavaScript等も使えますが、だいぶ書き方が違いますのでターゲットが決まっているのであればほかのタグは不要です。

Answer 1

Processingでのcsv作成はいろいろ方法がありますが、一番簡単なTableでやってみます。
Table \ Language (API) \ Processing 3+
Table

どういう操作をしたいのかわかりませんが、

• csv新規作成
• csv読み込み
• csv保存
• 行の追加
• 行の編集
• 行の削除

を一通りやりました。

サンプルの動作ですが、マウスドラッグで線（点の集まり）が引けます。
線のデータをcsvに保存して、次回起動時に線を復元します。
その際古いデータはだんだん色が薄くなり、古すぎるデータは削除します。

Table table;

void setup() {
  size(300, 300);
  strokeWeight(5);
  background(255);

  // 【csv 読み込み】
  table = loadTable("test.csv", "header");

  if (table == null) { // ファイルがなかったらnull

    // 【csv 新規作成】
    table = new Table();
    table.addColumn("x");
    table.addColumn("y");
    table.addColumn("color");
  }

  // 【csv 行の編集】 古いデータをグレーにする
  for (TableRow row : table.rows()) {
    // 読み込んだcolorに85を足して上書き（数字が大きいほど白くなる）
    row.setInt("color", row.getInt("color") + 85);
  }

  // 【csv 行の削除】 colorが255になったものは削除
  // colorが255の行のインデックスをすべて取得
  int[] deleteRowIndices = table.findRowIndices("255", "color");
  // 削除時の定跡 逆順にしてループ（後ろから削除しないとインデックスがずれていってしまう）
  for (int index : reverse(deleteRowIndices)) {
    // 指定インデックス行をTableから削除
    table.removeRow(index);
  }

  // csvに保存した点を指定位置・色で描画
  for (TableRow row : table.rows()) {
    stroke(row.getInt("color"));
    point(row.getInt("x"), row.getInt("y"));
  }

  stroke(0);
}

void draw() {
}

void mouseDragged(MouseEvent e) {
  point(mouseX, mouseY); // 点の描画

  // 【csv 行の追加】 描画した点をTableに追加
  TableRow newRow = table.addRow();
  newRow.setInt("x", mouseX);
  newRow.setInt("y", mouseY);
  newRow.setInt("color", 0); // 黒
}

void mouseReleased() {

  // 【csv 保存】
  saveTable(table, "test.csv");
}

上図は、

1. 丸を書いて一旦終了（削除された）
2. 三角を書いて一旦終了
3. 四角を書いて一旦終了
4. バツを書いた

ところです。

Answer 2

ファイルに出力してしまったものは、もはやプログラムの制御を離れています。

別途ファイルを編集することで対応することになるかと思います。