Access VBA クリックイベントをまとめたい

Question

お世話になります。

以下のサイトを参照して
http://www.h3.dion.ne.jp/~sakatsu/Breakthrough_P-Ctrl_Arrays05.htm

フォームのボタンのクリックイベントをまとめるプログラムを作ったのですが、クリックしても何も起こりません。
何が悪いのか見当がつかず、悩んでいます。

(状態）

form1に
ボタン名「b0~b9」を配置
（イベントプロシージャは空白）

---

<Class1>

Option Compare Database
Option Explicit

'イベントを持つコマンドボタン型の変数を宣言
Private WithEvents btn As MSForms.CommandButton
'ボタンの数字を格納する変数を宣言
Private Index As Integer

Public Property Let MyItem(ByVal c As MSForms.CommandButton)
'引数のコマンドボタンを変数に格納
Set btn = c
End Property

Public Property Let MyIndex(ByVal i As Integer)
'コマンドボタンの数字を変数に格納
Index = i
End Property

Private Sub Btn_Click()
MsgBox Index
End Sub

---

<Form1>

Option Compare Database
Option Explicit

Private NumBtn(0 To 9) As Class1

Private Sub Form_inisialyze()
Dim i As Integer

For i = 0 To 9
    Set NumBtn(i) = New Class1
    NumBtn(i).MyItem Controls("b" & i)
    NumBtn(i).MyIndex i
Next i

End Sub

Private Sub UserFom_Terminate()
Set NumBtn = Nothing
End Sub

---

求める結果
ボタン「b0」クリック → メッセージボックス「０」を表示
ボタン「b1」クリック → メッセージボックス「１」を表示
（以下略）

現状
何もおこりません。（エラー表示もなし）

心優しい方がいらっしゃいましたら教えて下さい。
よろしくお願いします。

Answer 1

参考にされているサイトはVB6についての記述のようですね。
AccessのフォームはMSForms.Formではなく、Access.Formとなり、VB6やExcelのフォームとは別物です。
そして、色々と試してみましたが、イベントをフックすることはできませんでした。

さて、私の結論は「できない」なのですが、一応、色々と間違ってそうなところをお伝えします。

まず、AccessのコマンドボタンはMSForms.CommandButtonとは別なので、Access.CommandButtonと書く必要があります。

次に、Form_inisialyzはスペルミスかと思いますが、もともとアクセスフォームにInitializeイベントやTerminateイベントはありません。書くならLoadイベント、Unloadイベントです。

次に、Terminateイベントに書いているSet NumBtn = Nothingですが、NumBtnは配列かと思いますので、個別にNothingするか「Erase NumBtn」とする必要があります。

最後に、NumBtn(i).MyItem Controls("b" & i) はプロパティへの値セットなので、イコールで代入する必要があります。さらにオブジェクト型プロパティなので、Setが必要です。

Set NumBtn(i).MyItem = Controls("b" & i)

しかし、全部直しても、やはり動作しませんでした。

【代替案】
次のマクロを用意して、

Private Sub ButtonClick(ByRef Num As Integer)
    MsgBox "ボタン" & Num & "が押されました。"
End Sub

個別のボタンクリックマクロから呼び出します。

Private Sub b0_Click()
    Call ButtonClick(0)
End Sub

個別のマクロをいちいち手で書くのが面倒なら、標準モジュールに次のコードを用意し、マクロにコードを書かせます。

Sub PrintButtonEvents()
    For i = 0 To 9
        Debug.Print "Private Sub b" & i & "_Click()"
        Debug.Print Space(4) & "Call ButtonClick(" & i & ")"
        Debug.Print "End Sub"
    Next
End Sub

実行するとイミディエイトウインドウにマクロが出力されるので、それを張り付けてください。

Comments

[urakawa]

ご回答いただきましてありがとうございました。
AccessVBAでは、クリックイベントを1つずつ書いていくしかないのですね。

１週間くらい悩んでいたので、残念ですが、
できないということが分かってよかったです。

とても助かりました。ありがとうございました！

Answer 2

解決済みですが、通りかかったので。

参照先のコードはVBAですが、Excel用のものですね。
Accessでも実現可能ですが、Excelとは少し異なります。。

クラスモジュール
<Class1>

Option Compare Database
Option Explicit

'イベントを持つコマンドボタン型の変数を宣言
Private WithEvents btn As Access.CommandButton
'ボタンの数字を格納する変数を宣言
Private Index As Integer

Public Property Let MyItem(ByVal c As Access.CommandButton)
    '引数のコマンドボタンを変数に格納
    Set btn = c
    'クリックイベントにイベントプロシージャを関連付け
    c.OnClick = "[EVENT PROCEDURE]"
End Property

Public Property Let MyIndex(ByVal i As Integer)
    'コマンドボタンの数字を変数に格納
    Index = i
End Property

Private Sub Btn_Click()
    MsgBox Index
End Sub

Excelと違って、クリックイベントにイベントプロシージャを関連付けするコードが必用になります。

フォームモジュール
<Form1>

Option Compare Database
Option Explicit

Private NumBtn(0 To 9) As Class1

Private Sub Form_Load()
    Dim i As Integer

    For i = 0 To 9
        Set NumBtn(i) = New Class1
        NumBtn(i).MyItem = Me("b" & i)
        NumBtn(i).MyIndex = i
    Next i
End Sub

Private Sub Form_Close()
    Erase NumBtn
End Sub

フォームの読み込み時(Load)イベントと閉じる時(Close)イベントを使います。

【別案】

今回の要件ならクラスモジュールを使わなくても、フォームモジュールのみで実現できます。

Accessでは、関数(Function)を下記のようにイベントプロパティに設定できます。

クリック時 =関数名()

これを利用します。

フォームモジュール
<Form1>

Option Compare Database
Option Explicit

Private Function Btn_Click(i As Integer)
    MsgBox i
End Function

Private Sub Form_Load()
    Dim i As Integer

    For i = 0 To 9
        Me("b" & i).OnClick = "=Btn_Click(" & i & ")"
    Next i
End Sub

Accessでのクラスモジュールの利用例は下記で紹介していますのでご参考に。

ClassModule - hatena chips

また、後者のイベントプロパティに関数を設定する方法の利用例が下記にありますのでそれもご参考に。

ボタンクリックでテキストボックスに文字入力 その1 - hatena chips

Comments

[urakawa]

ご回答ありがとうございます！

今までは諦めて
すべてのコマンドボタンのクリックイベント→Functionに飛ばして処理
していましたが、別案を試してみたら、理想通りの動きになりました。

本当にありがとうございます！