円が同じ動きをしてしまう

Question

前提・実現したいこと

・親の円を無くして子供の円だけにした場合を作り、どちらが見栄えが良いか比較したいと考えた。
円の処理の手順
1.実行時に円を5個程度指定した場所に描画する。
2.次の処理で弾ける様に表現する為に、指定した場所ごとに円を１０個程度同じ場所に描画する。
3.マウスクリックで全ての円が物理演算で動き出し、やがて下に落ちて溜まっていく。
4.さらにクリックしても追加の円は描画せず、単純に下に溜まっている円が再び動くだけにする。
5.いちいちプログラムを閉じなくても良い様に、クリックまたはキー操作で描画をリセットをする。
※最終的に手を加えなければ下に円が溜まり、初期位置には何も描画されていないという絵にしたい。

発生している問題・エラーメッセージ

単純に位置をずらしたellipseを増やすと、増やした数だけ横に連なって同じ動きをしてしまう。
例えば、実行時に描画する円を5個増やした場合は位置のずれた5つの円が描画される。←ここまでは良し
しかし、クリックすると横に5個連なった円の塊が10個動き出してしまう。←原因不明
何故横に連なってしまうのか分かりませんが、とにかくバラバラに動いて欲しいです。
他にも問題が発生しなんとか自己解決しましたが、どうしてもこの問題だけ分かりませんでした。すみません。

※該当のソースコードはプログラム全てでは無く、問題解決に必要であろう部分のみ載せています。
　ご要望があれば、追記で全体のプログラムを載せます。宜しくお願い致します。

該当のソースコード

import ddf.minim.*;
import ddf.minim.analysis.*;
import ddf.minim.effects.*;
import ddf.minim.signals.*;
import ddf.minim.spi.*;
import ddf.minim.ugens.*;

Minim minim;
AudioPlayer player;
float playerIn;
float x;
float y;
int buffersize = 512;

int NUM = 10; //パーティクルの数
//パーティクルを格納する配列
ParticleVec2[] particles = new ParticleVec2[NUM];

void setup() {
  fullScreen();
  smooth();
  frameRate(60);
  colorMode(HSB, 360, 100, 100, 100);

  minim = new Minim(this);
  player = minim.loadFile("Mountain.mp3");
  player.loop();

  for (int i = 0; i < NUM; i++) {
    particles[i] = new ParticleVec2();
    particles[i].location.set(width/2.0, height/2.3);
  }
}

