Excel for Mac のVBAにてメール送信したい

Question

前提・実現したいこと

Windows版 Excel VBAにて自動メール送信するツール使っています。
これを今度Macに移植する作業の中で問題にぶつかりました。
WindowsではCDO(Microsoft CDO for Windows 2000 Library)を利用しています。
Macではこれが標準で準備されておらず、実行できません。

質問は、
Macにもこのライブラリを追加することができるのか？
追加できるのであればどうしたら良いのか？
追加できない場合には、Excel for MacのVBAにて自動メール送信する代替方法はあるのか？
です。

色々と探したのですが、非力ながら情報を見つけることができませんでした。

どなたかわかる方がいましたらご教示頂けましたら幸いです。

どうぞ宜しくお願い致します。

発生している問題・エラーメッセージ

コンパイル エラーです。:

ユーザー定義型は定義されていません。

該当のソースコード

'*******************************************************************************
'   CDOでメールを送信する
'*******************************************************************************
'   [参照設定]
'   ・Microsoft CDO for Windows 2000 Library
'*******************************************************************************
Option Explicit

  'CDO Const
  Const cdoSendUsingMethod = _
    "http://schemas.microsoft.com/cdo/configuration/sendusing"
  Const cdoSMTPServer = "http://schemas.microsoft.com/cdo/configuration/smtpserver"
  Const cdoSMTPServerPort = _
    "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
  Const cdoSMTPConnectionTimeout = _
    "http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
  Const cdoSMTPAuthenticate = _
    "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
  Const cdoSendUsingPort = 2
  Const cdoAnonymous = 0
  Const cdoLanguageCode = _
    "http://schemas.microsoft.com/cdo/configuration/languagecode"
  
 'Font Code
  Const cdoShift_JIS = "shift-jis"
  Const cdoEUC_JP = "euc-jp"
  Const cdoISO = "iso-2022-jp"
  Const cdoUTF_7 = "utf-7"
  Const cdoUTF_8 = "utf-8"
  
  'kitei
  Private Const cnsConfiguration = "http://schemas.microsoft.com/cdo/configuration/"
  Private Const cnsSendUsing = 2
  
'*******************************************************************************
' メール送信テストプログラム
'*******************************************************************************
Sub TEST()
    Dim MailSmtpServer As String
    Dim MailFrom As String
    Dim MailTo As String
    Dim MailSubject As String
    Dim MailBody As String
    Dim strMSG As String

    ' 送信確認
    If MsgBox("メールを送信します。", vbYesNo) <> vbYes Then Exit Sub
    MailSmtpServer = Cells(1, 2).Text   ' SMTPサーバ
    MailFrom = Cells(2, 2).Text         ' 発信者
    MailTo = Cells(3, 2).Text           ' 宛先
    MailSubject = Cells(4, 2).Text      ' 件名
    MailBody = Cells(5, 2).Text         ' 本文
    ' メール送信(CC,BCCはブランク)
    strMSG = SendMailByCDO(MailSmtpServer, MailFrom, MailTo, "", "", _
        MailSubject, MailBody)
    If strMSG <> "OK" Then MsgBox Mid(strMSG, 3)
End Sub


