取り込んだcsvのデータをソートしたいです。

Question

前提・実現したいこと

VBAで取り込んだcsvファイルのデータをソートしたいのですがうまくいきません。
3列目の数字をキーにして昇順ソートを行ってからデータを扱いたいです。

よろしければソートの手法やソートが実現できるコードを教えて頂けませんでしょうか。
お手数お掛けいたしますがご教授をよろしくお願いします。

csvファイルはテキストファイルで作成し拡張子をcsvにしております。
■使用するCSVのデータ
"富田","男","104","神奈川"
"村田","男","106","沖縄"
"山田","女","103","福岡"
"前田","男","101","北海道"
"栗田","男","103","東京"
"藤田","男","102","大阪"
"三田","女","106","愛媛"
"園田","女","105","愛媛"

該当のソースコード

Public Const COLNUM = 3

Public Function CntConfirmation(ByVal pfilePath As String)As Boolean

CntConfirmation = False

Dim agoRecord As String
Dim newRecord As String
Dim cntStorage As String
'CSV行格納配列
Dim fileDataTable() As String

Dim FSO As Object
Dim dataFile As Object

Set FSO = CreateObject("Scripting.FileSystemObject")
Set dataFile = FSO.OpenTextFile(pfilePath)

'ここが焦点になります。
'********************************
'ここの処理でソートを試みてみました。
dataFile.sort
Key := Range("C1"), _
Order := xlAscending
'********************************

Do while readCSV(dataFile,fileDataTable)

newRecord = fileDataTable(COLNUM - 1)
If agoRecord = newRecord  Then
 cntStorage = cntStorage + 1
End If

agoRecord = newRecord

loop

CntConfirmation = True
End Function

補足情報（FW/ツールのバージョンなど）

Excel2016

Comments

[tatsu99]

FileSystemObjectにソート機能はないと思いますが（私が知らないだけかもしれませんが）、
FileSystemObjectでソートを行うことができるという情報は、どこから入手したのでしょうか。
そのＵＲＬ等を提示していただければ幸いです。
私が思うに、適当なワークシートにファイルの内容を展開し、ワークシート上でソートするのが、一番簡単かと思うのですが、いかがでしょうか。

[xss]

tatsu99さん回答ありがとうございます。
FileSystemObjectでソートを行おうとしていなくオブジェクト型に格納した後で処理を通してソートできないか探っている所です。
エクセルで開いてフィルタでソートをするのが手っ取り早いのは事実でございますがなんとかコード上で昇順ソートを実現したく困っております。。

[meg_]

OpenTextFileの戻り値は「TextStream オブジェクト」ですね。仮にこれを並べ替えられたとしても、意味ないかと思います。
エクセルの機能を使いたくないなら、ご自身でソート機能を実装すれば良いです。

[tatsu99]

>FileSystemObjectでソートを行おうとしていなくオブジェクト型に格納した後で処理を通してソートできないか探っている所です。
meg_さんも書かれていますが、OpenTextFileの戻り値は「TextStream オブジェクト」です。
TextStream オブジェクトはSortメソッドを持っていません。
vbaで最も使用されるソートは、Rangeオブジェクトのソートです。Rangeオブジェクトはセルの集合です。したがって、「適当なワークシートにファイルの内容を展開し、ワークシート上でソートする」ことになります。この場合、人間の手作業は発生しません。全て、マクロで行います。
それで良ければ、提示可能です（案１）。ただし、この場合、ワークシートを１枚使用するので、そのワークシートを予め、確保しておく必要があります。そんな、みっともないことはしたくないということであれば、実行時にワークシートを追加し、完了後にワークシートを削除することになります。
Rangeオブジェクトのソートは使いたくないということであれば、SortedListの使用が考えられますが、ソートの条件は１つのキーという制約があります。また、キーの重複を許さないので、特別な手当てが必要になります。それで良ければ、提示可能です。（案２）
又、ソートのキーですが３桁固定なのでしょうか。もし、そうでないなら、文字列としてソートするのか数字としてソートするのか、どちらでしょうか。
数字のソート昇順の場合、以下のようになります。
"50"
"223"
"1234"
文字のソート昇順の場合、以下のようになります。
"1234"
"223"
"50"

[tatsu99]

結局最終的には、何がほしいのでしょうか。
fileDataTable()にソートされた結果がほしいのでしょうか。
readCSVのソースが提示されていないので、よくわかりませんが、
fileDataTableの要素は、１レコードですか、それとも、３列目のキーのみでしょうか。
キーの重複件数をカウントしているようにも見えますが、キーの重複件数がほしいためにだけソートしているのであれば、ソートせずに、キーの重複件数のみを取得する方法もあります。（dictionaryを使います）

