質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

89.05%

Unity ライトを使用しないで、奥に行くほど暗くなるシェーダ

解決済

回答 1

投稿 編集

  • 評価
  • クリップ 0
  • VIEW 1,025

yaman

score 7

前提・実現したいこと

unityシェーダーで「ライトを使用しないで奥に行くほど暗くなるシェーダ」を作成しています。
現状、Unlitで「Texture」は出来たのですが、Unlitで「Cutout」と「Transparent」の対応がしたいのですが
出来ておりません。
(シェーダー初心者なので、お力をお借りしたく)

Unlitで「Texture」の自作シェーダー → (自分では出来ていると思っている…)

Shader "Custom/UnlitDepthShadow_Normal" 
{
    Properties
    {
        _MainTex ("Main Texture", 2D) = "white" {}
        _StartDepth ("カメラからの開始深度(小数)", Float) = 50.
        _EndDepth ("カメラからの終了深度(小数)", Float) = 100.
        _DepthColor ("深度カラー", Color) = (1,1,1,1)
    }

    SubShader
    {
        Pass
        {
            Tags { "RenderType"="Opaque" "Queue"="Geometry"}

            Lighting Off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float2 uv : TEXCOORD0;
                float4 projPos : TEXCOORD3;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;

                // World position
                float3 _worldPos = mul(unity_ObjectToWorld, v.vertex);
                // Clip position
                float4 _pos = mul(UNITY_MATRIX_VP, float4(_worldPos, 1.));
                // Screen position
                o.projPos = ComputeScreenPos(_pos);

                return o;
            }

            sampler2D _MainTex;
            float _StartDepth;
            float _EndDepth;
            fixed4 _DepthColor;
            sampler2D _CameraDepthTexture;    // Depth texture

            fixed4 frag(v2f i) : SV_Target
            {   
                fixed4 c = tex2D(_MainTex, i.uv);

                // カメラからの距離
                float sceneZ = LinearEyeDepth(SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, UNITY_PROJ_COORD(i.projPos)));

                if( _StartDepth <= sceneZ )
                {
                    fixed4 c2 = tex2D(_MainTex, i.uv) * _DepthColor;
                    ////float _z = clamp(sceneZ,_StartDepth,_EndDepth );
                    float _per = (sceneZ - _StartDepth) / (_EndDepth - _StartDepth);    // 奥に行くほど1.0になる
                    c.rgb = lerp(c.rgb, c2.rgb, _per);
                }

                return c;
            }

            ENDCG
        }
    }

    FallBack "Diffuse"
}

> 結果(成功)

![イメージ説明](bd009cb29046d09a68ec87378af57956.png)

↓↓↓↓↓ 以下失敗の様子 ↓↓↓↓↓

Unlitで「Transparent」の自作シェーダー

上手くDepth値が取得出来ていないのか、または、その他設定が悪いのか、見当がつかない状態です。
自分なりに調べてコード書いてみたのですがうまく行かず。

Shader "Custom/UnlitDepthShadow_Transparent" 
{
    Properties
    {
        _MainTex ("Main Texture", 2D) = "white" {}
        _StartDepth ("カメラからの開始深度(小数)", Float) = 50.
        _EndDepth ("カメラからの終了深度(小数)", Float) = 100.
        _DepthColor ("深度カラー", Color) = (1,1,1,1)
    }

    SubShader
    {    
        Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}

        Pass
        {    

            Lighting Off
            ZWrite Off
            ZTest LEqual
            Blend SrcAlpha OneMinusSrcAlpha

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float2 uv : TEXCOORD0;
                float4 projPos : TEXCOORD3;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;

                // World position
                float3 _worldPos = mul(unity_ObjectToWorld, v.vertex);
                // Clip position
                float4 _pos = mul(UNITY_MATRIX_VP, float4(_worldPos, 1.));
                // Screen position
                o.projPos = ComputeScreenPos(_pos);

                return o;
            }

            sampler2D _MainTex;
            float _StartDepth;
            float _EndDepth;
            fixed4 _DepthColor;
            sampler2D _CameraDepthTexture;    // Depth texture

            fixed4 frag(v2f i) : SV_Target
            {   
                fixed4 c = tex2D(_MainTex, i.uv);

                // カメラからの距離
                float sceneZ = LinearEyeDepth(SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, UNITY_PROJ_COORD(i.projPos)));
                ////float partZ = i.projPos.z;

                if( _StartDepth <= sceneZ )
                {
                    fixed4 c2 = tex2D(_MainTex, i.uv) * _DepthColor;
                    float _per = (sceneZ - _StartDepth) / (_EndDepth - _StartDepth);    // 奥に行くほど1.0になる
                    c.rgb = lerp(c.rgb, c2.rgb, _per);

                }

                return c;
            }

            ENDCG
        }
    }

    FallBack "Diffuse"
}

