Arduino時計で1秒の誤差を縮めたいです

前提・実現したいこと

ArduinoMEGAで7セグメントLEDを用いた時計を作っています

表示はダイナミック点灯、1日の誤差1秒以内を条件に製作しています

発生している問題・エラーメッセージ

開発環境上ライブラリへのMsTimer2、DS1307RTC、Timeの追加ができない状況です。
現在delayを用いて1秒間ごとに出力していますが誤差が19時間で2分程度あり、とても時計としての機能に難がある状況です。
そこでmillis関数を用いて1秒間を計測して出力しようとしていますが、やり方がわかりません。
知恵をお貸しください。

現在のdelayを用いたコードです。
7セグは分、時にカソードコモン、秒にアノードコモンを用いています。
ピン22、23は1秒ごとに点滅、ピン8は時刻設定時に点灯します。

byte cnt,sec,min,hour;
int val=0;
int val3=0;
int val2=0;
int old_val=0;
int state=0;

byte sec_pin[8]= {24,25,26,27,28,29,30,31}; //カソード
byte min_pin[8]= {40,41,42,43,44,45,46,47}; //アノード
byte hour_pin[8]= {32,33,34,35,36,37,38,39};

byte sec_a_com[]= {12,13};
byte min_c_com[]= {10,11};
byte hour_b_com[]={8,9};

boolean Num_Array2[10][7]= {
{1,1,1,1,1,1,0}, //0
{0,1,1,0,0,0,0}, //1
{1,1,0,1,1,0,1}, //2
{1,1,1,1,0,0,1}, //3
{0,1,1,0,0,1,1}, //4
{1,0,1,1,0,1,1}, //5
{1,0,1,1,1,1,1}, //6
{1,1,1,0,0,1,0}, //7
{1,1,1,1,1,1,1}, //8
{1,1,1,1,0,1,1}, //9
};

void NumPrint(byte min_num,byte sec_num,byte hour_num) {
for(byte i=0; i<7; i++) {
digitalWrite(sec_pin[i],!Num_Array2[sec_num][i]);
digitalWrite(min_pin[i],Num_Array2[min_num][i]);
digitalWrite(hour_pin[i],Num_Array2[hour_num][i]);
}
}

void setup() {
for(byte i=0; i<2; i++) {
digitalWrite(sec_a_com[i],LOW);
pinMode(sec_a_com[i],OUTPUT);
digitalWrite(min_c_com,HIGH);
pinMode(min_c_com[i],OUTPUT);
digitalWrite(hour_b_com,HIGH);
pinMode(hour_b_com[i],OUTPUT);
}
for(byte i=0; i<8; i++) {
pinMode(sec_pin[i],OUTPUT);
pinMode(min_pin[i],OUTPUT);
pinMode(hour_pin[i],OUTPUT);
}
pinMode(2,INPUT);
pinMode(3,OUTPUT);
pinMode(4,INPUT);
pinMode(5,INPUT);
}

void loop() {
if(cnt&1) {
digitalWrite(sec_a_com[0],LOW);//秒1桁目を消す
digitalWrite(min_c_com[0],HIGH);//分1桁目を消す
digitalWrite(hour_b_com[0],HIGH);//時1桁目を消す

NumPrint(min/10,sec/10,hour/10);//数字形にする。

digitalWrite(sec_a_com[1],HIGH);//秒2桁目を点ける
digitalWrite(min_c_com[1],LOW);//分2桁目を点ける
digitalWrite(hour_b_com[1],LOW);//時1桁目をつける
} else {
digitalWrite(sec_a_com[1],LOW);
digitalWrite(min_c_com[1],HIGH);
digitalWrite(hour_b_com[1],HIGH);
NumPrint(min%10,sec%10,hour%10);
digitalWrite(sec_a_com[0],HIGH);
digitalWrite(min_c_com[0],LOW);
digitalWrite(hour_b_com[0],LOW);
}

if(cnt==20){
digitalWrite(22,LOW);
digitalWrite(23,LOW);
}

if(++cnt==191){
cnt=0;
digitalWrite(22,HIGH);
digitalWrite(23,HIGH);
if(++sec==60) {
sec=0;
if(++min==60){
min=0;
if(++hour==24){
hour=0;
}
}
}
}
delay(5);

val = digitalRead(2);
val2 = digitalRead(4);
val3 = digitalRead(5);
if((val==1)&&(old_val==0)){
state= 1 - state;
delay(100);
}
old_val = val;
if(state==1){
digitalWrite(3,HIGH);
}
else{
digitalWrite(3,LOW);
}

if((val2==1)&&(state==1)){
delay(100);
min++;
if(min>=60){
min=0;
}
}
if((val3==1)&&(state==1)){
delay(100);
hour++;
if(hour>=24){
hour=0;
}
}
}

