【Excel VBA】Application.GetOpenFilename を使用したファイル選択でのキャンセルした場合のエラー

Question

■環境
Excel vbaを使用

■やりたいこと
[csvファイルを開く]ダイアログボックスで、キャンセルを押した際エラーが出てしまう。
エラーを出さずにvbaを終了させるか、if文中のelseに振り分けたい。

■過去の質問
https://teratail.com/questions/231492

■エラー内容
実行エラー '1004':
申し訳ございません。False.xlsxが見つかりません。名前が変更されたか、移動や削除が行われた可能性があります。

■VBA

Sub vba()
    '変数
    Dim csv As String
    Dim csvname As String 'csvの名前
    Dim csvsheet As String 'csvのシート名

    'csvシートを選択する。
    ChDir "C:\"
    csv = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", Title:="CSVファイルの選択")
    If OpenFileName <> "False" Then
        Workbooks.Open csv
        'ファイル名を取得
        csvname = Dir(csv)
        'シート名を取得
        csvsheet = ActiveSheet.Name
    Else
        MsgBox "キャンセルされました"
    End If

End Sub

■試したこと
・If OpenFileName <> "False" Then
→If OpenFileName <> "False" And OpenFileName <> "False.xlsm" Then に変更
・If OpenFileName <> "False" Then
→If OpenFileName <> "False*" Then に変更

ご存知の方がいらっしゃれば教えていただけると幸いです。

Comments

[imihito]

モジュールの先頭に Option Explicit は存在しますか？
OpenFileName はどこでどのように定義されている識別子ですか？

[zazabi]

コメントありがとうございます。
存在していません。
調べてみたら便利なコマンドですね……。使用して修正してみます。

[imihito]

`Option Explicit`をモジュールの先頭に書いておくと、よくわからない名前を検知してコンパイルエラーを起こしてくれるようになります。
書き捨てのコードならともかく、きっちり処理を作成したい場合は、しょうもないミス(質問のような変数名のミスなど)を減らせるので有用です。

VBA のエディタのメニューバーの ツール(T) > オプション(O) > 編集タブ > 変数の宣言を強制する(R) をオンにしておくと、それ以降に作成したモジュールに`Option Explicit`が自動挿入されるようにもなります。

[zazabi]

追加のコメントありがとうございます。
そんな設定があるのですね！
さっそく設定して今後に生かさせていただきます。

Answer 1

マニュアルをよく読みましょう。
https://docs.microsoft.com/ja-jp/office/vba/api/excel.application.getopenfilename

GetOpenFilenameの戻り値は以下のように書かれています。

このメソッドは、ユーザーによって選択、または入力されたファイルの名前とパス名を返します。 引数 MultiSelect が True の場合は、選択されたファイルの名前の配列が返されます。 もし_MultiSelect_がTrueの場合、戻り値は選択されたファイル名の配列です（1つのファイル名しか選択されていない場合でも）。 入力が取り消された場合には False が返されます。

サンプルも載っていますので参考になります。
同じように修正するなら以下のようになります。

Sub vba()
    '変数
    Dim csv As String
    Dim csvname As String 'csvの名前
    Dim csvsheet As String 'csvのシート名

    'csvシートを選択する。
    ChDir "C:\"
    csv = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", Title:="CSVファイルの選択")
    If csv <> False Then
        Workbooks.Open csv
        'ファイル名を取得
        csvname = Dir(csv)
        'シート名を取得
        csvsheet = ActiveSheet.Name
    Else
        MsgBox "キャンセルされました"
    End If

End Sub

今回のダメだったところは、以下2点です。

• GetOpenFilenameの戻り値を使ってキャンセルかどうかを判定していない
• Falseが文字列になっている

ついでに言うとファイルを読み込んだ後の処理も無駄なことをしています。
シート名を取得したいなら以下のようにするとよいでしょう。

Dim wb As Workbook

Set wb = Workbooks.Open(csv)
'シート名を取得
csvsheet = wb.Worksheets(1).Name

Comments

[zazabi]

コメントありがとうございます。
追加のご指摘も修正させていただきます。

Answer 2

GetOpenFilenameメソッドがFalseを返すとき、受け取る変数の型が問題になります。

受け取る変数が文字列型(String)の場合
If OpenFileName <> "False" Then

受け取る変数がバリアント型(Variant)の場合
If OpenFileName <> False Then

のどちらかです。
VBAは内部的に自動型変換をしてくれることが多いですが、これを機会にチェックしてみるとよいでしょう。

---追記

やられた。さてはこれどっかのコピペを合体させてますね？
csv = Application.GetOpenFilename(...
としているのですから、当然
If csv <> "False" Then
としてください。OpenFileNameはどこにも存在してませんよ。

Comments

[zazabi]

コメントありがとうございます。
GetOpenFilename について、まだわかっていなかったみたいです。
他の方からもアドバイスを頂いたので、修正してみます。

[zazabi]

追記ありがとうございます。
色々調べて合体させて、手を加えている状態です……。
「Application.GetOpenFilename」というコマンドかと思っていたので、「OpenFilename」の部分が変数だと認識していませんでした。
ご指摘の通り、修正したら期待通りに機能しました。
大変ありがとうございます。