processingにおけるNullpointerExceptionの改善方法（波形の3D表示および音楽との連動）

Question

null pointer exception の改善方法がわかりません。

音を3Dで表示するようなものを構築しようと思い、ネット情報などを頼りに描いてみたのですがどうにも動作しません。

import ddf.minim.analysis.*;

import ddf.minim.;
import ddf.minim.effects.;
import ddf.minim.signals.;
import ddf.minim.spi.;
import ddf.minim.ugens.*;

final int BUFSIZE = 512;

Minim minim;
AudioPlayer player;

AudioInput in;
FFT fft;

int grid = 50;

float gridWidth;
float [][] zs;

public void settings(){

size(800, 800, P3D);
smooth();

}

void setup() {

minim = new Minim(this);
in = minim.getLineIn(Minim.STEREO, 1024);
fft = new FFT(in.bufferSize(), in.sampleRate());

zs = new float[grid + 1][grid + 1];

for(int w = 0; w< grid; w++){
for(int h = 0; h<grid; h++){
zs[w][h] = 0.0;
}
}
gridWidth = width/float(grid);

player = minim.loadFile("SHINICHI OSAWA LOVE WILL GUIDE YOU feat. TOMMIE SUNSHINE.mp3");

player.play();
}

void draw(){

lights();

fft.forward(in.mix);

for(int w=grid-1; w>=0; w--){

for(int h = grid - 1; h >= 0; h--){
  if(h == 0){
    zs[w][h] = fft.getBand(w) * 3;
  } else {
    zs[w][h] = zs[w][h - 1];
  }
}

}

background(0);

translate(0,0,-300);
rotateX(PI/4.0);
for (int w = 0; w < grid; w++){
for(int h = 0; h < grid; h++){
beginShape();

  >> vertex(w * gridWidth, h * gridWidth, zs[w][h]);
  vertex((w + 1) * gridWidth, h * gridWidth, zs[w + 1][h]);
  vertex((w + 1) * gridWidth, (h + 1) * gridWidth, zs[w + 1][h + 1]);      
  vertex(w * gridWidth, (h + 1) * gridWidth, zs[w][h + 1]);      
  endShape(CLOSE);
}

}
}

どうすればよいでしょうか。どうかご教示のほどよろしくお願いいたします。

Comments

[thkana]

どこがぬるぽになってるとか、回答者がブログラムを走らせて確かめないといけないのですか?
あなたはそれを知ってるんじゃないかと思うのですけれど、なぜ質問に書かないのですか?

[swordone]

そもそもコードブロックの書き方間違えてる。
行頭の>をすべて消して、コード部分を選択して<code>を押してください。

Answer 1

今頃回答するのもなんですが、誰か検索で来たりするかもしれませんので書いておきます。
ヌルポが出るのは、AudioInputがない（＝マイクが刺さっていない）からだと思います。
waxogawaさんがやりたかったのは、mp3の波形だと思われるのでinをplayerに置き換えました。

コメントのところが変更した部分

import ddf.minim.analysis.*;
import ddf.minim.*;
import ddf.minim.effects.*;
import ddf.minim.signals.*;
import ddf.minim.spi.*;
import ddf.minim.ugens.*;

final int BUFSIZE = 512;

Minim minim;
AudioPlayer player;

//AudioInput in;
FFT fft;

int grid = 50;
float gridWidth;
float [][] zs;

public void settings() {
  size(800, 800, P3D);
  smooth();
}

void setup() {
  minim = new Minim(this);
//  in = minim.getLineIn(Minim.STEREO, 1024);
  player = minim.loadFile("SHINICHI OSAWA  LOVE WILL GUIDE YOU feat. TOMMIE SUNSHINE.mp3");
  player.play();
  fft = new FFT(player.bufferSize(), player.sampleRate());
//  fft = new FFT(in.bufferSize(), in.sampleRate());

  zs = new float[grid + 1][grid + 1];
  for (int w = 0; w< grid; w++) {
    for (int h = 0; h<grid; h++) {
      zs[w][h] = 0.0;
    }
  }
  gridWidth = width/float(grid);

  //player = minim.loadFile("SHINICHI OSAWA  LOVE WILL GUIDE YOU feat. TOMMIE SUNSHINE.mp3");
  //player.play();
}

void draw() {
  lights();

//  fft.forward(in.mix);
  fft.forward(player.mix);

  for (int w=grid-1; w>=0; w--) {
    for (int h = grid - 1; h >= 0; h--) {
      if (h == 0) {
        zs[w][h] = fft.getBand(w) * 3;
      } else {
        zs[w][h] = zs[w][h - 1];
      }
    }
  }  

  background(0);
  translate(0, 0, -300);
  rotateX(PI/4.0);
  for (int w = 0; w < grid; w++) {
    for (int h = 0; h < grid; h++) {
      beginShape();

      vertex(w * gridWidth, h * gridWidth, zs[w][h]);
      vertex((w + 1) * gridWidth, h * gridWidth, zs[w + 1][h]);
      vertex((w + 1) * gridWidth, (h + 1) * gridWidth, zs[w + 1][h + 1]);      
      vertex(w * gridWidth, (h + 1) * gridWidth, zs[w][h + 1]);      
      endShape(CLOSE);
    }
  }
}