awkを使って平均点を出すと思っているものと違う結果が出てしまう

Question

前提・実現したいこと

太郎 50 70
次郎 58 56
三郎 64 67
と書かれたファイルを読み込んで
合計が１２０以上の人は〇〇さんは合格ですと、そしてその後に全員の平均（小数第１位まで）が出るようにしたい。

つまり

太郎さんは合格です
三郎さんは合格です
平均は121.7点です

こういう結果が出るようにしたいのですがうまくいっていません。
どなたか助けていただきたいです。~~~

今私が作っているものはこう返ってきてしまう

太郎さんは合格です
平均は120点です
次郎さんは合格です
平均は83点です

該当のソースコード

#!/bin/sh

awk '
$2 + $3 >= 120{

	printf("%sさんは合格です\n",$1)
	m+=$3
	n+=$2
	printf("平均は%.1f点です\n",((m+n)/NR))
}' $1

Answer 1

まず、問題定義と結果の例があやふやですね。

「合計が120の人」→「合計が120点以上の人」だとして、想定される結果は、

太郎さんは合格です
三郎さんは合格です
平均は125.5点です

なのでは。次郎さんは114点なので不合格ですよね。

次に、合格した人の(2つの数値の合計の)平均点を最後に出すには、合格した人だけの合計点と人数を数えておいて、すべての入力が終わった後で計算と表示を行なう必要があります。

$2 + $3 >= 120 {
    print $1 "さんは合格です"
    total += $2 + $3
    member += 1
}
END {
    printf("平均は%.1f点です\n", total/member)
}

追加分:
全員の(2つの数値の合計の)平均点を最後に出すのであれば、

{
    if ($2 + $3 >= 120) {
        print $1 "さんは合格です"
    }
    total += $2 + $3
}
END {
    printf("平均は%.1f点です\n", total/NR)
}

としてください。この場合に得られる結果は以下のようになります。

太郎さんは合格です
三郎さんは合格です
平均は121.7点です

Comments

[Zuishin]

全員の平均ではなく合格者の平均になりますね。

[Daregada]

そもそも、「誰に対する何の平均点か」が明確に定義されていないんですよね。

[Zuishin]

そうですね。質問者は書いていないので、問い合わせて確定するか、回答者側でこのように決めたことを説明するのがいいのではないかと思いました。

[terataillll]

返信ありがとうございます！
すみません！いろいろ間違えていました。。。
平均は3人全員の分を出したいです。

[Daregada]

というわけで記述を追加しました。

[terataillll]

#!/bin/sh

awk '
$2 + $3 >= 120{
if ($2 + $3) {
printf("%sさんは合格です\n",$1)
}
total += $2 + $3
}END{
printf("平均は%1.d点です\n",(total/NR))

}' $1
と変更してみたのですが平均点が合わないです．
121.７が正しいのですが83という結果になります。
awkを理解できていないと思うのでわかりやすく教えていただけませんか...？

[Daregada]

$2 + $3 >= 120 { ... }
と書くと、{ ... }の処理は、その前の条件が成立した場合だけ処理されます。
今回は全員の点数をtotalに追加していきたいので、「$2 + $3 >= 120」を取り除いてください。それから、if文の条件式の後半が抜けていたので、修正した回答のように「>= 120」を追加してください。

[terataillll]

理解しました！できました！ありがとうございます！！！助かりました！