【awk】csvファイルをフィールド値で判定し2つのファイルに書き出す

Question

前提・実現したいこと

awkでcsvファイルをフィールドの値によって2つのファイルに分割したい。

・業務用システムが出力したcsvを分割（抽出）する
・windowsのコマンドプロンプトにてgawkスクリプトを利用
・フィールド2が空白ならAファイル、それ以外はBファイルに書き出す

発生している問題・エラーメッセージ

・if文で処理を分けたいがうまく書けず、
現状はAファイル、Bファイルをそれぞれ抽出しています

該当のソースコード

*** test.cmd
gawk -f "kuuhaku.awk" indata.csv  > kuuhaku.csv
gawk -f "igai.awk" indata.csv  > igai.csv


***kuuhaku.awk
BEGIN{
  FS = ",";
  OFS = ",";
 }
{
    if ( $2 == null ){
                  print($0) ;
}
END{
}


***`igai.awk
BEGIN{
  FS = ",";
  OFS = ",";
}
{
    if ( $2 != null ){
                  print($0) ;
　　 }
}
END{
}

### 試したこと
if else で書けないか試しましたがうまくいきませんでした。

### 補足情報
1980年代にMS-DOSツール（アスキー）に入っていたgrepやawkでcsvファイルをいじった記憶があります。
今回、仕事の必要に迫られ、昔似たようなことやったなあと思って探したところwindowsで走るgawkを見つけ、Webを参考に走らせています。
初歩的な質問で誠に恐縮です。よろしくお願いいたします。
・

Answer 1

回答としてはY.H.さんの通りですが、質問のコードでの注意です。
if($2 == null)ですが、awkにはnullというキーワードは無いので、単なる未定義変数です。
未定義変数は、数値として評価されたとき0で、文字列として評価されたときは空文字列です。

==の比較の際に$2が数字からなる文字列の場合は、数値として比較されますので、意図しない結果になります。

echo 1 0 | awk '{if($2 == null) print "Col 2 is Null"}' #ゼロとゼロの比較で真になる

空文字列かの比較対象には、""を使いましょう。

若干の修正例：

BEGIN{FS=OFS=",";} $2==""{print >out1;next}{print >out2}

if/elseで書くなら：

BEGIN{FS=OFS=",";} {if($2==""){print >out1}else{print >out2}}

Comments

[dos_1980_bat]

otn様

(1)空文字列判定について、アドバイスありがとうございました。
　　以降、””を使うようにします。

(2)ソースの修正とif-elseの件、回答ありがとうございました。
　いずれもうまく動きました。

** test1.awk
BEGIN{FS = OFS = ",";out1="file1.txt";out2="file2.txt"}
$2 == "" {print > out1;next}{print > out2}
END{}

** test2.awk
BEGIN{FS = OFS = ",";out1="file1.txt";out2="file2.txt"}
{if($2==""){print >out1}else{print >out2}}
END{}

※みなさまのご回答にてうまく動きました。ご回答に感謝いたします。
　空文字列判定についてコメントいただいたotn様をベストアンサーとさせていだだきました。

Answer 2

普段はLinuxですがgawkなのでこれで動くかと

BEGIN{FS=",";fa="fileA";fb="fileB"}{ot=fb;if($2=="")ot=fa;print $0 >ot}

gawk -f sample.awk indata.csv

windowsでも動きました
gawk -F, -v fa=fileA -v fb=fileB "{ot=fa; if(length($2)>0)ot=fb; print $0>ot}" indata.csv

Comments

[dos_1980_bat]

amura様、ありがとうございました。
回答いただいた「gawk -f sample.awk indata.csv」そのままでうまく動きました。
ご指導ありがとうございました。

Answer 3

$2 == "" {print > out1}と$2 != "" {print > out2}のようにパターン指定で$2を判定し
リダイレクトでファイルに出力してしまうのが手っ取り早いです。

$ cat input.csv
1,,AAA
1,3,BBB
2,,AAA
2,3,BBB
$ gawk -v out1=file1.txt -v out2=file2.txt 'BEGIN{FS = ",";OFS = ",";}$2 == "" {print > out1}$2 != "" {print > out2}' input.csv
$ cat file1.txt
1,,AAA
2,,AAA
$ cat file2.txt
1,3,BBB
2,3,BBB

Comments

[dos_1980_bat]

Y.H.様、ありがとうございました。回答を参考に以下の記述を試したらうまくいきました。
ご指導ありがとうございました。

** test1.awk
BEGIN{FS = ",";OFS = ",";out1="file1.txt";out2="file2.txt"}
$2 == "" {print > out1}
$2 != "" {print > out2}
END{}

** test1.cmd
gawk -f "test1.awk" input.csv

**コマンドプロンプトから、test.cmdを実行