(VBA)PowerPoint(パワポ)のフォントを統一させたい

Question

いつもお世話になっております。
表題の件について質問させてください。

お世話になっております。
表題の件で質問をさせてください。

環境：
Windows 10 Pro x64
Power Point 2016

パワポで使う文字って大体下のパターンだと思っております。

下記のVBAを使ってパワポの種類を統一させてみましたが、表とグループ化した文字は変わりませんでした。

Sub フォントを一括変更する()

  'Const FNT_NAME = "Times New Roman"
  Const FNT_NAME = "Meiryo UI"
  Const FNT_SIZE = "10.5"
  Dim sld As Slide
  Dim shp As Shape

  For Each sld In ActivePresentation.Slides
    'テキストボックス
    For Each shp In sld.Shapes
      If shp.Type <> msoPlaceholder Then
        If shp.HasTextFrame Then

          With shp.TextFrame.TextRange.Font
            .Name = FNT_NAME
            .NameFarEast = FNT_NAME
            .Size = FNT_SIZE
          End With

        End If
      End If
    Next shp
  Next sld
End Sub

調べてみたところサンプルを発見したので以下のVBAサンプルを使ってみましたが上手くいきません。

Sub フォントの一括変換()
    'Const FontName = "MSP ゴシック"
    Const FontName = "Meiryo UI"

    Dim sld As Slide
    Dim shp As Shape
    Dim clm As Columns
    Dim cl  As Object
    Dim gsh As GroupShapes
    

    For Each sld In Application.ActivePresentation.Slides
        For Each shp In sld.Shapes
            'テキストボックス
            If shp.HasTextFrame Then
                With shp.TextFrame.TextRange.Font
                    .name = FontName
                    .NameFarEast = FontName
                End With
            End If
            'テーブル内変換
            If shp.HasTable Then
                For Each clm In shp.Table.Columns
                    For Each cl In clm.Cells
                    
                        With cl.Shape.TextFrame.TextRange.Font
                            .name = FontName
                            .NameFarEast = FontName
                        End With
                    Next  'cl
                Next 'clm
            End If 'HasTable
            'グループの場合
            If shp.Type = msoGroup Then
                For Each gsh In shp.GroupItems
                    If gsh.HasTextFrame Then
                        With gsh.TextFrame.TextRange.Font
                            .name = FontName
                            .NameFarEast = FontName
                        End With
                    End If 'HasTextFrame
                Next 'gsh
            End If
        Next
    Next
End Sub

For Each cl In clm.Cellsのところでエラーになります。
調べたところColumnsにCellsは存在しない様ですが、メソッドを変更したりもしましたが、
上手くいかずに再び質問をいたしました。

申し訳ございませんがご回答いただけませんでしょうか。

何卒宜しくお願い致します。

Answer 1

調べてみたところサンプルを発見したので以下のVBAサンプルを使ってみましたが上手くいきません。

の引用元は以下のサイトですかね？

【PowerPoint（VBA）】パワポ資料のフォントを一括変換する方法（グループ化図形対応）｜ひとりPython3アプリ制作、分析、解析

---

コードの方の話をすると、Dim clm As Columnsの型が誤っているのが原因です。
.ColumnsをFor Eachで列挙したオブジェクトになるので、単数形のColumn型を指定しましょう。

問題の箇所の手前までは、きっちり型を明示して頂いているので、
以下のように、一時的に.Itemと入力すると、列挙されるオブジェクトの型を確認することもできます。

また、以下の変数についても型の指定を変更した方が良いでしょう。

Dim cl  As Cell
Dim gsh As Shape

---

ただ、「フォントの統一」という事を考えるのであれば、「テーマのフォント」を使用するのを個人的には推奨したいです。

フォントの名前に「～ 見出し」「～ 本文」と設定されている場合があると思いますが、それらのフォントは「テーマのフォント」の設定を参照しているフォントになります。

「～ 見出し」「～ 本文」のフォントを設定しておくことで、「テーマのフォント」さえ変更すれば瞬時に全ての図形のフォントを変更できるようになります。

PowerPoint2016では「表示タブ」>「スライドマスター表示」>「スラ痔尾マスタータブ」>「フォント」から「テーマのフォント」を確認できます。

VBAからテーマのフォントを設定する場合は、以下の文字列をFontのNameなどに設定します。

プロパティ名	見出しのフォント	本文のフォント	備考
Name	+mj-lt	+mn-lt	英数字用のフォント
NameFarEast	+mj-ea	+mn-ea	日本語文字用のフォント

mj = Major
mn = Minor
lt = Latin
ea = East Asia

Comments

[izuki_y]

返事が遅くなってしまい大変申し訳ございませんでした。
ご回答頂きましてありがとうございます。