mikkame

2019/08/06 04:58

arduino も普通のpcも厳密に言えば n ms 以上待ったら実行する（割り込みとかでずれる）というふうになっているので厳密にn ms待っているわけじゃない

ikadzuchi

2019/08/06 15:01

> mikkameさんそれは時計がずれる話と無関係ですね。 millisもdelayもずれますが、PCでの時間待ちやdelayのずれは蓄積するのに対しmillisのずれは蓄積しません。

coco_bauer

2019/08/08 13:42

arduinoはインターネットに接続されていますか？　接続されているのであれば、NTPクライアントを定期的に（8分おきにとか）実行することで、時計の時刻合わせをするという方法が使えると思います。１９時間で２分(120秒)狂うということは、１時間に６秒余り（120/19 = 6.316)狂う訳で、狂いを１秒以内に抑えるには１時間に７回以上の時刻合わせをする必要があります。

行動規範の内容に同意します

回答5件

開発環境上ライブラリへのMsTimer2、DS1307RTC、Timeの追加ができない状況です。

ってのはなんで出来ないのかを追求すべきかも知れないと思いますけれど
それはともかく。

30cmのものさしがあったとして、ものさしの端を使わないで長さを計るとき、あなたはどうしますか? 例えば3.2cmのところから20.7cmのところまであるモノの長さはいくつでしょう。
millis()だって基本的には同じです。ある時、millis()が返す値が1234だった。次にmillis()を呼んだら、5999だった。この間にどれだけの時間が経ったのでしょう。これが基本になります。

それと、注意しなければいけないのはmillis()はunsigned longで値を返すこと。つまり、49日程で値が0に戻ります。単純に引き算だけで時間を求めているとこの罠にハマります。(誤りなので削除)

もちろん、精度はあまり期待出来ませんから、外部の正確な時計で1時間とか一日分のmilllis()の値を計ってみていくつだったのか、というデータを取らないと時計と呼べるレベルにはなかなかならないかも知れません。長時間のデータを取れば取るほど精確な計時が期待できるようになるでしょう。1時間は単純にmsで言えば3600000msですが、millis()が精確でないが故に3601800(millis)が1時間なのかも知れないので、それで「校正」するのです。逆に言うと、millis()が1000毎に1秒、何ていう処理をしているとまともな精度が得られないかもしれません。

もう一つ、millis()の元はマイコンが動けばいい、というクロックですから、温度や基板の実装状態によっては湿度の変化に対しても無視できない周波数変動を起こかもしれません。昔の時計みたいに、夏と冬とでずれ方が変わるとか。

とりあえずデータを取ってみました。
純正(というのかな?)のArduinoです。

Arduino
1void setup() {
2  Serial.begin(115200);
3}
4
5void loop() {
6  unsigned long ms=millis();
7  if(ms%10==0){//通信量を抑えるため
8    Serial.println(ms);
9    delay(5);
10  }
11}

で、出てくるデータをteratermのタイムスタンプ付きのログで記録してみたところ、抜粋ですが

Text
1[2019-08-08 20:34:42.702] 0
2[2019-08-08 20:51:22.705] 998820
3[2019-08-08 20:51:23.884] 1000000
4[2019-08-08 21:08:02.705] 1997640
5[2019-08-08 21:08:05.069] 2000000
6[2019-08-08 21:24:42.706] 2996460
7[2019-08-08 21:24:46.254] 3000000
8[2019-08-08 21:34:42.696] 3595740
9[2019-08-08 21:34:46.965] 3600000
10[2019-08-08 21:41:22.700] 3995270
11[2019-08-08 21:41:27.439] 4000000

冷房は入れていない夜の室内なので28℃ぐらいの環境と思います。
1000000msは16分40秒。0.11%ぐらいのずれ、というところでしょうか。USBで繋いでいるしWindowsなのでタイムスタンプの10ms以下はあまり意味がないと思いますが、millis()に対して100000/99882を乗じればそこそこは合うかな、というところ。もっと長くデータを取れば桁数は増えるでしょうし、温度が変わるとまた影響があるでしょう。必要なら温度センサもつけて補正係数を求める、なんてことも考えられます。
素直に正確なタイムベースを設けろ、の説もあり。質問者さんの必要な精度に合わせて手を打って下さい。

バタバタやってみたけど、読み返してみると要求は日差1秒以下、でしたっけ。腕時計なんかでも(実は腕時計って着けたり外したりで温度差が出るから条件は厳しいのだけれど)日差±15秒ぐらいじゃなかったかしら。つまり、水晶にしたとしてもその目標は困難かと。

