VBAでのIE制御におけるボタン操作

Question

Excel VBAを活用して、IE制御をするプログラムを作成している中で操作できないボタンがあり、
操作方法をご教示いただけませんでしょうか。

以下のコードに沿って試していくと、住所入力まではうまくいくものの、住所入力後の
遷移サイト上の「選択中の情報」欄にある「洪水」ボタンを押すことがどうしてもできません。
同様に「土砂災害」ボタンおよび「検索結果」欄の「×ボタン」も押下したいのですが、同様に
制御できず、住所入力後の検索ボタン押下時との制御の違いが理解できずにおります。

Sub hazardmap()

    Dim ie As InternetExplorer
    Dim txt As HTMLTextAreaElement
    Dim inputTags As IHTMLElementCollection
    Dim inputTag As IHTMLElement
    Dim inputTags2 As IHTMLElementCollection
    Dim inputTag2 As IHTMLElement
                 
'IEでHPを開く。
'---------------------------------------------------------------------------------------------------------
    Set ie = CreateObject("InternetExplorer.Application")
        ie.Visible = True
        ie.Navigate "https://disaportal.gsi.go.jp/"
    Do While ie.Busy Or ie.ReadyState < READYSTATE_COMPLETE
        DoEvents
    Loop
'---------------------------------------------------------------------------------------------------------
    
'ハザードマップにセルの住所を入力して検索
'---------------------------------------------------------------------------------------------------------
    Set txt = ie.document.getElementById("query")
        txt.Value = "東京都"
    Set inputTags = ie.document.getElementsByTagName("IMG")
        For Each inputTag In inputTags
            If InStr(inputTag.src, "https://disaportal.gsi.go.jp/hazardmap/image/skin/search.png") > 0 Then
                inputTag.Click
                Exit For
            End If
        Next
    
    Do While ie.Busy Or ie.ReadyState < READYSTATE_COMPLETE
        DoEvents
    Loop

'「洪水」ボタンをクリック
'---------------------------------------------------------------------------------------------------------
    Set inputTags2 = ie.document.getElementsByTagName("img")
        For Each inputTag2 In inputTags2
            If InStr(inputTag2.src, "image/skin/kouzui.png") > 0 Then
            inputTag2.Click
            Exit For
        End If
    Next

End Sub

Answer 1

2点問題があると思います。下記へ変更してやってみて下さい。
1.("img")訂正--->("IMG")
2.msgbox "ok"を追加して一旦画面を止める。
(IE側Load完了前にクリックが動いていると思われる。)
不明な場合は下記の様に、ｲﾐﾃﾞｨｴｲﾄ画面へ値を出してデバックして見て下さい。
Debug.Print inputTags2.uniqueNumber & " - " & inputTags2.src
'========================================================
'----------------------------
'「洪水」ボタンをクリック
'----------------------------
MsgBox "ok"
set inputTags2 = ie.document.getElementsByTagName("IMG")
'========================================================
＜下記は参考です＞
画面ボタンが選択されて動く状態が見えると思います。

'(Test_Sample_Miniature)
'----------------------------------
'「洪水」ボタンをクリック部分を変更
'----------------------------------
Dim inputTag_Kozui As IHTMLElement
Dim inputTag_Dosha As IHTMLElement
Dim inputTag_Tsunami As IHTMLElement
Dim inputTag_Douro As IHTMLElement

Set inputTags = ie.document.getElementsByTagName("IMG")
For Each inputTag In inputTags
	'
	'(デバック用記述)
	Debug.Print inputTag.uniqueNumber & " - " & inputTag.src
	'
	Select Case True
		Case InStr(inputTag.src, "image/skin/kouzui.png") > 0
			Set inputTag_Kozui = inputTag
		Case InStr(inputTag.src, "image/skin/dosha.png") > 0
			Set inputTag_Dosha = inputTag
		Case InStr(inputTag.src, "image/skin/tsunami.png") > 0
			Set inputTag_Tsunami = inputTag
		Case InStr(inputTag.src, "image/skin/douro.png") > 0
			Set inputTag_Douro = inputTag
	End Select
Next

'画面選択
'----------------------------------
Dim strNo As String
Do
strNo = InputBox("No：1～4", "処理選択", 1)
Select Case strNo
	Case "1"
		inputTag_Kozui.Click
	Case "2"
		inputTag_Dosha.Click
	Case "3"
		inputTag_Tsunami.Click
	Case "4"
		inputTag_Douro.Click
	Case Else
		Exit Do
End Select
Loop

Comments

[washio]

ご回答ありがとうございました。
ご指摘通り「IE側Load完了前にクリックが動いている」ことが原因だったと思われアドバイスいただいた内容にてうまく動作しいました。
誠にありがとうございました！

Answer 2

取得しているタグはIMGであり、inputタグではないため、クリックしても反応がないのでは？

Set inputTags = ie.document.getElementsByTagName("IMG")

            If InStr(inputTag.src, "https://disaportal.gsi.go.jp/hazardmap/image/skin/search.png") > 0 Then

IMGの親ノード(parentElement)を取得してクリックすることで動作しませんか？

Comments

[washio]

ご回答いただきましてありがとうございます。
ご指摘いただきましたコード部分２か所修正してもやはり動作しませんでした。。

ただし、parentElementの参照方法が若干怪しく、もとのコードからparentElementの参照
のための修正内容ご教示いただけますと大変幸いです。

理解悪く申し訳ございません。

[etsuhisa]

https://teratail.com/questions/79006
にparentElementの使用例があります。
これを参考にしてみるとよいと思います。
（VBAだとすぐに実機確認できないため、ご容赦願います。）

Answer 3

ダメもとですが、alt属性を利用してクリックする方法を試してみてください。
（修正後）If InStr(inputTag2.alt, "image/skin/kouzui.png") > 0 Then
（修正前）If InStr(inputTag2.src, "image/skin/kouzui.png") > 0 Then

Comments

[washio]

ご丁寧に回答いただきまして誠にありがとうございます。
結論から言うとご指摘箇所修正しても変わらずでした。
（InStr（・・・）が0となり、キャッチできていないようです。）

該当HPをF12開発者ツールで確認すると元々今回制御したいボタンが「index.html」のソース内になく、「hazardmaps.js」内に記載されており、そのため通常の「index.html」のソース内と制御方法に違いがあるのかな、等改めて考えましたがもう少しリサーチさせていただこうかと思います。
うまく制御できた住所入力と検索ボタン押下はいずれも「index.html」内の項目を使用しておりますので。。

[TanakaHiroaki]

そうですか。私の対応範疇を超えています。

VBAでJavaScriptを発動させる必要がありそうなので、以下サイトを参考にしてみてください。
https://mmm-program.com/vba-ie-js-listbox/

[washio]

ありがとうございます。
参考HPの内容も参照させていただきます。