【Access】複数レコードからのあいまい検索

Question

お世話になります。
フォーム画面の検索ボックスから得意先名を検索する際に「得意先名1」と「得意先名2」と2つのレコードからあいまい検索にしたいのですが、どのようなVBAにすれば良いのでしょうか。
ちなみに今は「得意先名1」と「得意先名2」別々に検索ボックスを設けてあります。
現在のVBAは以下です。

Private Sub cmd_filter_Click()

    Dim strFilter As String

    '[得意先名1]の条件指定
    If Nz(Me![得意先名1検索], "") <> "" Then
        strFilter = strFilter & _
                    " AND ([得意先名1]Like '*" & Replace(Me![得意先名1検索], "'", "''", , , vbBinaryCompare) & "*')"
    Me.cmd_filter.SetFocus
    End If
    
     '[得意先名2]の条件指定
    If Nz(Me![得意先名2検索], "") <> "" Then
        strFilter = strFilter & _
                    " AND ([得意先名2]Like '*" & Replace(Me![得意先名2検索], "'", "''", , , vbBinaryCompare) & "*')"
    Me.cmd_filter.SetFocus
    End If

DoCmd.OpenForm "F売上サブフォーム", acFormDS, , strFilter 'F売上サブフォームをデータシートで開く
    
End Sub

初歩的な質問かと存じますが何卒宜しくお願い致します。

Answer 1

現状のコードだと、strFilter の先頭に余分な " AND " が付いてますので、それを取り除けばいいでしょう。

Private Sub cmd_filter_Click()

    Dim strFilter As String

    '[得意先名1]の条件指定
    If Nz(Me![得意先名1検索], "") <> "" Then
        strFilter = strFilter & _
                    " AND ([得意先名1]Like '*" & Replace(Me![得意先名1検索], "'", "''", , , vbBinaryCompare) & "*')"
    End If

     '[得意先名2]の条件指定
    If Nz(Me![得意先名2検索], "") <> "" Then
        strFilter = strFilter & _
                    " AND ([得意先名2]Like '*" & Replace(Me![得意先名2検索], "'", "''", , , vbBinaryCompare) & "*')"
    End If

    strFilter = Mid(strFilter, 6) '6文字目以降を切り出す

    DoCmd.OpenForm "F売上サブフォーム", acFormDS, , strFilter 'F売上サブフォームをデータシートで開く

End Sub

Comments

[tkyk.]

hatena19様
お世話になります。
すみません。
私の質問が悪かったのですが、「得意先名1」と「得意先名2」の2つのレコードからひとつの検索ボックスを使ってあいまい検索するVBAを知りたいです。
おそらくORを使うのかと思いますが、どのように繋げれば良いのかわからず･･･

例：　㈱山田商会を検索　→　「得意先名1」　or　「得意先名2」のレコードから抽出

宜しくお願い致します。

[hatena19]

OR条件ですね。
ならば、
" AND " の部分を " OR " に修正、
Me![得意先名2検索] を Me![得意先名1検索] に修正、
strFilter = Mid(strFilter, 6) を strFilter = Mid(strFilter, 5) に修正
にすればいいでしょう。

[tkyk.]

hatena19様
ありがとうございます！
教えていただいた通りに試したところ思い通りになりました。
今後とも宜しくお願い致します。

[tkyk.]

hatena19様
お世話になります。
昨日ご回答いただきました上記の件ですが、OR条件を使いうまく行ったっかと思ったのですが
他の検索ボックスでも検索しようとするとうまく抽出できません。
下記例です。

例：　得意先が「山田商会」で商品名に「鉛筆」が含まれている商品を抽出したい。

この場合、教えていただいたOR条件で抽出すると「山田商会」は抽出できるのですが「鉛筆」だけではなく「山田商会」の全ての商品が出てきてしまいます。
どのように繋げれば良いのでしょうか。
度々申し訳ございませんが宜しくお願い致します。

[hatena19]

[得意先名1]と[得意先名2]は OR条件、それと商品名は AND条件ということになりますので、
strFilterの中身が下記のような条件式になるようにコードを修正すればいいでしょう。

([得意先名1] = '山田商会' OR [得意先名2] = '山田商会') AND [商品名]='鉛筆'

OR と AND ではANDの方が優先順位が高いので、OR条件の方を ( ) で囲まないと想定外の結果になります。

上記ヒントをもとにご自身でコードを書いてみてください。それでうまくいかないようでしたら、新規に質問を立て直して、ご自身で書いたコードを提示して、どのようしたいが、どのようにうまくいかないかを説明してください。

[tkyk.]

hatena19様
ありがとうございます！
教えていただいたコードで無事にうまく行きました。
いつもありがとうございます。助かります。