[xss]

ご返事ありがとうございます。dataFile(CSVのデータ)に対して
3列目をキーにして昇順ソートをしたいです。
CSVは毎回レコード数が違います。
10万レコードだったり1万レコードだったりします。
3列目は値は桁数が同じ数字になります。
分かりやすく3桁にしております。
そして重複した値があります。

fileDataTableは1レコードの3列目の値(数字)を差していてそれを交互に比較していき差異があった場合にカウントをするコードを作成したく迷っておりました。

私がほしいものは
Set dataFile = FSO.OpenTextFile(pfilePath)
のdataFileを3列目を基準に昇順ソートを行いたいです。

[meg_]

.NETのArrayListのSortメソッドでもソート出来そうです。

Answer 1

既存のオブジェクトを使うのであれば、ADODB(Microsoft ActiveX Data Objects X.X Library)を使うのも手ではあるでしょう。

例1:ADODB.Connectionを使う方法

既存のCSVファイルをデータベースとして見立てて、読み込む方法です。
実行環境によって調整が必要ですが、動くのであれば色々操作が楽な方法です。

結果はADODB.Recordsetというオブジェクトとなりますが、このオブジェクトから色々な形式に変換できます(下記コードでは確認用に文字列化しています)。

Sub teratail211399_CSVSort_ADODBConnection(pfilePath As String)
    '元の質問
    'https://teratail.com/questions/211399
    '参考サイト
    'https://z1000s.hatenablog.com/entry/2019/06/10/225834
    
    Dim FSO As Object 'As Scripting.FileSystemObject
    Set FSO = CreateObject("Scripting.FileSystemObject")
    
    'ここの書き方はOfficeのバージョン・bit数・Accessインストールの有無などによって変わる。
        '参考
        'Driver={Microsoft Text Driver (*.txt; *.csv)};
        'Driver={Microsoft Access Text Driver (*.txt, *.csv)};
    Const ConnectionStringBase = _
        "Provider=Microsoft.ACE.OLEDB.12.0;" & _
        "Data Source='{SourceFolder}';" & _
        "Extended Properties=""Text;HDR=No;"""
    
    Dim conString As String
    conString = Replace( _
        ConnectionStringBase, _
        "{SourceFolder}", _
        FSO.GetParentFolderName(pfilePath) _
    )
    
    Dim con As Object 'As ADODB.Connection
    Set con = CreateObject("ADODB.Connection")
    
    con.Open conString
    
    'FileNameから(FROM [{FileName}])
    '全列取得(SELECT *)
    'F3の列を昇順(ASC)ソート(ORDER BY F3 ASC)
    Const SQLBase = "SELECT * FROM [{FileName}] ORDER BY F3 ASC"
    
    Dim cmdSql As String
    cmdSql = Replace( _
        SQLBase, _
        "{FileName}", _
        FSO.GetFileName(pfilePath) _
    )
    
    Dim rs As Object 'As ADODB.Recordset
    Set rs = con.Execute(cmdSql)
    
    '確認用(ORDER BYで指定していない列はCSVファイル通りの順番ではない)
    rs.MoveFirst
    Debug.Print rs.GetString
    Stop
    
End Sub

前田    男  101 北海道
藤田    男  102 大阪
栗田    男  103 東京
山田    女  103 福岡
富田    男  104 神奈川
園田    女  105 愛媛
三田    女  106 愛媛
村田    男  106 沖縄

例2:ADODB.Recordsetを単独で使う方法

例1で使っているADODB.Recordsetは単独でもソート機能を持っているため、そちらを使う手もあります。

CSVの読み込みと解釈は自前で実装する必要があります(下記コードは簡易コードです)。

