質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

89.13%

VBAファンクション定義で「ユーザ定義型が定義されていません」とコンパイルエラーが表示される。

受付中

回答 1

投稿

  • 評価
  • クリップ 0
  • VIEW 1,124

Surface-Yuki

score 34

環境:Win10
やりたいこと:Wordで作成した文書内の漢字にルビを振りたい。マニュアルで1つずつ変換するのが大変なので、マクロで自動化したい。

ファンクションを実行すると、以下の部分で
コンパイルエラー:ユーザ定義型が定義されていません。と表示されます。

ネットで調べると、参照設定からMicrosoft Word15.0 Object Libraryを追加すれば治るというページがいくつかありましが、それだけでは治りませんでした。
以下がエラーの部分、全体のコードも貼ってあります。

Private Function GetElement(ByVal uiAuto As CUIAutomation, _
                            ByVal elmParent As IUIAutomationElement, _
                            ByVal propertyId As Long, _
                            ByVal propertyValue As Variant, _
                            Optional ByVal ctrlType As Long = 0)

VBA詳しいかたいらっしゃいましたら、ご回答お願いします。

'ThisDocument
Option Explicit

Private d As Object

Public Sub Rubi()
  If Selection.Start <> Selection.End Then
    Set d = CreateObject("htmlfile")
    Set d.parentWindow.onhelp = Me
    d.parentWindow.SetTimeout "onhelp.ExecSetPhoneticDialog()", 100, "VBScript" 'setTimeoutで時間差実行
    Application.Dialogs(wdDialogPhoneticGuide).Show
  End If
End Sub

Public Sub ExecSetPhoneticDialog(Optional ByVal dummy As Long = 0)
'文字単位,右揃え,オフセット:20,フォント:メイリオ,フォントサイズ:15
  SetPhoneticDialog False, False, "右揃え", 20, "メイリオ", 15
End Sub

Private Sub SetPhoneticDialog(Optional ByVal flgClearReadingsButton As Boolean = False, _
                              Optional ByVal flgGroup As Boolean = True, _
                              Optional ByVal alignmentValue As String = "", _
                              Optional ByVal offsetValue As Long = 0, _
                              Optional ByVal fontValue As String = "", _
                              Optional ByVal sizeValue As Long = 0)
