Arduinoとprocessingシリアル通信。NullPointerExceptionの解決方法を教えてください!!

ボタンを押したらLEDとprocessingから映像を流したいです。ボタンを２つにした時から　NullPointerException　のエラーが頻発するようになりました。他のPCでも同じエラーが出たのでスペックの問題ではなくコードのミスがあると思うのですがよくわかりません、、
processing　の

  String[] message = receiveMessage.split(",", 0);

に対して　NullPointerException　とだけ出ます。

Arduinoのコード------------------------------------------------------------


//const byte buttonPin[SW_NUM] = {2,4};
//const byte ledPin[SW_NUM] =  {3,5};

const int buttonPin = 2;
const int ledPin =  8;

const int buttonPin2 = 3;
const int ledPin2 =  9;

int buttonState = 0; // BUTTONの状態を格納(LOW/HIGH)
int buttonState2 = 0;

int state = 0;// LEDの状態(0ならオフ、1ならオン)
int state2 = 0;

void setup() {
  Serial.begin(115200);
  pinMode(ledPin, OUTPUT);
  pinMode(buttonPin, INPUT_PULLUP); // Inputモードでプルアップ抵抗を有効に
  pinMode(ledPin2, OUTPUT);
  pinMode(buttonPin2, INPUT_PULLUP);
}
}

void loop() {
  buttonState = digitalRead(buttonPin);
  buttonState2 = digitalRead(buttonPin2);

  if (buttonState == LOW) {
    digitalWrite(ledPin, HIGH);
    state = 1;
  } else {
    digitalWrite(ledPin, LOW);
    state = 10;
  }

  if (buttonState2 == LOW) {
    digitalWrite(ledPin2, HIGH);
    state2 = 2;
  } else {
    digitalWrite(ledPin2, LOW);
    state2 = 12;
  }

  Serial.print(state);
  Serial.print(",");
  Serial.print(state2);
  Serial.println();

  delay(20);
}

processingのコード------------------------------

import processing.serial.*;
import processing.video.*; 

Movie movie; 
Movie movie2;

Serial myPort;
//int inByte;
String receiveMessage;

float tako;
float cmyk;

void setup() {
  size(1000, 1000);
      
  myPort = new Serial(this, ポート名, 115200);
  //myPort.clear();
  movie = new Movie( this, "tako.mp4");
  movie2 = new Movie( this, "cmyk.mp4");

  frameRate(60);
}

void draw() {

  if (receiveMessage != null && receiveMessage != "") {
    print(receiveMessage);
    println();
    
  String[] message = receiveMessage.split(",", 0);
    if (message.length >= 2)
    {
      tako = float( message[0] );
      cmyk = float( message[1] );

      print(tako == float( message[0]));
      print(" : " );
      print( cmyk == float( message[1] ));
      println();
    }
  }
  
  //映像を再生する--------------------------
  int j, k;
  j = 150;
  k = 6;

  //if (tako == 1.0) {
  //  image(movie, 0, 0, width/k, height/k);
  //  movie.play();
  //} else {
  //  movie.stop();
  //}

  //if (cmyk == 2.0) {
  //  image(movie2, j*2, 0, width/k, height/k);
  //  movie2.play();
  //} else {
  //  movie2.stop();
  //}
}


void movieEvent( Movie m ) {
  m.read();
}

void serialEvent(Serial p) {
  //delay(10);
  //inByte = p.read();
  receiveMessage = p.readStringUntil('\n');
}

y_waiwai

2019/12/26 21:50

そのエラーが出たときのprint内容を提示してください

sgc_o_

2019/12/26 23:19

10,12 true : true 10,12 true : true 10,12 true : true 10,12 true : true 10,12 true : true 10,12 true : true 10,12 NullPointerException Copied to the clipboard. Use shift-click to search the web instead. と出ました。

行動規範の内容に同意します

回答1件

ベストアンサー

Arduino側は私の手元ではシミュレータとして

Arduino
1float data;
2bool afterDp = false; //小数点以下のときtrueとする
3float weight = 1; //小数点以下の位
4
5void setup() {
6  Serial.begin(115200);
7}
8int state,state2;
9void loop() {
10  state=random(0,2);
11  state2=random(0,2)*10+2;
12  Serial.print(state);
13  Serial.print(",");
14  Serial.print(state2);
15  Serial.println();
16  delay(20);
17}

としておきます。

[実験]Processing側のdraw()の冒頭を

Processing
1void draw() {
2  String rcvBuf=receiveMessage;
3  if (receiveMessage != null && receiveMessage != "") {
4    print(receiveMessage);
5    println();
6    if(!rcvBuf.equals(receiveMessage)){
7      println("---------------------------");
8    }
9    String[] message = receiveMessage.split(",", 0);

としてみました。そうすると、

Text
1true : true
21,2
3
4true : true
50,12
6
7true : true
80,12
9
10---------------------------
11NullPointerException
12

という出力結果が観測出来ます。

serialEvent()は、メインスレッド(draw()関数の実行)とは関係なく、事象(シリアルデータの受信)が起こった時に即実行される。結果として、if (receiveMessage != null && receiveMessage != "") {のときのreceiveMessageとString[] message = receiveMessage.split(",", 0);のreceiveMessageは(厳密には先の式の２つのreceiveMessageの間でも)違うオブジェクトになってしまっている、ということが考えられます。

とりあえず、

Processing
1void draw() {
2  String rcvBuf=receiveMessage;
3  if (rcvBuf != null && rcvBuf != "") {
4    print(rcvBuf);
5    println();
6    String[] message = rcvBuf.split(",", 0);

としてみると、if (rcvBuf != null && rcvBuf != "") {で検査したrcvBufについて以降の処理が行われるので、同様のエラーは出なくなるようです(しばらく流した限りでは)
厳密には、

Processing
1Object obj=new Object();
2void draw() {
3  String rcvBuf="";
4  synchronized(obj) {
5    rcvBuf=receiveMessage;
6  }
7  if (rcvBuf != null && rcvBuf != "") {

また、イベントハンドラの方は

Processing
1void serialEvent(Serial p) {
2  synchronized(obj) {
3    receiveMessage = p.readStringUntil('\n');
4  }
5}

としてがっちりガードを固めておくべきなのかも知れません。(ちゃんと調査してません)

(この機にスレッドセーフ、という言葉について調べてみるといいかもしれません。)

[余談]
イベントハンドラserialEvent()の中でSerial.readStringUntil()メソッドを使っています。~~このメソッドは指定文字が来るまでひたすら待ちに入る可能性もあり、プログラムの進行を阻害することがあります。~~ (勘違いにつき以下削除、書き換え。readStringUntil()はブロックしない)

Serial.readStringUntil()は、公式のリファレンスによれば"Returns null if it doesn't find what you're looking for. "とのことなので、例えば"10,12\r\n"の'1'～'\r'を受信するとそれぞれserialEvent()が起動してreceiveMessageがNULLになる、ということでそのタイミングが先のif (receiveMessage != null && receiveMessage != "")と絡み合うとぬるぽで止まる、ということになるようですね。

投稿2019/12/27 00:04

編集2019/12/27 03:37