Sub teratail211399_CSVSort_ADODBRecordsetOnly(pfilePath As String)
    '元の質問
    'https://teratail.com/questions/211399
    
    Dim FSO As Object 'As Scripting.FileSystemObject
    Set FSO = CreateObject("Scripting.FileSystemObject")
    
    Dim rs As Object 'As ADODB.Recordset
    Set rs = CreateObject("ADODB.Recordset")
    
    'CSVの列を定義
        '文字列でもソートしたいなら、adBSTRではなく、adVarWChar(= 202)と3個目の引数指定が必要
    Const adBSTR = VBA.VbVarType.vbString '= 8
    Const adInteger = VBA.VbVarType.vbLong '= 3
    With rs.Fields
        .Append "名字", adBSTR
        .Append "性別", adBSTR
        .Append "No.", adInteger
        .Append "県", adBSTR
    End With
    rs.Open
    rs.Sort = "[No.] ASC"  'No.の列を昇順ソートさせる
    
    Dim ts As Object 'As Scripting.TextStream
    Set ts = FSO.OpenTextFile(pfilePath)
    
    Do Until ts.AtEndOfLine
        Dim csvRecord() As String
        csvRecord = Split(ts.ReadLine(), ",")
        rs.AddNew
        Dim c As Long
        For c = LBound(csvRecord) To UBound(csvRecord)
            'VBAの暗黙の型変換も利用
            'ダブルクォーテーションを削除
            rs.Fields.Item(c).Value = Replace(csvRecord(c), """", "")
        Next c
    Loop
    ts.Close
    
    '確認用
    rs.MoveFirst
    Debug.Print rs.GetString
    Stop
    
End Sub

前田    男  101 北海道
藤田    男  102 大阪
山田    女  103 福岡
栗田    男  103 東京
富田    男  104 神奈川
園田    女  105 愛媛
村田    男  106 沖縄
三田    女  106 愛媛

Comments

[xss]

imihitoさんご解答ありがとうございます。
ADODBを使用する方法もあるのですね、ものすごく参考になります。
ご回答感謝いたします。

Answer 2

あなたの提示された関数を修正しました。
「作業」シートを事前に作成してください。
A列がキー、B列が１レコードの内容になります。
個々の項目にはばらしていません。ダブルクオートもとっていません。
A列でソートされた結果が表示されます。

Public Function CntConfirmation(ByVal pfilePath As String) As Boolean
    Application.ScreenUpdating = False

    CntConfirmation = False
    Dim line As String
    Dim items As Variant
    Dim ws As Worksheet
    Dim sr_key As String
    Dim wrow As Long
    Dim FSO As Object
    Dim dataFile As Object
    Set ws = Worksheets("作業")
    ws.Cells.ClearContents
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set dataFile = FSO.OpenTextFile(pfilePath)
    wrow = 0
    '最後の行迄1行ずつ読み込む
    Do Until dataFile.AtEndOfStream
        wrow = wrow + 1
        line = dataFile.ReadLine
        items = Split(line, ",")
        sr_key = CStr(items(2))
        ws.Cells(wrow, "A").Value = sr_key
        ws.Cells(wrow, "B").Value = line
    Loop
    'キーでソート
    ws.Range("A1:B" & wrow).Sort key1:=ws.Range("A1"), Order1:=xlAscending, Header:=xlNo
    Application.ScreenUpdating = True
    
    CntConfirmation = True
End Function

Comments

[tatsu99]

リプライがありませんが、何か不満があるのでしょうか？
個々の項目にばらすとか、ダブルクオートをとるのは、あなたのスキルなら可能かと判断したためです。
また、このケースでは、それらの処理は、求められていないと判断しました。

[xss]

返信遅れて申し訳ございません。
回答ありがとうございます。

読み返して勉強した結果、納得をいたしました。
その中でtatsu99さんのご解答とても参考になりました。
感謝いたします。

Answer 3

＞よろしければソートの手法やソートが実現できるコードを
＞教えて頂けませんでしょうか。
＞お手数お掛けいたしますがご教授をよろしくお願いします

CSV　ソート

で検索すれば、手法やサンプルコードがいくつか見つかります。
いつ回答があるかわからない掲示板より、
解決が早いと思いますよ。

多分、
1）エクセルでCSVファイルを開く
2）エクセルの並び替え機能で並び替え
とやる手法が、開発コストが少なく、処理速度も速い部類になると思います。

http://www.asahi-net.or.jp/~ef2o-inue/vba_o/sub05_800.html
http://mofuken.blogspot.com/2017/09/vba-csv.html
https://accesskid.wordpress.com/2011/07/01/%E4%B8%A6%E3%81%B9%E6%9B%BF%E3%81%88%E3%81%AE%E5%9F%BA%E6%BA%96%E3%81%A8%E3%81%99%E3%82%8B%E5%88%97%E3%82%92%E6%8C%87%E5%AE%9A%E3%81%97%E3%81%A6csv%E3%83%95%E3%82%A1%E3%82%A4%E3%83%AB%E3%82%92/
http://sak.cool.coocan.jp/w_sak3/doc/sysbrd/vb_t06.htm