ネットワークに繋いでNTPとか、GPSモジュール付けて時刻を拾うとかいうのが実現しやすい解決になると思います。

投稿2019/08/06 12:08

編集2019/08/08 13:33

thkana

総合スコア7723

mkgt00

2019/08/07 09:59

本題とは関係ないところで恐縮ですが、 > それと、注意しなければいけないのはmillis()はunsigned longで値を返すこと。つまり、49日程で値が0に戻ります。単純に引き算だけで時間を求めているとこの罠にハマります。これ、unsigned なので、単純に引き算だけで時間を求めることができると思いますが… (49日を超えて待つのは無理ですが) 具体的に、どういう罠にハマるのでしょうか?

thkana

2019/08/07 13:20

> 単純に引き算だけで時間を求めることができると思いますが… その通りですね。私の勘違いです。

thkana

2019/08/08 14:32

10^7記念。 [2019-08-08 23:21:22.700] 9988170 [2019-08-08 23:21:34.541] 10000000

行動規範の内容に同意します

そもそものはなしですが、Arduinoに搭載されているシステムクロック用の水晶は時計用じゃありません
時計用として使用するには誤差が大きすぎます
本気で時計を作りたいなら、水晶内臓の時計ICを増設して、そこから時間を読むようにしましょう。

この質問には全く意味がないです。
だいたい、millisはシステムクロックで駆動されているわけで、その狂っている測定機でいくら正確に測っても、その測定器以上の精度は出るはずもありません。

って、そもそも、millisは正確だと思ってるなら、そのmillisで計時すればいいだけの話ですがな。

さあ、それ使って時計作ってみなさい。システムクロックの限界を思い知ることになりますぜｗ

投稿2019/08/06 03:59

編集2019/08/06 12:51

y_waiwai

総合スコア88163

少し質問の意図とは違いますが、新たな視点として一つ提案いたします。
プログラムをななめ読みしたところ、7セグのそれぞれのピンに直接MEGAからピンを引っ張ってきているように見えます。
これを7セグのドライバIC(http://akizukidenshi.com/catalog/g/gI-14057/等)を使うようにすると、MEGAから出すピンが減らせて結果的にTimerが使えるような設計にできないでしょうか。

投稿2019/09/23 03:47

退会済みユーザー

総合スコア0

既にy_waiwaiさんが指摘しているように、Arduinoのクロック発生には水嶼発振子ではなくセラミック発振子が使われています。マイコンの動作は、このクロックに基づいて行われます。

セラミック発振子は0.5%程度の誤差があるので、１日に(246060)*0.005 = 432秒(7分12秒)程度の誤差を覚悟しなくてはなりません。
millsの値も0.5%程度の誤差を含んだものになります。

クロックの発生に使われている発振子という部品の問題なので、部品を取り換えるといったハードウェア的な対処でないと解決できません。

投稿2019/08/08 08:24

coco_bauer

総合スコア6919

thkana

2019/08/08 11:55

セラミック振動子だ、という具体的な資料はありますか? 私は見つけられていないのですが。とりあえず、手元の現物とか本家の https://store.arduino.cc/usa/arduino-uno-rev3 の写真を見ると、(写真では見えないですが16.000と書いてある)金属の缶はHC49/ssパッケージの水晶のように思えます。

koujikuu

2019/08/08 12:19

回路図表記では、CSTCE16M0V53-R0 セラミック発信子です https://www.murata.com/ja-jp/products/productdetail?partno=CSTCE16M0V53-R0 https://content.arduino.cc/assets/MEGA2560_Rev3e_sch.pdf https://www.arduino.cc/en/uploads/Main/Arduino_Uno_Rev3-schematic.pdf 16MHz HC49 は、USBシリアル通信 ATMEGA16U2 マイコン用です

thkana

2019/08/08 12:21

了解しました。

行動規範の内容に同意します

millis() を使ったテストプログラム

unsigned char sec = 0 , min = 0 , hour = 0 ;
#define ms 1000

char time_count(void){
  static unsigned long millis_old = 0;
  if ( ( millis() - millis_old ) < ms ){ return 0; }
  millis_old += ms;
  sec++ ; if ( sec < 60 ){ return 1; }
  sec = 0 ;  
  min++ ; if ( min < 60 ){ return 2; }
  min = 0 ;
  hour++ ; if ( hour < 24 ){ return 3; }
  hour = 0; 
  return 4;
}

void setup() {
  Serial.begin( 9600 );
  Serial.println("Arduino Program Start !!");
}

void loop() {
  if ( time_count() != 0 ){
    Serial.print( hour ); Serial.print(":");
    Serial.print( min ); Serial.print(":");
    Serial.print( sec ); Serial.println();
  }
}

投稿2019/08/06 08:23

koujikuu

総合スコア401