Unityで重なってる部分をずらして見えるようにしたい

Question

現在Unityで水に入れたら屈折するというのを再現するものを作成しています。
透明なシリンダーに棒を入れて重なっている部分だけずれて見えるようにしたいです。
また、棒は移動できるようにしたいのでずれるとこだけ別々で作るというのは無理です。
実現方法のアイデアでもよろしいのでヒントだけでも教えてもらえませんか？

使用しているのはUnity2018です。

Answer 1

どの程度の正確さが必要でしょうか?
そのまま透過させただけだと水らしさに欠けるので、ちょっとゆがみを加えたいといった程度なのか、あるいは屈折がゲームプレイ上または表現上重要な役割を持っていて、なるべく正確に屈折像を描画したいのかによって難しさが変わってきそうです。

屈折表現は未だにやっかいな部類の処理だと思います。正確に描こうと考え始めると...

• 光線はカメラに向いている面だけでなく背面でも屈折する可能性があるが、普通のレンダリング方法では背面の屈折を考慮した描画はやりにくい。
• 媒質の境界面を通過するたびに光線は屈折成分と反射成分に分かれ、計算するべき光の経路は境界面を通過するたびにねずみ算式に増える。
• 物体が落とす影も屈折の影響を受ける。プールの底に網目状の模様が生じたり虫眼鏡が太陽の光を集めるように、影の中に周りよりも明るくなる部分が生じたりするので（コースティック）、単純な光源からの遮蔽判定だけでは美しく描画できない。
• よりリアルな映像にしたい場合、光の波長によって屈折の程度が微妙に異なることによる色ズレ（分散、色収差）を考慮する必要がある。

といった面倒な処理を行うことになり、かなり重くなってしまうでしょう。できるだけ妥協して「軽量な屈折もどき」でごまかしたいところです。
屈折もどきであれば「Unity 屈折」あたりのキーワードで検索していただきますと、けっこう多くの参考情報が見つかるかと思います。
たとえば【Unity】GrabPassを用いた屈折(Refraction)シェーダー - Qiitaなどは面白そうですね。これを使って透明な円柱を通して不透明な角柱を見てみると下図のようになりました。

屈折像としてどの程度妥当なのか気になるかもしれません。さすがに実際に円柱型の水の塊を宙に浮かせて、突き刺した棒を波を立てずに回転させてみる...なんて実験はしたことはありませんので、本当はどんな屈折像になるのかは分かりませんが、レイトレーシング法ならば物理的にもっともらしい屈折像を描かせることができると思います。
外部ソフトウェアで似せて作ったシーンをレイトレーシング法でレンダリングしてみたところ、下図のような屈折像になりました。

ひずみ方がけっこう違っていることを見て取れるかと思います。この屈折像にもう少し近づけられないかと思い、下図のようなマテリアルを作成してみたところ...

