VBAでダブルコーテンションを上手く表示できない

Question

いつもお世話になっております。

現在、エクセルのVBAを使用して、セルの値からPHPの連想配列を作成しようとしています。

現在のコードは以下です。

Sub makephpFile()

    'カラム数と行数を格納
    Dim clms_cnt As Integer
    clms_cnt = Application.CountA(Range("1:1"))
    
    Dim row_cnt As Integer
    row_cnt = Application.CountA(Range("A:A"))

    'カラム名を配列に格納
    Dim clm_arr() As Variant 'lengthは条件によって変わる
    ReDim clm_arr(clms_cnt) As Variant
    
    For i = 1 To clms_cnt
        clm_arr(i - 1) = Cells(1, i)
    Next i
    
    'PHPの連想配列を作成
    Open "C:\Users\ユーザー名\Desktop\sample.php" For Append As #1
        For i = 2 To row_cnt
            Print #1, "["
                For j = 1 To clms_cnt
                    Print #1, clm_arr(j - 1) & " => " & Cells(i, j) // to be changed
                Next j
            Print #1, "]"
        Next i
    Close #1
End Sub

これを実行しますと以下のように指定したファイルに値が生成されます

[
column1 => 1
column2 => 2
column3 => 3
column4 => 4
column5 => 5
column6 => 6
column7 => 7
column8 => 8
]
[
column1 => 11
column2 => 12
column3 => 13
column4 => 14
column5 => 15
column6 => 16
column7 => 17
column8 => 18
]
[
column1 => 21
column2 => 22
column3 => 23
column4 => 24
column5 => 25
column6 => 26
column7 => 27
column8 => 28
]
[
column1 => 31
column2 => 32
column3 => 33
column4 => 34
column5 => 35
column6 => 36
column7 => 27
column8 => 38
]

// 理想は以下
[
"column1" => "31"
"column2" => "32"
"column3" => "33"
"column4" => "34"
"column5" => "35"
"column6" => "36"
"column7" => "27"
"column8" => "38"
]

形としてはほぼ完成なのですが、キーと値をダブルコーテーションでくくりたいです。
ですので「to be changed」の部分を以下のように変更しました

Print #1, """ & clm_arr(j - 1) & """ & " => " & """ & Cells(i, j) & """

このように記述すると、Cellsなどが文字列としてそのまま吐き出されてしまいます。
どのように記述すればよいでしょうか。

どうかご教授お願いします。

追記①

Print #1, "'" & clm_arr(j - 1) & "'" & " => " & "'" & Cells(i, j) & "'"

上記のようにシングルコーテーションなら上手くいきます。

Comments

[m.ts10806]

回答受付中のままになってますが。

Answer 1

Print #1, """" & clm_arr(j - 1) & """" & " => " & """" & Cells(i, j) & """"

のように、引用符の間に引用符自身を入れるときは引用符を２つ書きます。すると１つの引用符になります。

Print #1, """" & clm_arr(j - 1) & """ => """ & Cells(i, j) & """"

でいいですね。

#追記
カンマもいるのでは？

Print #1, """" & clm_arr(j - 1) & """ => """ & Cells(i, j) & ""","

Comments

[Chandler_Bing]

上手くいきました。ありがとうございました。