processing,arduino ランダムで音を鳴らしたい

Question

arduinoとprocessingを連携させ、プッシュスイッチを押したら、processing上でランダムでdataファイル内のmp3が流れるというコードを書こうとしています。押したら設定したmp3（設定しているのは今のところ一つのみ）が流れるという所までは書けたのですが、ランダムで流すというコードが上手く書けずつまずいています。どこをどのようにプログラムを書き換えればよいでしょうか？

import cc.arduino.; // Arduinoライブラリ
import processing.serial.; // シリアル通信ライブラリ
import ddf.minim.*;
Minim minim;
AudioPlayer player;

Arduino arduino;
int pin = 2; // 入力ピン（デジタル）
String[]sound={"jingle.mp3"};

void setup() {
println(Arduino.list()); // シリアルポートの一覧を表示
arduino = new Arduino(this, Arduino.list()[0], 57600); // Arduinoの接続設定
arduino.pinMode(pin, Arduino.INPUT); // 入出力ピンの設定

minim=new Minim(this);
player=minim.loadFile("jingle.mp3");
}

void draw() {
int value = arduino.digitalRead(pin); // ピンの状態を読み取る

if (value == arduino.HIGH) { // 入力がHIGH（ボタンが押されているとき）
background(255,0,0);
player.play();
player.rewind();
}
else if (value == arduino.LOW) { // 入力がLOW
background(0,0,0);
}
}

void stop(){
player.close();
minim.stop();
super.stop();
}

Answer 1

Arduinoはないのでマウスクリックに置き換えさせていただきました。

import ddf.minim.*;

Minim minim;
AudioPlayer[] sounds;
int index;

void setup() {
  minim = new Minim(this);
  sounds = new AudioPlayer[] { 
    minim.loadFile("jingle.mp3"), 
    minim.loadFile("groove.mp3"), 
  };
}

void draw() {
  if (mousePressed) {
    background(255, 0, 0);

    sounds[index].pause();
    index = int(random(sounds.length));
    sounds[index].rewind();
    sounds[index].play();
  } else { 
    background(0, 0, 0);
  }
}

void stop() {
  for (AudioPlayer s : sounds) {
    s.close();
  }
  minim.stop();
  super.stop();
}

Comments

[karateka]

コメント遅れてすみません。arduinoと組み合わせて、実際に動かすことができました！ありがとうございました。

Answer 2

MP3のファイル名を配列ででも複数持っておいて、乱数出して選択すればいいんでは