トップレベルウィンドウ＝親ハンドルゼロ？

前提・実現したいこと

興味本位でExcel VBAでWin32 APIコマンドを実行しています。

発生している問題・エラーメッセージ

疑問点：
下記ソースコードは、API関数 EnumWindowsを使用して
Excel "Sheet1"シートに親ハンドル、自ハンドル等を列挙するプログラムです。

EnumWindowsは、トップレベルウィンドウを列挙する関数だと思いますが、
親ウィンドウのハンドル (A列) にゼロ("0")ではない数字が入ることがあります。なぜでしょうか？

トップレベルウィンドウ ＝ 親ハンドル ゼロ("0")

ではないのでしょうか？

該当のソースコード言語：VBA (Excel)



Option Explicit

'-------------------------------------
'　親ハンドルの取得
'-------------------------------------
Private Declare PtrSafe Function GetParent Lib "user32" (ByVal hWnd As LongPtr) As LongPtr

'-------------------------------------
' ウィンドウのクラス名を取得
'-------------------------------------
Private Declare PtrSafe Function GetClassName Lib "user32" Alias "GetClassNameA" _
(ByVal hWnd As LongPtr, ByVal lpClassName As String, _
ByVal nMaxCount As Long) As Long

'-------------------------------------
' ウィンドウのタイトルバーのテキストを取得
'-------------------------------------
Private Declare PtrSafe Function GetWindowText Lib "user32" Alias "GetWindowTextA" _
(ByVal hWnd As LongPtr, ByVal lpString As String, _
ByVal cch As Long) As Long

'-------------------------------------
' ウィンドウのプロセスIDとスレッドIDを取得
'-------------------------------------
Private Declare PtrSafe Function GetWindowThreadProcessId Lib "user32" _
(ByVal hWnd As LongPtr, ByRef lpdwProcessId As Long) As Long

'-------------------------------------
' トップレベルウィンドウを列挙
'-------------------------------------
' トップレベルウィンドウを列挙する関数の宣言
Private Declare PtrSafe Function EnumWindows Lib "user32" _
(ByVal lpEnumFunc As LongPtr, ByRef lParam() As LongPtr) As Long



'------------------------------------------------------------------------------
' Main
'------------------------------------------------------------------------------
Sub EnumList()
Dim hWndList() As LongPtr 'ウィンドウハンドル格納域
Dim i As Long

ReDim hWndList(0) '領域確保

Worksheets("Sheet1").Range("A:k").ClearContents ' リストクリア

Worksheets("Sheet1").Cells(1, 1).Value = "親ハンドル"
Worksheets("Sheet1").Cells(1, 2).Value = "自ハンドル"
Worksheets("Sheet1").Cells(1, 3).Value = "プロセスID"
Worksheets("Sheet1").Cells(1, 4).Value = "スレッドID"
Worksheets("Sheet1").Cells(1, 5).Value = "クラス名"
Worksheets("Sheet1").Cells(1, 6).Value = "ウィンドウタイトル"

' すべてのウィンドウハンドルを配列に取得
Call EnumWindows(AddressOf EnumWindowsProc, hWndList)

For i = 1 To UBound(hWndList) '配列の0番目は使っていません
Call SetList(i + 1, hWndList(i)) 'タイトル分+1してシートに列挙
Next

MsgBox "End"
End Sub

'-------------------------------------
' コールバック関数 - トップレベルウィンドウを列挙
'-------------------------------------
Private Function EnumWindowsProc(ByVal hWnd As Long, ByRef lParam() As LongPtr) As Long

'参照形式で受け取ったポインター配列に見つかったハンドルを追加
ReDim Preserve lParam(UBound(lParam) + 1) '領域拡張
lParam(UBound(lParam)) = hWnd 'ウィンドウハンドルセット

EnumWindowsProc = True '列挙を継続

End Function


'-------------------------------------
' ウィンドウハンドルから各種情報を取得し、エクセルシートに書き出し
'-------------------------------------
Private Sub SetList(lngRow As Long, hWnd As LongPtr)

Dim Buffer As String * 512 'バッファ

Dim lngPrs As Long 'プロセスID
Dim lngTrd As Long 'スレッドID

Worksheets("Sheet1").Cells(lngRow, 1).Value = GetParent(hWnd) '親ハンドル
Worksheets("Sheet1").Cells(lngRow, 2).Value = hWnd '自ハンドル

'プロセスIDとスレッドIDを取得する
lngTrd = GetWindowThreadProcessId(hWnd, lngPrs)
Worksheets("Sheet1").Cells(lngRow, 3).Value = lngPrs 'プロセスID
Worksheets("Sheet1").Cells(lngRow, 4).Value = lngTrd 'スレッドID


' クラス名
Dim strClassName As String
Call GetClassName(hWnd, Buffer, Len(Buffer))
strClassName = Left(Buffer, InStr(Buffer, vbNullChar) - 1)
Worksheets("Sheet1").Cells(lngRow, 5).Value = strClassName ' クラス名


' ウィンドウタイトル
Call GetWindowText(hWnd, Buffer, Len(Buffer))
Worksheets("Sheet1").Cells(lngRow, 6).Value = Left(Buffer, InStr(Buffer, vbNullChar) - 1) ' ウィンドウタイトル

End Sub

補足情報（FW/ツールのバージョンなど）

Windows10 Home
64ビットオペレーティングシステム、x64ベースプロセッサ
Excel(Microsoft365)

行動規範の内容に同意します

回答3件

ベストアンサー

たとえばポップアップメニューなどが他のウィンドウを親として持つトップレベルウィンドウですね。
Windows Forms で作った場合は Form はトップレベルですが、Application という不可視のウィンドウの子になります。

トップレベルウィンドウというのは、ボタンやテキストボックスなど他のウィンドウのコントロールではないウィンドウを指します。雑に言うと、宙に浮いているものがトップレベルです。ただし MDI を除きます。

追記

もっとも、トップレベルの場合は通常は親と言わずオーナーと言います。

GetParent function (winuser.h) - Win32 apps | Microsoft Docs

GetParent function (winuser.h)
If the window is a child window, the return value is a handle to the parent window. If the window is a top-level window with the WS_POPUP style, the return value is a handle to the owner window.

投稿2020/09/26 23:50

編集2020/09/26 23:59