ExcelあるいはWordの数式エディタであらわせる数式を、VBAを用いて編集したい

Question

https://teratail.com/questions/input

ExcelあるいはWordの数式エディタを用いた数式VBAを用いて編集したい

中学校レベルの「計算問題」（以下数学式）を作成するツールを作成したいと思っています。
しかし、数学式を編集する有効な手段が見つけられませんでした。

そこで、数学式を編集する手段として一番可能性があると考えたのが「OfficeのExcel・Wordに搭載されている数式エディタをマクロで操作する」という方法で、Excel上で数式エディタの編集アクションを「マクロの記録」で取得したのですが、正確に記録ができません。
また、そのマクロを実行しても再現しません。

ExcelあるいはWordの数式エディタをVBAを用いて編集する方法をご教授いただけますでしょうか。
また、もしExcel・Word以外で、かつweb上のツールを利用せずに数学式を出力する方法がありましたら、ご教授ください。
よろしくお願いします。

バージョン

office365

発生している問題・エラーメッセージ

【Excel」
数式エディタで分数やルートを表す編集アクションを記録すると、記録されたマクロのコードに"?1?2?"が入力される
例　：数式エディタで分数「1/2」を入力した動作を記録したところ、下記のように自動記録された。

　  ActiveSheet.Shapes.AddLabel(msoTextOrientationHorizontal, 663, 251.25, 72, 72). Select
    Selection.ShapeRange(1).TextFrame2.TextRange.Characters.Text = "?1?2?"
    Selection.ShapeRange(1).TextFrame2.TextRange.Characters(1, 5).ParagraphFormat.irstLineIndent = 0
    With Selection.ShapeRange(1).TextFrame2.TextRange.Characters(1, 1).Font
        .NameComplexScript = "+mn-cs"
        .NameFarEast = "+mn-ea"
        .Fill.Visible = msoTrue
        .Fill.ForeColor.ObjectThemeColor = msoThemeColorText1
        .Fill.ForeColor.TintAndShade = 0
        .Fill.ForeColor.Brightness = 0
        .Fill.Transparency = 0
        .Fill.Solid
        .Size = 11
        .Italic = msoTrue
        .Name = "Cambria Math"
    End With

補足：上記のロジックを実行すると、オブジェクト内にテキストとして"?1?2?"が出力される。

【word】
数式を入力しても、数式エディタ上を参照しない
例：数式エディタ上で、ax+y=0を入力

Selection.TypeText Text:="$ax+y=0$"

補足：上記を実行すると、本文に"$ax+y=0$"が出力される。
WordについてはLaTeXの構文を利用した。

その他調査した内容

このソースコードの中で、オブジェクト内の文字について書かれているのは下記のみである、という認識です。

    Selection.ShapeRange(1).TextFrame2.TextRange.Characters.Text = "?1?2?"

また、最低限度出力したい数学記号は、2次方程式の解の公式です。
ご助力の程、どうぞよろしくお願いいたします。
.

Answer 1

回答出ていますが参考まで。(Word-VBA)

Sub Test_Sample_Miniature()

    Dim InitRange As Word.Range
    Dim objRange As Word.Range
    Dim objOMFun As Word.OMathFunction
    Dim objSEL As Word.Selection
    
    '末尾へ数式オブジェクトを設定
    ActiveDocument.Bookmarks("\EndOfDoc").Select
    Selection.TypeParagraph
    Set InitRange = Selection.Range
    InitRange.Text = " "
    Set objRange = Selection.OMaths.Add(InitRange)

    '∑式を追加
    Set objOMFun = objRange.OMaths(1).Functions.Add(objRange, wdOMathFunctionNary)
    Set objSEL = Selection  '文字位置取得
    
    objOMFun.Nary.Char = 8721
    objOMFun.Nary.HideSub = True
    objOMFun.Nary.HideSup = True
    
    '1文字右へ移動して数式セット
    objSEL.MoveRight Unit:=wdCharacter, Count:=1
    Selection.TypeText Text:="a/b"
    Set objSEL = Selection  '文字位置取得
    
    '1文字右へ移動して数式セット
    objSEL.MoveRight Unit:=wdCharacter, Count:=1
    Selection.TypeText Text:="=x"
    Set objSEL = Selection  '文字位置取得
    
    '数式の画面編集
    objRange.OMaths(1).BuildUp
    
    '√式を追加
    Set objOMFun = Selection.OMaths(1).Functions.Add(Selection.Range, wdOMathFunctionRad)
    objOMFun.Rad.HideDeg = True
    Set objSEL = Selection  '文字位置取得
    
    '1文字左へ移動してルート内へ数式セット
    objSEL.MoveLeft Unit:=wdCharacter, Count:=1
    objSEL.TypeText Text:="x+1"
    Set objSEL = Selection  '文字位置取得
    
    '1文字左へ移動して分母数式セット
    objSEL.MoveRight Unit:=wdCharacter, Count:=1
    objSEL.TypeText Text:="/(a+b)"
    
    '数式の画面編集
    objRange.OMaths(1).BuildUp
    
    '移動100文字で欄外へぬける。
    On Error Resume Next
    Selection.MoveRight Unit:=wdCharacter, Count:=100
    
End Sub

Answer 2

Powerpoint VBA 数式を書く ⑤ 参照設定不要版 - Powerpoint VBAを使おう!

上記記事によると、ExcelよりはWordで行うのが良さそうです(Excel/PowerPointの図形では直接編集が難しいため)。

以下は、記事の内容を参考にして、最前面のWord文書のテキストを「$ax+y=0$」という数式で上書きするものになります(WordのVBAで実行してください)。

Private Sub teratail275491()
'https://teratail.com/questions/275491
'参考サイト:Powerpoint VBA 数式を書く ⑤ 参照設定不要版(Powerpoint VBAを使おう!) http://chemiphys.hateblo.jp/entry/2017/02/19/114203
    
    Dim doc As Word.Document
    Set doc = ActiveDocument
    
    '数式を入力するテキスト範囲(文書全体)
    Dim tmpRng As Word.Range
    Set tmpRng = doc.Content
    
    'LaTex 形式で入力。
    tmpRng.Text = "$ax+b=0$"
    
    '数式化。
    Dim om As Word.OMath
    Set om = tmpRng.OMaths.Add(tmpRng).OMaths.Item(1)
    om.BuildUp
    
    Stop
End Sub

Comments

[Nissy019]

実行しましたところ、数式を表示することに成功しました。
例のロジックがわかりやすく、問題の本質部分まで理解を近づけることができました。
ありがとうございました。