Shader "Custom/FauxRefraction"
{
	Properties
	{
		_Color ("Color", Color) = (0.8, 0.5, 0.5, 0.1)
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
		_Glossiness ("Smoothness", Range(0,1)) = 0.5
		_Metallic ("Metallic", Range(0,1)) = 0.0
		_Refraction ("Refraction Index", Range(1.0, 3.0)) = 1.33
		_Distance ("Refraction Distance", Float) = 10.0
	}
	SubShader
	{
		Tags { "Queue"="Transparent" "RenderType"="Transparent" }

		GrabPass {}

		CGPROGRAM
		#pragma surface surf Standard alpha
		#pragma target 3.0

		sampler2D _MainTex;
		sampler2D _GrabTexture;
		sampler2D _CameraDepthTexture;

		struct Input
		{
			float2 uv_MainTex;
			float3 worldPos;
			float3 worldNormal;
		};

		half _Glossiness;
		half _Metallic;
		fixed4 _Color;
		float _Refraction;
		float _Distance;

		void surf(Input IN, inout SurfaceOutputStandard o)
		{
			#define DISTANCE_DIVISOR 16.0
			#define ITERATION_COUNT 32
			#define DEPTH_THRESHOLD 0.1
			#define EDGE_BLENDING_EXPONENT 4.0

			// まず屈折方向を求め...
			float3 eyeDir = normalize(IN.worldPos - _WorldSpaceCameraPos);
			float3 refractionDir = refract(eyeDir, normalize(IN.worldNormal), 1.0 / _Refraction);

			// 透明物体の表面を起点に、少しずつ屈折方向へ進みながら
			// デプスをチェックしていき、他のオブジェクトと衝突する点を求める
			float stride = _Distance / DISTANCE_DIVISOR;
			float s = 1.0;
			float4 refractionPos = float4(IN.worldPos, 1.0);
			float4 refractionViewPos;
			float4 refractionClipPos;
			float backgroundDepth;
			float hit = 0.0;
			for (int i = 0; i < ITERATION_COUNT; i++)
			{
				refractionPos.xyz += s * stride * refractionDir;
				refractionViewPos = mul(UNITY_MATRIX_V, refractionPos);
				refractionClipPos = mul(UNITY_MATRIX_P, refractionViewPos);
				backgroundDepth = LinearEyeDepth(SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, ComputeScreenPos(refractionClipPos)));
				if (s * (backgroundDepth + refractionViewPos.z) < 0.0)
				{
					// もし衝突が検出されたら、進行方向を逆転させ
					// 進行スピードを半減させて衝突しなくなるまで戻る
					// 衝突しなくなったら再び進行方向逆転・スピード半減...を繰り返し
					// なるべく正確な接触位置を求める
					hit = 1.0;
					s *= -1.0;
					stride *= 0.5;
				}
			}

			// このようなデプスだけを頼りにした衝突判定では、画面内のオブジェクトが奥行き方向に
			// どれだけの厚みを持っているかわからないので、本来であればオブジェクトの背後を
			// 素通りしていくべき屈折光経路まで衝突していると判定されてしまうことになる
			// しょうがないので「衝突している」と判定されたとしても、オブジェクトのデプスと
			// 検出された衝突点のデプスがある程度ずれているようなら誤検出と見なして検出を取り消す
			// また、判定境界の部分に発生するノイズを軽減するため、境界付近では判定値をなめらかに変える
			float depthDelta = abs(backgroundDepth + refractionViewPos.z);
			hit = hit * saturate(1.0 - pow(depthDelta / DEPTH_THRESHOLD, EDGE_BLENDING_EXPONENT));

			// 衝突していると判定された場合はグラブテクスチャの色を、そうでなければ
			// リフレクション用キューブマップの色を屈折色として採用する
			float4 grabTexColor = tex2Dproj(_GrabTexture, ComputeGrabScreenPos(refractionClipPos));
			float4 backgroundColor = UNITY_SAMPLE_TEXCUBE(unity_SpecCube0, refractionDir);
			float4 refractionColor = lerp(backgroundColor, grabTexColor, hit);
			fixed4 surfaceColor = tex2D(_MainTex, IN.uv_MainTex) * _Color;

			o.Albedo = surfaceColor.rgb * surfaceColor.a;
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = 1.0;
			o.Emission = refractionColor.rgb * surfaceColor.rgb * (1.0 - surfaceColor.a);
		}
		ENDCG
	}
}

Unity上でのレンダリング結果は下図のようになりました。

遠目で見ればいくらかはレイトレーシング法の結果に近づいたかもしれませんが、オブジェクトのエッジをきれいにしきれておらずブサイクなノイズが現れています（多少は軽減する措置は加えたのですが...）。総合的に見れば品質は悪化してしまいました。
結局、透明な物体の「透明っぽさ」を表現する目的でしたら@aa_debdebさんのようなシンプルな方法が計算コストも小さく実用的だと思います。