'*******************************************************************************
' メール送信(CDO)
'*******************************************************************************
' [引数]
'  ①MailSmtpServer : SMTPサーバ名(又はIPアドレス)
'  ②MailFrom       : 送信元アドレス
'  ③MailTo         : 宛先アドレス(複数の場合はカンマで区切る)
'  ④MailCc         : CCアドレス(複数の場合はカンマで区切る)
'  ⑤MailBcc        : BCCアドレス(複数の場合はカンマで区切る)
'  ⑥MailSubject    : 件名
'  ⑦MailBody       : 本文(改行はvbCrLf付加)
'  ⑧MailAddFile    : 添付ファイル(複数の場合はカンマで区切るか配列渡し) ※Option
'  ⑨MailCharacter  : 文字コード指定(デフォルトはShift-JIS)              ※Option
' [戻り値]
'  正常時："OK", エラー時："NG"+エラーメッセージ
'*******************************************************************************
Private Function SendMailByCDO(MailSmtpServer As String, _
                               MailFrom As String, _
                               MailTo As String, _
                               MailCc As String, _
                               MailBcc As String, _
                               MailSubject As String, _
                               MailBody As String, _
                               Optional MailAddFile As Variant, _
                               Optional MailCharacter As String)
    Const cnsOK = "OK"
    Const cnsNG = "NG"
    'Dim objCDO As New CDO.Message
    Dim objCDO As Object
    Dim vntFILE As Variant
    Dim IX As Long
    Dim strCharacter As String, strBody As String, strChar As String

    On Error GoTo SendMailByCDO_ERR
    SendMailByCDO = cnsNG

    ' 文字コード指定の確認
    If MailCharacter <> "" Then
        ' 指定ありの場合は指定値をセット
        strCharacter = MailCharacter
    Else
        ' 指定なしの場合はShift-JISとする
        strCharacter = cdoShift_JIS
    End If

    ' 本文の改行コードの確認
    ' Lfのみの場合Cr+Lfに変換
    strBody = Replace(MailBody, vbLf, vbCrLf)
    ' 上記で元がCr+Lfの場合Cr+Cr+LfになるのでCr+Lfに戻す
    MailBody = Replace(strBody, vbCr & vbCrLf, vbCrLf)
    
    #If Mac Then
        Set objCDO = New CDO.Message
    #Else
        Set objCDO = CreateObject("CDO.Message")
    #End If
    
    With objCDO
        With .Configuration.Fields                          ' 設定項目
            .Item(cdoSendUsingMethod) = cdoSendUsingPort    ' 外部SMTP指定
            .Item(cdoSMTPServer) = MailSmtpServer           ' SMTPサーバ名
            .Item(cdoSMTPServerPort) = 25                   ' ポート№
            .Item(cdoSMTPConnectionTimeout) = 60            ' タイムアウト
            .Item(cdoSMTPAuthenticate) = cdoAnonymous       ' 0
            .Item(cdoLanguageCode) = strCharacter           ' 文字セット指定
            .Update                                         ' 設定を更新
        End With
        .MimeFormatted = True
        .Fields.Update
        .From = MailFrom                        ' 送信者
        .To = MailTo                            ' 宛先
        If MailCc <> "" Then .CC = MailCc       ' CC
        If MailBcc <> "" Then .BCC = MailBcc    ' BCC
        .Subject = MailSubject                  ' 件名
        .TextBody = MailBody                    ' 本文
        .TextBodyPart.Charset = strCharacter    ' 文字セット指定(本文)
        ' 添付ファイルの登録(複数対応)
        If ((VarType(MailAddFile) <> vbError) And _
            (VarType(MailAddFile) <> vbBoolean) And _
            (VarType(MailAddFile) <> vbEmpty) And _
            (VarType(MailAddFile) <> vbNull)) Then
            If IsArray(MailAddFile) Then
                For IX = LBound(MailAddFile) To UBound(MailAddFile)
                    .AddAttachment MailAddFile(IX)
                Next IX
            ElseIf MailAddFile <> "" Then
                vntFILE = Split(CStr(MailAddFile), ",")
                For IX = LBound(vntFILE) To UBound(vntFILE)
                    If Trim(vntFILE(IX)) <> "" Then
                        .AddAttachment Trim(vntFILE(IX))
                    End If
                Next IX
            End If
        End If
        .Send                                   ' 送信
    End With
    Set objCDO = Nothing
    SendMailByCDO = cnsOK
    Exit Function

'-------------------------------------------------------------------------------
SendMailByCDO_ERR:
    SendMailByCDO = cnsNG & Err.Number & " " & Err.Description
    On Error Resume Next
    Set objCDO = Nothing
End Function

'-----------------------------<< End of Source >>-------------------------------

試したこと

Windows のCDOライブラリである、
cdosys.dll
をそのままExcel for Mac のVBAの参照設定に追加しようとしたが、
当然ながら追加できなかった。
それ以外の方法を思いつくことや、情報を得ることができず、立ち往生しています。

補足情報（FW/ツールのバージョンなど）

***開発環境
MacBook Pro Mid 2015
macOS Mojave (バージョン10.14.16)
Excel for Mac (バージョン16.28)
Microsoft Visual Basic for Applications 7.1

Comments

[imihito]

AppleScript について調べられてみてはどうでしょう？

[UniverseMove]

コメントありがとうございます。
AppleScriptですね。調べてみます。
ありがとうございます。

[退会済みユーザー]

Stack Overflowに似た質問がありますね。
https://stackoverflow.com/questions/51990005/send-email-with-workbook-from-vba-macro-on-both-windows-and-mac

Anser中にTipsサイトへのリンクが貼ってあるので、そちらがヒントになるかもしれません。
技術情報の検索ワードは英字だけすると、ヒットしやすいですよ。

[UniverseMove]

コメントありがとうございます。
Answer中のリンクにはExcel for Mac 2011のケースに関する記述もありとても参考になりそうです。後ほど解決できるか試したいと思います。
貴重な情報ありがとうございます。

Answer 1

はじめまして。
やりたいことはよくわかりましたので、参考までにURLを記載しますので、試してみてください。
https://www.fastclassinfo.com/entry/vba_gmail_sendmail

これにより、問題が解決することを祈ります。

Comments

[imihito]

質問に「CDOでは出来なかった」とあるのにCDOを使った記事を勧めるのは適当ではないと思われます。

[UniverseMove]

回答ありがとうございます。
ですが、imihitoにもありますように、CDOでできないのをどうしたらよいか、という質問でしたので申し訳ございませんが不要情報でございました。