void draw() {
  //背景をフェードさせる
  fill(0, 30);
  rect(0, 0, width, height);
  fill(100);
  
  //木
  colorMode(RGB);
  Tree(30, width/2, height, PI, width/8);

  //パーティクルの位置を更新して描画
  for (int i = 0; i < NUM; i++) {
    particles[i].update();
    particles[i].draw();
    particles[i].bounceOffWalls();
  }

  //地面
  fill(#959592);
  rect(0, 1030, 2000, 50);
}

//木の生成
void Tree(float strokeWeight, float x, float y, float rotate, float length) {
  pushMatrix();  //座標を一時保存
  translate(x, y);  //座標移動
  rotate(rotate);  //座標回転
  strokeWeight(strokeWeight);  //線の輪郭線の太さ
  stroke(#E57409);  //線の色
  line(0, 0, 0, length);  //線の描画,配列の長さ
  popMatrix();  //変更した座標を元に戻す
  if (strokeWeight<2)return;
  if (x%5>3 && strokeWeight<3)return;
  Tree(strokeWeight*2/3, x-sin(rotate)*length, y+cos(rotate)*length, rotate-PI/10, length*2/3);
  Tree(strokeWeight*2/3, x-sin(rotate)*length, y+cos(rotate)*length, rotate+PI/10, length*2/3);
}

void mouseClicked() {
  //パーティクルの数だけくりかえし
  for (int i = 0; i < NUM; i++) {

    //ランダムに加速度を設定 - ランダムの範囲を中央からの距離に
    float angle = random(PI * 2.0);
    float length = random(20);
    float posX = cos(angle) * length;
    float posY = sin(angle) * length;
    particles[i].acceleration.set(posX, posY);
    //下向きに0.1の重力
    particles[i].gravity.set(0.0, 0.1);
    //摩擦を0.01に
    particles[i].friction = 0.01;
    PVector force = new PVector(cos(angle) * length, sin(angle) * length);
    particles[i].addForce(force);
  }
}

void keyPressed(){
   for (int i = 0; i < NUM; i++) {
    particles[i] = new ParticleVec2();
    particles[i].location.set(width/2.0, height/2.3);
   }
}

void stop() {
  minim.stop();
  super.stop();
}


     // ↑メイン　↓物理演算


// 物体の運動を計算(運動方程式)
class ParticleVec2 {
  PVector location; // 位置
  PVector velocity; // 速度
  PVector acceleration; // 加速度
  PVector gravity; // 重力
  float mass; // 質量
  float friction; // 摩擦力
  PVector min; // 稼動範囲(min)
  PVector max; // 稼動範囲(max)
  float radius; // パーティクル半径
  // コンストラクタ
  ParticleVec2() {
    radius = 4.0;
    mass = 1.0; // 質量は1.0に設定する
    friction = 0.01; // 摩擦力を0.01に設定する
    // 位置、速度、加速度を初期化する
    location = new PVector(0.0, 0.0);
    velocity = new PVector(0.0, 0.0);
    acceleration = new PVector(0.0, 0.0);
    gravity = new PVector(0.0, 0.0); // 重力なし
    // 稼動範囲を設定する
    min = new PVector(0.0, 0.0);
    max = new PVector(width, height);
  }
  // 運動方程式から位置を更新
  void update() {
    acceleration.add(gravity); // 重力を加える
    velocity.add(acceleration); // 加速度から速度を算出する
    velocity.mult(1.0 - friction); // 摩擦力から速度を変化させる
    location.add(velocity); // 速度から位置を算出する
    acceleration.set(0, 0); // 加速度を0にリセット(等速運動)する
  }

 //問題の部分↓
  void draw() {
    playerIn = player.mix.level()*200; //minimを使って円の大きさと色を変えています
    noStroke();
    fill(random(255), random(255), random(255), 255);
    
    ellipse(location.x, location.y, playerIn, playerIn);
    //translate(location.x/1.4,location.y/2);//位置はずれたが同じ動きでバウンド位置もずれる
    //ellipse(location.x, location.y, playerIn, playerIn);
    
  }
  

  // 壁でバウンドさせる
  void bounceOffWalls() {
    if (location.x > max.x) {
      location.x = max.x;
      velocity.x *= -1;
    }
    if (location.x < min.x) {
      location.x = min.x;
      velocity.x *= -1;
    }
    if (location.y > max.y) {
      location.y = max.y;
      velocity.y *= -1;
    }
    if (location.y < min.y) {
      location.y = min.y;
      velocity.y *= -1;
    }
  }
  // 壁を突き抜けて反対から出現させる
  void throughWalls() {
    if (location.x < min.x) {
      location.x = max.x;
    }
    if (location.y < min.y) {
      location.y = max.y;
    }
    if (location.x > max.x) {
      location.x = min.x;
    }
    if (location.y > max.y) {
      location.y = min.y;
    }
  }
  //力を加える
  void addForce(PVector force) {
    force.div(mass); //力と質量から加速度を算出
    acceleration.add(force); //力を加速度に加える
  }
}

試したこと

translateを使って座標軸をずらしてみたが、同じ動きをする上に壁の位置までずれているのか、画面外に行ってしまう円もある。

補足情報（FW/ツールのバージョンなど）

processing3.5.3

Comments

[y_waiwai]

このままではコードが読みづらいので、質問を編集し、<code>ボタンを押し、出てくる’’’の枠の中にコードを貼り付けてください

[msw]

すみません。修正しました。

[TN8001]

メイン側のsetupとdrawも欲しいです。

[thkana]

そのプログラムで、
> 増やした数だけ横に連なって同じ動きをしてしまう
というのが観察できないのですが?
(minimとか本質に関係ないならさっさと外して欲しい、なんて思ったりもするけれど)

Answer 1

ellipse(location.x, location.y, playerIn, playerIn);
//translate(location.x/1.4,location.y/2);//位置はずれたが同じ動きでバウンド位置もずれる
//ellipse(location.x, location.y, playerIn, playerIn);

locationをいじってもvelocityやaccelerationが同じなので、同じ動きになってしまいます。

ParticleVec2は円ひとつを表すオブジェクトですから、円の個数分作らなければなりません。

最初の5個とそれぞれの10個、合計55個のParticleVec2を作ります。
配列に入れるときに11個ずつ同じ位置になるようにすれば、後はほとんど変える必要はありません。

キープレスでリセットしたいので配列に入れる処理を関数に分け、setupとkeyPressedで呼ぶようにします。

//省略

int NUM = 5 + 5 * 10; //パーティクルの数 55個 最初の5個+それぞれに10個
ParticleVec2[] particles = new ParticleVec2[NUM];

void setup() {
  fullScreen();
  smooth();
  frameRate(60);
  colorMode(HSB, 360, 100, 100, 100);

  minim = new Minim(this);
  player = minim.loadFile("Mountain.mp3");
  player.loop();

  resetParticles();
}

void resetParticles() {
  // forいっこで書けるけど調整しやすいようにグループごとに設定した
  int w=width/12;
  int offset=width/12*3;
  for (int i = 0; i < 11; i++) { // 左端
    particles[i] = new ParticleVec2();
    particles[i].location.set(w+offset, height/2.3);
  }
  for (int i = 11; i < 22; i++) {
    particles[i] = new ParticleVec2();
    particles[i].location.set(w*2+offset, height/2.3);
  }
  for (int i = 22; i < 33; i++) { // 真ん中
    particles[i] = new ParticleVec2();
    particles[i].location.set(w*3+offset, height/2.3);
  }
  for (int i = 33; i < 44; i++) {
    particles[i] = new ParticleVec2();
    particles[i].location.set(w*4+offset, height/2.3);
  }
  for (int i = 44; i < 55; i++) { // 右端
    particles[i] = new ParticleVec2();
    particles[i].location.set(w*5+offset, height/2.3);
  }
}

void keyPressed() {
  resetParticles();
}
//省略

Comments

[msw]

TN様ありがとうございます。
なるほど、location以外も同じだからいくらlocationを弄っても駄目だったんですね。
繰り返し処理だけでやろうとしていたのが間違いでした。これからは配列を使ってみる事を意識します。
また、お手数をお掛けしたメインプログラムの追加に関しても、初めから全部載せる様にします。

↓ご要望を送ってくださった他の方へのコメントです。
問題に関係ないminimを入れているのは、まさか実行をして原因を調べる方が居るとは考えていなかったからです。また、実行しても言っている問題と一致しないのは、試したことに書いてある通り別の方法を試した後のものを載せているからです。試す前と試した後のどちらを載せた方が良いか理解出来ておらず、大変申し訳ございませんでした。次からは、試す前のものなのか試した後のものなのかも記載致します。要望を送ってくださった皆様ありがとうございました。