Arduino　 LEDの点灯消灯をシリアル通信（文字列）でやりたい

Question

Arduino初心者です。
LEDの点灯消灯をシリアル通信（文字列）でやりたいのですがうまくいきません。

以下がスケッチなのですが、 Serial.println(dat); で目的のon01がdatに入力されているのは確認出来るのですが
 if(dat == "on01"){ が動作していないようです。
データ型の問題の様な気がするのですが、あれこれ試しても上手くいきませんでした。
御教授のほどお願い致します。

追記
マルチポストを推奨をしていない旨を知らずに下記のリンクに同じ質問をしてしまいました。
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q12228794132
まだ問題は解決はしていないのですが関連した質問などを参考にしてやってみます。

```Aruduino IDE
//IOのピン番号
const int DIN_PIN = 7;
const int LED_PIN = 6;
 
//入力された文字を入れる変数
char dat[32];   // 格納用文字列
int count = 0;  // 文字数のカウンタ
 
void setup(){
  pinMode( LED_PIN, OUTPUT);
  pinMode( DIN_PIN, INPUT_PULLUP );
  Serial.begin(9600);
} 
void loop(){
  //文字列を読み込む
    Serial.flush();
    if (Serial.available()) {
    dat[count] = Serial.read();
    if (count > 30 || dat[count] == '=') {  // 文字数が既定の個数を超えた場合、又は終了文字を受信した場合 
     dat[count] = '\0';                    // 末尾に終端文字を入れる
      count = 0;                            // 文字カウンタをリセット
    Serial.println(dat);
    } else {
      count++;                              // 文字カウンタに 1 加算
    }
  } 
    //出力
    //読み込んだ文字が「on01」のときシリアルモニタに「ON」をさせ、LEDを点灯させる
    if(dat == 'on01'){
     digitalWrite(LED_PIN, HIGH);
    //LEDを点灯させた後okを返信
     Serial.print("ok
");
     Serial.flush();
     }
     
    //読み込んだ文字が「off01」のときシリアルモニタに「OFF」をさせ、LEDを消灯する
    if(dat == 'off01'){
      digitalWrite(LED_PIN, LOW);
    //LEDを消灯させた後okを返信
      Serial.print("ok
");
      Serial.flush();
    }
}
```

Accepted Answer

最初の間違いは「文字リテラル(定数)」と「文字列リテラル」の区別が出来ていないこと。文字リテラル'A'は単に数値65の意味(ASCIIコード環境下。なお、''の中に複数の文字を入れてもエラーにはならないことが多いですが、その使い方は通常しない、と思っておいていいです。それでも本気で知りたければその旨聞いて下さい)。一方、文字列リテラル"A"はどこかにデータ'A''\0'を置いたそのアドレス(ポインタ)の意味になります。今回は文字列として比較するのですから、比較対象は文字列リテラル。

で、文字列の中身の比較をするのならstrcmp()関数を使うのがまず第一案。
strcmp()関数は、第1/第2パラメータの文字列が等しければ0を返すので
`if(strcmp(dat,"on01")==0){ //datの中身が"on01"に等しければ`
とします。
なお、`dat=="on01"`は文字列の在り処の比較なので、意図した動きにはなりません。

でも、せっかく文字列型が用意されているのだから使わなきゃもったいないし、String型を使うのならもっと使い込まなきゃもったいない。

まず。
String型に対する==演算子はArduinoでは文字列の中身の比較をちゃんと(?)やってくれます。
[https://www.arduino.cc/en/Tutorial/BuiltInExamples#strings](https://www.arduino.cc/en/Tutorial/BuiltInExamples#strings) を読めば、
> The operator == and the method equals() perform identically.

と書いてあります。つまり
`if(String(dat)=="on01"){`で先のstrcmp版と同様の結果が得られます。String::equals()で書きたいのなら別に止めませんが...

で、Stringを使うと、文字列の格納スペースとか、最後に'\0'をつけることとかは基本的には気にする必要がなくなります。なので、datをそもそもString型にして
`String dat="";`
として宣言すれば、countの管理は不要。さらにcがchar型の値とすれば
`dat+=c;`
で文字列を成長させることが出来ます。また、やりたければ行頭や行末のホワイトスペース(スペース、改行、水平タブ)を除去するtrim()を使って`dat.trim()`なんてことも出来ます。
先程の比較も、わざわざString型のオブジェクトを生成する必要もなく、
`if(dat=="on01"){`でOK。

速度やメモリ容量に厳しいプログラム(あるいはC言語の基礎修行)でないのなら、String型を使っちゃえばよいのでは。

つぎに。
全体の構成の話ですが、現状は
```
  1文字受信して
  文字列を成長させて
　コマンド検出/実行
```
という構成になっています。でも、コマンド検出/実行は、文字列が確定してからやるものではないでしょうか?
```
  1文字受信して
　コマンド文字列確定? ならば
　　　コマンド検出/実行
　でなければ
　　　文字列成長
```
成長中の文字列を覗くから、途中で実行しちゃうみたいな現象が起こるのです。

話は変わって、
Serial.flush();。多分、OS環境下のCでprintf()がデータをバッファに貯めることがあるという話を聞きかじってそれを真似たものだと思いますが、それはあくまでその処理系でのprintf()関数の話。ArduinoのSerial::flush()は全く別の意味、用途を持っています。その意味、用途を以てここに使っているのですか? まぁ、この場合使っても害はなさそうですが...

もう一点、Serial.print("文字列
"):としているのはなぜでしょう? 特別な意図が無いのなら、Serail.println("文字列");とした方がよろしいかと思います。これも大きな害はないですけれど。

そんなこんなを盛り込むと、loop()関数の一例としてはこんなところでは。
```Arduino
//入力された文字を入れる変数
String dat = "";
void loop() {
  //文字列を読み込む
  if (Serial.available()) {
    char c = Serial.read();
    if ( c == '=') { // 終了文字を受信した場合
      //dat.toLowerCase();//必要に応じて。全部小文字に変換
      Serial.println(dat);
      //出力
      //読み込んだ文字が「on01」のときシリアルモニタに「ON」を送り、LEDを点灯させる
      if (dat == "on01") {
        digitalWrite(LED_PIN, HIGH);
        //LEDを点灯させた後okを返信
        Serial.println("ok");
      } else
      //読み込んだ文字が「off01」のときシリアルモニタに「OFF」を送り、LEDを消灯する
      if (dat == "off01") {
        digitalWrite(LED_PIN, LOW);
        //LEDを消灯させた後okを返信
        Serial.println("ok");
      } else
      //入力確認
      //読み込んだ文字が「in01」のとき
      if (dat == "in01") {
        //DIN_PINの状態をon/offで返信
        int value;
        value = digitalRead( DIN_PIN );
        if ( value == HIGH ) { //HIGHがOFF,LOWがON
          Serial.println("off");
        } else {
          Serial.println("on");
        }
      }else{
        Serial.println("Command ERROR.");
      }
      dat = "";
    } else {
      if (dat.length() < 5) {//これ以下でないとコマンドに絶対に一致しないのでデータを保存する意味がない。
        dat += c;
        //dat.trim();//必要に応じて。前後のホワイトスペース文字を除く
      }
    }
  }
}
```

Answer

- Serial.flush();はこれまで受信した文字を捨ててしまうのでこれを実行してはダメです。この行はコメントアウトしときましょう
- 文字列の比較はstrcmp関数を使います

でもひとつ、
文字列の比較をループ回るたびに行ってますが、これを、
１行受信完了したときだけ、にするように、
また、
文字列の処理が終わったら、再度処理しないように（例えば受信バッファをクリアするなど）
するようにしましょう。

Answer

文字列の比較はString.equalsを使います。

```cpp
String(dat).equals("in01");
```

この辺りを読んでください
https://www.arduino.cc/en/Tutorial/BuiltInExamples#strings
https://www.arduino.cc/reference/en/language/variables/data-types/string/functions/equals/

---

追記：コメント欄はフォーマットが効かないので、ここに書きます。
2020/07/23 03:55の返信です。

原因はよく分からなかったのですが、とりあえず以下の問題があり、これらをクリアしたら動きました。

* バッファオーバーフローが発生しています
* 見えない文字（改行など）を想定していません
* 読み込みし終わる（想定？）前に1.2.3.が走ります

##### バッファオーバーフローが発生しています

```
char dat[4]; // 格納用文字列
```

読み込む文字は `of01` 等、終端文字を入れて5バイトなので、4バイトでは足りません。なので、`count` 等が破壊される可能性があります。
（質問文では32バイトなのに…）

##### 見えない文字（改行など）を想定していません

シリアルモニターの設定で回避出来ますが、改行文字`'
'`等を読み取ってしまいます。
`in01=
` という文字列が来たとき、次に`in01=
` を受けても、`=`の解釈時にdatは`
in01=`となっているので、どれにもequalsになりません。

```cpp
  if (Serial.available()) {
    int chr = Serial.read();
    if (chr >= 31) {  // 可視文字または半角スペースを受け取ったとき
      dat[count] = chr;
```


##### 読み込みし終わる（想定？）前に1.2.3.が走ります

多分、`on01xxxxxx` な入力をしても反応するのでは？
読み込みが完了したかどうかのフラグを入れると良いと思います

```cpp

void loop(){
  bool fire = false;

  // 略

      dat[count] = Serial.read();
      if (count > 30 || dat[count] == '=') {
        fire = true;

  // 略

  if (fire == true) {
  
    //1.読み込んだ文字が「on01」のときLEDを点灯させる
    if(String(dat).equals("on01") == true){
      // ...
    }
}
```