【VBA】動的配列内での項目別最大値の抽出方法について

Question

##質問

VBAにてCSVデータから特定の条件で抽出作業を施し、
それらのデータでn行×4列のリストを作成しました。
![

上記のリストにおいて，
各項目別の最大値(ex.項目名Aでの高さの最大値)となるリスト番号を取得するには
どのようにコーディングすべきでしょうか？

if文で条件分岐を行うなど色々トライしてみたのですが、
うまく動かず苦戦しております。コードは以下の通りです。

方針は
0. myArray()にてn行×4列の配列を作成
0. まずは項目名がAの場合のみのn行×4列の配列を作成
0. 2.にて生成した配列の中から「長さ」・「深さ」のデータだけのn行×1列の配列作成
0. 3.の中で最大となる行番号とデータを取得する
を考えておりました。

• myArray(n)の中身は以下の通りです

myArray(n)
L myArray(n,1)
L myArray(n,2)
L myArray(n,3)
L myArray(n,4)

ex)
myArray(1)
L myArray(1,1)=A
L myArray(1,2)=n1
L myArray(1,3)=66
L myArray(1,4)=91
といった具合です。

• コードは以下の通りです。

'Rangeの定義
Dim myRange As Range
Set myRange = Range("A1:An","D1:Dn")

'配列myArrayを生成
Dim myArray As Variant
myArray = myRange

'配列を定義
Dim Array_A_len_pre() As Variant
Dim Array_A_len() As Variant

'ループ変数
Dim i As Long
        
'if文で格納する
For i = 1 To n
  　If myArray(i, 1) = "A" Then
　　　　'長さののみの配列を生成
    　　ReDim Preserve Array_A_len_pre(i)
    　　Array_A_len_pre(i) = myArray(i, 4)
        
  　　　'ループ変数
    　　Dim j As Long
                               
    　　'Array_A_len_pre()のempty値を除去し配列を再生成
    　　For j = 0 To n
       　　　If Array_A_len_pre(j) <> "" Then
          　　　ReDim Preserve Array_A_len(j)
          　　　Array_A_len(j) = Array_A_len_pre(i)
       　　　End If
    　　Next
　　　　========================以下質問内容です===================


  　End If
Next

ご教示いただけますと幸いです。
よろしくお願いいたします。

Comments

[Orlofsky]

教授 → 教示

[Orlofsky]

ここの掲示板は丸投げは嫌われるので、不完全で良いからできている分だけでいいから、質問にプログラム・コードを https://teratail.com/help/question-tips#questionTips3-7 の [コード] で提示してください。

[tatsu99]

>それらのデータでn行×4列のリストを作成しました。
どうやって、そのリストを作成したのでしょうか。そのソースを提示してください。
（Array(1)~Array(n)を作成した個所のソースです）

Answer 1

もし質問内容が件名と違っていて、質問本文に記載されている「各項目名の最大値となるリスト番号」を取得したいのであればtatsu99さんのソースにもう一工夫必要となります。
たとえば、
１）キーを項目名、値をリスト番号にしたディクショナリを別に用意するとか
２）dicHの値を"リスト番号_高さ最大値"にして、最大値判定の際に_の右側の高さ最大値を使うとか
３）高さ最大値を抽出した後もう一度ループして項目と最大値が一致する行を検索するとか
など。

１）が良いですかね。

    Dim dicHNo As Object  'キー：項目名　値：最大高さのリスト番号 を追加
    Set dicHNo = CreateObject("Scripting.Dictionary")

　　If dicH.exists(wkey) = False Then
       dicH.add wkey, myArray(i, 3)  '修正
       dicHNo.add wkey, i            '追加

    If dicH(wkey) < myArray(i, 3) Then
        dicH(wkey) = myArray(i, 3)
        dicHNo(wkey) = i            '追加

    Debug.Print wkey, dicH(wkey), dicHNo(wkey)

出力結果
A 98 2
B 61 3
D 42 4

Comments

[tatsu99]

取得するのはリスト番号でしたね。ご指摘ありがとうございました。

[MrIgat]

最初のキー出現時の登録、ご注意ください。
dicObject.add key,value

[tatsu99]

＞最初のキー出現時の登録、ご注意ください。
ご指摘ありがとうございます。
正式なドキュメントで確認できなかったのですが、
最初のキー出現時の登録時、
dicObject.add key,value　と
dicObject[key] = value
は同じ結果になるはずです。
http://www.koikikukan.com/archives/2014/02/27-015555.php
にそれに似たサンプルがあります。
どちらを使うかは趣味の問題ですが。
すみません。完全に同じではないですね。
valueが.NET FrameworkのSystem.Collections.ArrayList
のような場合は、dicObject.add key,value　の方法でないとエラーになりますね。

[MrIgat]

大変失礼いたしました。下記の注釈に「item を変更するときにkey がない場合は、指定した newitem で新しい key が作成されます」と記載ありますね。
https://docs.microsoft.com/ja-jp/office/vba/language/reference/user-interface-help/item-property-dictionary-object

[8787]

アドバイスいただきまして誠にありがとうございます。
また、質問の内容が曖昧で申し訳ありませんでした。

出力したかった情報をそれぞれ取得できる方法をご指導いただき大変助かりました。
ありがとうございます。

Answer 2

dictionary（連想配列）を使った例です。
n=5として、作成してみました。

Public Sub test()
    'Rangeの定義
    Dim n As Long
    n = 5
    Dim myRange As Range
    Set myRange = Range("A1:A" & n, "D1:D" & n)

    '配列myArrayを生成
    Dim myArray As Variant
    myArray = myRange

    '連想配列の定義
    Dim dicH As Object  'キー：項目名　値：高さ
    Set dicH = CreateObject("Scripting.Dictionary")
    'ループ変数
    Dim i As Long
    'キー変数
    Dim wkey As Variant
    'if文で格納する
    For i = 1 To n
        wkey = myArray(i, 1)
        If dicH.exists(wkey) = False Then
            '最初のキー出現時、その高さを登録
            dicH(wkey) = myArray(i, 3)
        Else
            '以降のキー出現時、大きいほうで高さを更新
            If dicH(wkey) < myArray(i, 3) Then
                dicH(wkey) = myArray(i, 3)
            End If
        End If
    Next
    '全てのキーと値を出力する
    For Each wkey In dicH
        Debug.Print wkey, dicH(wkey)
    Next
End Sub

以下、実行結果です。（シート内容はあなたの提示された画像と同じです）
A 98
B 61
D 42

Comments

[8787]

返信遅くなりまして申し訳ありません。
辞書を活用する発想は全くございませんでしたので勉強になりました。
アドバイスいただきましてありがとうございました。

Answer 3

コーディング方法の一つの案として私なら、
0. 高さ最大値、高さ最大値のリスト番号、長さの最大値、長さの最大値のリスト番号の4つのメンバーを持つクラスAを作成する。
0. キーを項目名、値をクラスAとしたディクショナリー使い、Arrayをループして項目ごとの高さ最大値のリスト番号と長さの最大値のリスト番号を抽出する。

同じ最大値をもつリスト番号が複数ある場合、取得するリスト番号を、どれか一つにするか全てにするかによって抽出の仕方やクラスAの作り方に工夫が必要となります。