ExcelVBAでコンボボックス内の日付をFindメソッドにて検索したい。

Question

以前コード全体のことについて質問させていただいたものです。依然解決していません。今回はその中でもFindメソッドについてです。

ーーー希望の作動ーーーーーー
UserForm３にあるComboBox１内の日付を選択→CommandBotton1をトリガに別シートのE列にある様々な日付から同様（複数）の日付の行のみを取得したい
コンボボックスの内の日付は関数を用い第N週の木曜日を表示させてます。
関数参考サイト→https://vba-labo.rs-techdev.com/archives/170
以下コードには検索用のコード、日付をコンボボックスに追加するコードを記入します。
初心者なものでどこがいけないのかがわかりません。
このコードを実行すると必ずnothingの結果になってしまいます。（星マークのところ）
単純に検索結果が一致してないことが原因だと思います。しかし何をどうすればいいかがわかりません。いろいろ試しましたが日付のシリアル値、テキスト、値等どれでもヒットしないのです。
検索先の別シートのE列にはカスタム書式yyyy/mm/ddが入っています。
ご教授のほどよろしくお願いします。

'検索用のコード
Private Sub CommandButton1_Click()

Dim S2 As Workshhet
 Set S2 = Worksheets("2")

 Dim LastRowY As Long
   LastRowY = S2.Cells(Rows.Count, 1).End(xlUp).Row

    Dim myRange As Range
    Dim myObj As Range
    Dim KeyDate As Date

 　　 Set myRange = S2.Range(S2.Cells(2, 5),S2.Cells(LastRowY, 5))
     KeyDate = CDate(UserForm3.ComboBox1)
     Set myObj = myRange.Find(What:=KeyDate, LookIn:=xlFormulas)                

   　 If myObj Is Nothing Or ComboBox1 = "" Then
   　　　 **MsgBox ComboBox1 & "はいません。"**
    　　　Exit Sub
     Else
        DeBug.Print myObj
     End If
End Sub

'コンボボックス内の日付の追加（第１週、第４週木曜日の日付を表示。カスタム関数については参考サイト参照）

Private Sub  UserForm _Initialize(）
With ComboBox１
　Dim i As Long
  Dim m As Date
  Dim y As Date 
   m = month(Date)
   y = year(Date) 
      
    Dim x As Date
    Dim z As Date
    Dim a As Date
         x = DateSerial(y, m, Day(Date))
         z = getDateWeekNum(y, m, vbThrusday,1)'カスタム関数第１週木曜日
　　　　　 a = getDateWeekNum(y, m, vbThrusday,4)'カスタム関数第4週木曜日


If CDate(x) <= CDate(z) Then
   For i = 0 To 12
   .AddItem getDateWeekNum(y, m + i, vbThrusday,1)
   .AddItem getDateWeekNum(y, m + i, vbThrusday,4)
   Next

ElseIf CDate(x) > CDate(Z) And CDate(x) <= CDate(a) Then
   For i = 0 To 12
   .AddItem getDateWeekNum(y, m + i, vbThrusday,1)
   .AddItem getDateWeekNum(y, m + i + 1, vbThrusday,4)
   Next

Else
   For i = 0 To 12
   .AddItem getDateWeekNum(y, m + i + 1, vbThrusday,1)
   .AddItem getDateWeekNum(y, m + i + 1, vbThrusday,4)
   Next
End If
End With
End Sub

Comments

[meg_]

LookIn:=xlFormulasのxlFormulasをxlValuesに変えたらどうなりますか？

[Apoll047]

オブジェクトが見つかりませんとのエラーが出ます。

[Apoll047]

失礼しました。
オブジェクトではなく
インデックスが有効範囲にありません。
9
がでます。
以上修正いたします。

[meg_]

そのエラーはどこで（どの行で）発生しましたか？

Answer 1

いろいろ試しましたが日付のシリアル値、テキスト、値等どれでもヒットしないのです。

※注意点
1)コンボボックスの値は文字列(String型)です。
2)FindメソッドのLookInにxlValuesを指定したら、「表示されている文字列」を検索します。

なので、「日付」を検索したいなら、文字列の表示形式を同じにしないと、同じ日付を検索できません。

※値で
値で検索しようと思ったことはないですが、
LookInにxlFormulasを指定して、日付を示す文字列をシリアル値に変換したら、できるかも？
試してみる価値はありそう？（試してみる元気はないけども＾＾；）

Findメソッドで日付を検索するとこういうトラブルが多いです。
（同様の回答をここ1～2ヶ月で3件目かと思います）
ワークシート上の関数、「Match関数」で検索すると、「セルの値」で検索できるので、
トラブルが少ないです。

同様（複数）の日付の行のみを取得したい

複数の結果を得たいなら、オートフィルター等のフィルター機能で検索すると、
VBAでループ処理を書かなくてもよくなります。
この際にも、単純にキーワードを指定すると、「文字列」で検索するので注意が必要になります。
しかし、これはまた別の話。

Option Explicit

Dim mrngTable As Range

Private Sub UserForm_Initialize()
    Me.CommandButton1.Enabled = False
    Me.ComboBox1.List = GetItem(Date)
    Set mrngTable = Worksheets(2).Cells(1).CurrentRegion
End Sub

Private Sub ComboBox1_Change()
    Me.CommandButton1.Enabled = Me.ComboBox1.ListIndex + 1
End Sub

Private Sub CommandButton1_Click()
    Dim sKey As String
    Dim rngFind As Range
    
    sKey = Me.ComboBox1.Text
    If Len(sKey) Then
        With mrngTable.Columns("E").Cells
            Set rngFind = .Find(sKey, .Item(.Count), xlValues, xlWhole)
        End With
        If rngFind Is Nothing Then
            MsgBox "ありません。"
        Else
            Application.Goto rngFind
        End If
    End If
End Sub

Function GetItem(ByVal d As Date) As Variant
    Dim n As Long
    Dim i As Long
    Dim v(1) As String
    
    d = d + 7 - Weekday(d) + vbThursday
    Do
        Select Case (Day(d) + 6) \ 7
            Case 1, 4
                v(i) = Format(d, "yyyy/mm/dd")
                i = i + 1
        End Select
        d = d + 7
    Loop Until i > UBound(v)
    GetItem = v
End Function