'[ルビ]ダイアログ操作
'※UIAutomationClient(UIAutomationCore.dll)要参照
'  引数説明
'    flgClearReadingsButton : True : ルビの解除
'    flgGroup : True : 文字列全体, False : 文字単位
'    alignmentValue : 配置
'    offsetValue : オフセット
'    fontValue : フォント
'    sizeValue : サイズ

  Dim uiAuto As CUIAutomation
  Dim elmRoot As IUIAutomationElement
  Dim elmPhoneticDialog As IUIAutomationElement 'ルビダイアログ
  Dim elmGroupButton As IUIAutomationElement '文字列全体
  Dim elmMonoButton As IUIAutomationElement '文字単位
  Dim elmClearReadingsButton As IUIAutomationElement 'ルビの解除
  Dim elmOkButton As IUIAutomationElement 'OK
  Dim elmAlignmentComboBox  As IUIAutomationElement '配置
  Dim elmRubyEdit As IUIAutomationElement 'ルビ
  Dim elmOffsetEdit As IUIAutomationElement 'オフセット
  Dim elmFontEdit As IUIAutomationElement 'フォント
  Dim elmSizeEdit As IUIAutomationElement 'サイズ
  Dim accAlignmentComboBox As IAccessible
  Dim aptn As IUIAutomationLegacyIAccessiblePattern
  Dim vptn As IUIAutomationValuePattern
  Dim iptn As IUIAutomationInvokePattern
  Dim i As Long

  Set uiAuto = New CUIAutomation
  Set elmRoot = uiAuto.GetRootElement

  '[ルビ]ダイアログ取得
  While elmPhoneticDialog Is Nothing
    Set elmPhoneticDialog = GetElement(uiAuto, elmRoot, UIA_NamePropertyId, "ルビ", UIA_WindowControlTypeId)
    DoEvents
  Wend
  '[文字列全体]ボタン取得
  Set elmGroupButton = GetElement(uiAuto, elmPhoneticDialog, UIA_NamePropertyId, "文字列全体(G)", UIA_ButtonControlTypeId)
  '[文字単位]ボタン取得
  Set elmMonoButton = GetElement(uiAuto, elmPhoneticDialog, UIA_NamePropertyId, "文字単位(M)", UIA_ButtonControlTypeId)
  '[ルビの解除]ボタン取得
  Set elmClearReadingsButton = GetElement(uiAuto, elmPhoneticDialog, UIA_NamePropertyId, "ルビの解除(C)", UIA_ButtonControlTypeId)
  '[OK]ボタン取得
  Set elmOkButton = GetElement(uiAuto, elmPhoneticDialog, UIA_NamePropertyId, "OK", UIA_ButtonControlTypeId)
  '[配置]コンボボックス取得
  Set elmAlignmentComboBox = GetElement(uiAuto, elmPhoneticDialog, UIA_NamePropertyId, "配置(L):", UIA_ComboBoxControlTypeId)
  '[ルビ]エディットボックス取得
  Set elmRubyEdit = GetElement(uiAuto, elmPhoneticDialog, UIA_AutomationIdPropertyId, "19")
  '[オフセット]エディットボックス取得
  Set elmOffsetEdit = GetElement(uiAuto, elmPhoneticDialog, UIA_AutomationIdPropertyId, "35")
  '[フォント]エディットボックス取得
  Set elmFontEdit = GetElement(uiAuto, elmPhoneticDialog, UIA_AutomationIdPropertyId, "1792")
  '[サイズ]エディットボックス取得
  Set elmSizeEdit = GetElement(uiAuto, elmPhoneticDialog, UIA_AutomationIdPropertyId, "1796")

  '[ルビの解除]ボタンクリック
  If flgClearReadingsButton = True Then
    Set iptn = elmClearReadingsButton.GetCurrentPattern(UIA_InvokePatternId)
    iptn.Invoke
  End If
  '[文字単位]設定
  If flgGroup = False Then
    Set iptn = elmMonoButton.GetCurrentPattern(UIA_InvokePatternId)
    iptn.Invoke
  End If

  '[配置]コンボボックス設定
  If alignmentValue <> "" Then
    Select Case alignmentValue
      Case "中央揃え", "均等割り付け 1", "均等割り付け 2", "左揃え", "右揃え"
        Set aptn = elmAlignmentComboBox.GetCurrentPattern(UIA_LegacyIAccessiblePatternId)
        Set accAlignmentComboBox = aptn.GetIAccessible
        For i = 1 To accAlignmentComboBox.accChildCount
          If accAlignmentComboBox.accName(i) = alignmentValue Then
            accAlignmentComboBox.accDoDefaultAction i
            Exit For
          End If
        Next
    End Select
  End If

  '[オフセット]エディットボックス設定
  If offsetValue <> 0 Then
    Set vptn = elmOffsetEdit.GetCurrentPattern(UIA_ValuePatternId)
    vptn.SetValue CStr(offsetValue)
  End If
  '[フォント]エディットボックス設定
  If fontValue <> "" Then
    Set vptn = elmFontEdit.GetCurrentPattern(UIA_ValuePatternId)
    vptn.SetValue fontValue
  End If
  '[サイズ]エディットボックス設定
  If sizeValue <> 0 Then
    Set vptn = elmSizeEdit.GetCurrentPattern(UIA_ValuePatternId)
    vptn.SetValue CStr(sizeValue)
  End If

  If Len(Trim(elmRubyEdit.GetCurrentPropertyValue(UIA_ValueValuePropertyId))) < 1 Then
    elmRubyEdit.SetFocus
  Else
    '[OK]ボタンクリック
    Set iptn = elmOkButton.GetCurrentPattern(UIA_InvokePatternId)
    iptn.Invoke
  End If
End Sub

Private Function GetElement(ByVal uiAuto As CUIAutomation, _
                            ByVal elmParent As IUIAutomationElement, _
                            ByVal propertyId As Long, _
                            ByVal propertyValue As Variant, _
                            Optional ByVal ctrlType As Long = 0)
  Dim cndFirst As IUIAutomationCondition
  Dim cndSecond As IUIAutomationCondition

  Set cndFirst = uiAuto.CreatePropertyCondition(propertyId, propertyValue)
  If ctrlType <> 0 Then
    Set cndSecond = uiAuto.CreatePropertyCondition(UIA_ControlTypePropertyId, ctrlType)
    Set cndFirst = uiAuto.CreateAndCondition(cndFirst, cndSecond)
  End If
  Set GetElement = elmParent.FindFirst(TreeScope_Subtree, cndFirst)
End Function
  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 過去に投稿した質問と同じ内容の質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 1

0

おそらく下記のページを参考にされたのかと思いますが、

[Word VBA]ルビ(ふりがな)ダイアログの操作に挑む | 初心者備忘録

そこに、

※ UIAutomationClient(UIAutomationCore.dll)要参照

との記述がありますが、UIAutomationClientの参照設定はしましたか。

参照設定の仕方については下記をご参考に。

VBA 参照設定

投稿

編集

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2019/11/13 17:13

    はい。初心者備忘録を参考に作りました。
    UIAutomationClientを参照から追加したところ、先ほどのエラーは消えました。
    しかし、コンパイルエラー:Meキーワードの使用方法が不正です。
    という新たなエラーが出ました。

    キャンセル

  • 2019/11/13 18:55

    リンク先に
    > ※ [ThisDocument]に記述
    という説明もありますが、
    コードを ThisDocument に記述してますか。

    キャンセル

15分調べてもわからないことは、teratailで質問しよう!

  • ただいまの回答率 89.13%
  • 質問をまとめることで、思考を整理して素早く解決
  • テンプレート機能で、簡単に質問をまとめられる
  • トップ
  • VBAに関する質問
  • VBAファンクション定義で「ユーザ定義型が定義されていません」とコンパイルエラーが表示される。