> 結果

イメージ説明

実現したい事

以下写真右の様に、「Transparent」または「Cutout」でも、奥に行くほど色(影)を付けたいのです。
ご教授お願い致します。

イメージ説明

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 過去に投稿した質問と同じ内容の質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 1

checkベストアンサー

+1

Transparentなマテリアルは通常はデプスバッファへの書き込みを行わないので、デプステクスチャからsceneZを求めようとしてもうまくいかなかったのではないかと思います。今回のような場合では、デプステクスチャを使わずとも座標をビュー座標系に変換してやるだけでいいのではないでしょうか?

Shader "Custom/UnlitDepthShadow_Transparent" 
{
    Properties
    {
        _MainTex ("Main Texture", 2D) = "white" {}
        _StartDepth ("カメラからの開始深度(小数)", Float) = 50.
        _EndDepth ("カメラからの終了深度(小数)", Float) = 100.
        _DepthColor ("深度カラー", Color) = (1,1,1,1)
    }

    SubShader
    {    
        Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}

        Pass
        {    

            Lighting Off
            ZWrite Off
            ZTest LEqual
            Blend SrcAlpha OneMinusSrcAlpha

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float2 uv : TEXCOORD0;

                // projPosはやめて、カメラから見た座標を使うことにする
                float sceneZ : TEXCOORD3;
                // float4 projPos : TEXCOORD3;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;

                // ビュー座標系はZが反転しているそうなので、正負反転して奥ほど大きな値になるようにする
                o.sceneZ = -UnityObjectToViewPos(v.vertex).z;

                /*
                // World position
                float3 _worldPos = mul(unity_ObjectToWorld, v.vertex);
                // Clip position
                float4 _pos = mul(UNITY_MATRIX_VP, float4(_worldPos, 1.));
                // Screen position
                o.projPos = ComputeScreenPos(_pos);
                */

                return o;
            }

            sampler2D _MainTex;
            float _StartDepth;
            float _EndDepth;
            fixed4 _DepthColor;

            // デプステクスチャも使わない
            // sampler2D _CameraDepthTexture;    // Depth texture

            fixed4 frag(v2f i) : SV_Target
            {   
                fixed4 c = tex2D(_MainTex, i.uv);

                // カメラからの距離
                // sceneZはやめて、以下ではsceneZに代わってi.sceneZを使う
                // float sceneZ = LinearEyeDepth(SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, UNITY_PROJ_COORD(i.projPos)));
                ////float partZ = i.projPos.z;

                if( _StartDepth <= i.sceneZ )
                {
                    // tex2D(_MainTex, i.uv)で得られる色は上で取得したcと同じはずなので、再度サンプリングする必要はないのではないでしょうか?
                    // fixed4 c2 = tex2D(_MainTex, i.uv) * _DepthColor;
                    fixed4 c2 = c * _DepthColor;
                    float _per = (i.sceneZ - _StartDepth) / (_EndDepth - _StartDepth);    // 奥に行くほど1.0になる
                    c.rgb = lerp(c.rgb, c2.rgb, _per);
                }

                return c;
            }

            ENDCG
        }
    }

    FallBack "Diffuse"
}

投稿

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2019/02/27 04:16

    お返事ありがとうございます。
    早速、入れ込んでみましたが、期待通りの表示になりました。
    ホントに有難う御座いました!

    // tex2D(_MainTex, i.uv)で得られる色は上で取得したcと同じはずなので、再度サンプリングする必要はないのではないでしょうか?
    「Transparent」も含め、上記も修正させて頂きました。

    キャンセル

15分調べてもわからないことは、teratailで質問しよう!

  • ただいまの回答率 89.05%
  • 質問をまとめることで、思考を整理して素早く解決
  • テンプレート機能で、簡単に質問をまとめられる

関連した質問

同じタグがついた質問を見る