Access VBA コントロール名を変数で指定

Question

前提・実現したいこと

Access VBAにてコントロール名を変数にて指定し、Value = などの処理を実行するシステムを作成しています。
この方法をフォームに設置しているサブフォームエリア内のコントロールに対して適用させようとしたら、エラーが発生しました。

発生している問題・エラーメッセージ

フォームに設置しているコントロールには適用できましたが、フォームに設置しているサブフォームエリア内のコントロールに適用するにはどのように修正すればよろしいでしょうか？

該当のソースコード

Dim FormName, TxtName As String
'親フォーム名とサブフォームエリア名を変数に格納する
FormName = "F02_2_注文画面.F02_1_入力画面"
'テキストボックス名を変数に格納する
TxtName = "Txt_b1"
'親フォームに設置しているサブフォームエリア内のコントロールに適用する
Forms(FormName).Controls(TxtName).Value = "12345"

補足情報

１：開発中のシステムの都合上、親フォーム内に設置しているサブフォームは、テーブルやクエリと連結できない非連結型のフォームのため、親フォーム内のサブフォームエリアに表示しているコントロールのプロパティを操作することになります。

２：プロパティを操作するテキストボックスが多いため、変数で指定する方式を採用したいです。

３：親フォーム名 → "F02_2_注文画面"
４：サブフォーム名兼サブフォームエリア名 → "F02_1_入力画面"
５：プロパティを操作するテキストボックス名 → "Txt_b1"など
※プロパティを操作するテキストボックスはたくさんあり、"Txt_"までは同じで、アンダーバーのあとのアルファベット１字と数字がテキストボックスごとに異なるようになっております。

'変数化する前のコード
Forms!F02_2_注文画面.F02_1_入力画面.Form!Txt_b1.Value = "12345"

Answer 1

親フォーム名、サブフォーム名、コントロール名をそれぞれString型の変数に格納することになります。

Dim mFormName As String, sFormName As String, TxtName As String 
Forms(mFormName).Controls(sFormName).Form.Controls(TxtName).Value = "12345"

このようにすると、常にサブフォームに配置してあるという前提でしか使えません。

フォームはオブジェクト変数に格納するとメインフォームでもサブフォームでも問題なく格納できるので便利です。

サブフォームとして開いたときのコード例
Txt_b1~Txt_b9 まで"12345" を代入する

Dim frm As Form
Set frm = Forms!F02_2_注文画面!F02_1_入力画面.Form

Dim txtName As String
txtName = "Txt_b"
For i = 1 to 9
    frm.Controls(TxtName & i).Value = "12345"
Next

メインフォームとして開いたときのコード例

Dim frm As Form
Set frm = Forms!F02_1_入力画面

Dim txtName As String
txtName = "Txt_b"
For i = 1 to 9
	frm.Controls(TxtName & i).Value = "12345"
Next

メインフォーム上のサブフォームから、同じメインフォーム上の別のサブフォームのコントロールを参照する場合のコード例

Dim frm As Form
Set frm = Me.Parent!F02_1_入力画面.Form

Dim txtName As String
txtName = "Txt_b"
For i = 1 to 9
	frm.Controls(TxtName & i).Value = "12345"
Next

Comments

[Yoshikun_0945]

大変助かりました。
ありがとうございました
今後ともよろしくお願いいたします。