Functionプロシージャで”修飾子が不正です。”のコンパイルエラーが出る

Question

Excelでデータを集めるツールを作成しています。
集めるところまではできたので、そのデータから文字列を抽出する関数を作成しているところで、エラーとなってしまいました。

エラーの内容

"修飾子が不正です。"といった内容のコンパイルエラーでした。
Logという引数に問題があるかと思ったのですが、
原因がよくわかりません。

実現したいこと

[000543]2019-07-02(2019-08-03/2020-02-14)
となっているデータを
2020-02-14
といったように抽出してセルに記載する。

コード

Dim Log As String
Dim Row, cntTd As Long
　　略
　　　　　　 '記事のDate情報を取得 
            For i = 0 To cntTd - 1
                If InStr(objIE.document.getElementsByTagName("td")(i).innerText, "Article Detail") > 0 Then
                    Log = objIE.document.getElementsByTagName("td")(i + 7).innerText
                    Cells(Row, 44).Value = Cleansing(PLog)
                    Exit For
                End If
            Next i
    略

Function Cleansing(ByVal Log As String) As String
'最終日のみ抽出する
Dim Str As Long
Dim Gal As Long
    Str = InStr(Log.Value, "/")
    Gal = InStr(Log.Value, ")")
    
    If Log = "" Then
        Exit Function
    Else
        Log.Value = Right(Log, Str)
        Log.Value = Replace(Log.Value, ")", "")
    End If
End Function

VBAについてはまだ勉強中なので、
いろいろおかしいところがあるかと思いますが、
ご助力いただけると幸いです。

Answer 1

Logという関数があるので、別名を使った方がよいでしょう。
名前を変えてどうなるかご確認ください。
またCleansing関数に渡しているPLogという変数がいきなり表れていますが大丈夫ですか？
直前の行ではLogに入れているようですが。
このような間違いを防ぐために、ファイル内行頭でOption Explicitを宣言するのをお勧めします。

Answer 2

エラーの原因は下記です。

Function Cleansing(ByVal Log As String) As String
                         '↑ Logは文字列(String)

'最終日のみ抽出する
Dim Str As Long
Dim Gal As Long
    Str = InStr(Log.Value, "/")
                '↑ 文字列にValueプロパティはないのでエラーになる
    Str = InStr(Log, "/")
                '↑ これでOK

'以下 Log.Value は Log に修正

---

Logという変数名は避けた方かいい、
Option Explicitを宣言すべき、
という点はttyp03さんも指摘している通りです。

---

さらに Cleansing関数ですが、.Valueを削除すればエラーはでなくなりますが、戻り値を設定していないので結果は常に""（空文字列）です。あと、"/"以降の切り出しはRightではなくMidです。これらを修正した関数が下記です。

Function Cleansing(ByVal Log As String) As String
'最終日のみ抽出する
Dim Str As Long
'Dim Gal As Long '未使用なので不要
    Str = InStr(Log, "/")
'    Gal = InStr(Log, ")") ' 未使用なので不要

    If Log = "" Then
        Exit Function
    Else
        Log = Mid(Log, Str + 1) 'Midに修正
        Log = Replace(Log, ")", "")
    End If
    Cleansing = Log '関数の戻り値を設定
End Function

---

自分が作成するなら下記のような感じにします。

Function Cleansing(ByVal vLog As String) As String
'最終日のみ抽出する
    If vLog = "" Or Not vLog Like "*/*" Then Exit Function

    Cleansing = Split(vLog, "/")(1)
    Cleansing = Replace(Cleansing, ")", "")
    
End Function