Excel VBA FindFirstメソッドでAccessへの検索をしたい。

Question

前提・実現したいこと

ExcelにBaseシートとsampleシートがあります。
sampleシートにはヘッダーありのcsvがA1から貼り付けられており
各行の7列目の値が「AAA」ならBaseシートの指定位置にその行の3列、5列目の値を書き込み
その書き込んだ値がデータベースにあるか検索するプログラムを作りたいです。

発生している問題・エラーメッセージ

実行時エラー '3077':
式の 構文エラー : 演算子がありません。

該当のソースコード

  Dim BaseRow As Integer
  Dim db As DAO.Database
  Dim rs As DAO.Recordset
  Dim Hinmei As String, Zuban As String

  BaseRow = 8
  Set db = OpenDatabase("C:\Users\○○\Desktop\Database_Sample.accdb")
  Set rs = db.OpenRecordset("Table1", dbOpenDynaset)

  For i = 2 To MaxRow
    If Cells(i, 7).Value = "AAA" Then
      Worksheets("Base").Cells(BaseRow, 2).Value = Cells(i, 3).Value
      Worksheets("Base").Cells(BaseRow, 16).Value = Cells(i, 5).Value
      
      Hinmei = Worksheets("Base").Cells(BaseRow, 2).Value
      Zuban = Worksheets("Base").Cells(BaseRow, 16).Value
      
      rs.FindFirst "3D品名 = 'Hinmei' AND 3D図番 = 'Zuban'"←「ここでエラーが発生する。」
      If rs.NoMatch Then
        Worksheets("Base").Cells(BaseRow, 54).Value = ""
      Else
        Worksheets("Base").Cells(BaseRow, 54).Value = rs![品目コード]
      End If
      rs.Close
      Set rs = Nothing
      Set db = Nothing
      
      BaseRow = BaseRow + 1
    End If
  Next i

試したこと

FindFirstの行でエラーが起きているので
引用符の分け方を変えたり、スペースの数を変えたりしましたが
同じエラー内容で、見当がつきません。。。

補足情報（FW/ツールのバージョンなど）

Windows7 64bit
Microsoft Visual Basic for Applications 7.1

Answer 1

Accessでは数字で始まるフィールド名は[]で囲む必要があります。
下記でどうでしょうか。

rs.FindFirst "[3D品名] = 'Hinmei' AND [3D図番] = 'Zuban'"

おっと、Hinmei Zuban は変数ですね。だとしたら文字列リテラル(""内)の外に出さないと単なる文字列です。

rs.FindFirst "[3D品名] = '" & Hinmei & "' AND [3D図番] = '" & Zuban & "'"

---

よく見たら、ループ内でレコードセットを閉じてしまってますね。
2回目のループでエラーになります。

      rs.Close
      Set rs = Nothing
      Set db = Nothing

これをNext iの後ろに移動させてください。

Comments

[clocolor12]

ご回答ありがとうございます。

ご指摘の通り編集したところ、期待通りの結果になりました。
延々と悩んでいたので助かりました。