フォルダ内のCSVファイルの行数を一覧表示させたい

Question

フォルダにあるCSVファイルの行数を一覧で表示させたいです。
VBAやPowerShellでの方法をググったのですがいまいち上手くいかず、教えていただけると助かります。

　ファイル数：約60ファイル(6GB)
行数／1ファイル：50万行〜１００万行程度
出力形式は問いません。

よろしくお願いいたします。

Comments

[gentaro]

ただの作業依頼はNGです。
https://teratail.com/help/avoid-asking
まず自分で作ったコードを提示しましょう。

[S.Kitsune]

失礼いたしました。ルールを理解していなかったようです。
ご指摘ありがとうございました。

Answer 1

CSVファイルを読み込む、Msgboxで行数を出力するマクロです。
ファイルサイズが大きいため、分割してファイルを読み込んでいます。
（int_count = 4　で 2の4乗 つまり16回に分割する設定）

'参考サイト
'VBA でファイルを高速に読み込む | 二律背反
'http://blog.kouga.net/?eid=102
'
'上記サイトの方法で、高速読込とメモリ対策を実装
' [1] CSVファイルをバイナリデータで高速読込
' [2] [1]の処理は、メモリ対策でファイル分割

Public Sub Csv_Byte_Read01()
    Const int_count = 4 'CSV読込時のファイル分割数(2 ^ int_count)を指定
    Dim openFilename As Variant
    openFilename = Application.GetOpenFilename("ブック(*.csv),*.csv")
    If VarType(openFilename) = vbBoolean Then Exit Sub

    Dim num As Integer
    Dim buf() As Byte         'バイナリデータ処理用
    Dim str_unicode As String
    Dim Records() As String   'csv一括読込用の配列
    Dim rCnt As Long 'ループカウンター
    Dim dCnt As Long 'ループカウンター

    num = FreeFile 'ファイル番号を取得する
'*************************************************************
'   バイナリモードで開く
'   分割読込の場合 For Binary の後に Lock Read が必要
'*************************************************************
    Open openFilename For Binary Lock Read As #num
    Do
        DoEvents: DoEvents
        'ファイルの長さを取得し、変数bufの大きさを確保する
        ReDim buf(LOF(num) \ 2 ^ int_count)
        'ファイルを変数bufに読み込む
        Get #num, , buf
        
        '前回の残りデータを追加。改行コードで区切り、配列に代入
        Records = Split(str_unicode & StrConv(buf, vbUnicode), vbNewLine)
        'この配列は行ごとのデータになる。

        Erase buf
        '最終行はデータ不完全のため別処理
        For rCnt = LBound(Records) To UBound(Records) - 1
            dCnt = dCnt + 1
            '●ここにメイン処理を書く●
        Next rCnt
        
        '最終行の処理
        If UBound(Records) > 0 Then
            '残ったデータがある場合、次の解析に回す
            str_unicode = Records(UBound(Records))
            Debug.Print Records(UBound(Records))
        End If
        
        Erase Records
    Loop While Not EOF(num)
    Close #num 'ファイルを閉じる
    MsgBox dCnt & "行"
End Sub

Comments

[S.Kitsune]

作業依頼になってしまいすみませんでした。
いただいたコードでカウントできました。ありがとうございました。
なお、MSGボックスではなく、指定フォルダの複数cab ファイルの行数をテキストやエクセルに一括で出力するにはどうカスタマイズすれば良いでしょか。お時間ありましたらで結構ですのでよろしくお願いします。