outlook VBAを使用した最新メールの添付ファイルを特定のフォルダへ取り込む方法

Question

OUTLOOKで使用するVBA を使うのはほぼ初めての為、
https://tonari-it.com/outlook-vba-mail-attachment-saveasfile/
https://tonari-it.com/outlook-vba-subfolder-mail-attachmentfile/
を殆ど引用という形で
フォルダ内(あさ)の最新受信1件の添付ファイルを対象(C:\保存フォルダ) へ保存できるようにしようとしています。

素人目で Set objItem = が　フォルダ内最新を選択できれば動くように感じるますが、このままだと

For Each objAttachment In .Attachments

でエラーが出てしまいます。
修正方法を教えていただきたいです。

ここからコード

Sub SaveAttachmentFile()
Dim objItem As Object
Dim objIns As Inspector
Dim strFile As String
Dim strPath As String
Dim objAttachment As Object
 
Set objIns = Application.ActiveInspector
Set myNamespace = GetNamespace("MAPI")
Set myInbox = myNamespace.GetDefaultFolder(olFolderInbox)
Set objItem = myInbox.Folders.Item("あさ")
 
strPath = "C:\保存フォルダ\"
 
With objItem
 
    For Each objAttachment In .Attachments
        strFile = strPath & objAttachment
        objAttachment.SaveAsFile strFile
    Next objAttachment
End With
 
End Sub

Answer 1

エラーが出たのであれば、そのメッセージを質問に記載した方が、回答もしやすい場合がありますね。

VBAの場合、エラーのダイアログの「デバッグ」を押して、イミディエイトウィンドウで?Err.Descriptionとすることで取得できます。

---

参考：エラー原因の追い方（一例）

今回問題となったエラーはおそらく、
オブジェクトは、このプロパティまたはメソッドをサポートしていません。
だと思われます。
このエラーは、そのオブジェクトに該当するプロパティなどがない場合に発生します。

エラー発生箇所を見るに、objItemのAttachmentsが取得できないと予測できます。
また、objItemの取得方法を確認するとmyInbox.Folders.Item("あさ")となっており、FoldersのItem、つまりメールなどではなくフォルダーを取得している雰囲気があります。

objItemの中身が怪しい、ということで、変数の中身を確認してみます。

実際に変数に入っているものを確認したい場合は「ローカルウィンドウ」を使うのが便利です。
ローカルウィンドウを表示しておくと、プロシージャ実行中に変数の一覧以下のように表示され、型や中身などを簡単に確認できます。

こちらを見ると、objItemの中身がMAPIFolder（これは内部用のオブジェクトと思われるので、宣言に使える型としてはOutlook.Folder）であることがわかります。

という事で、今回の問題の原因は、Set objItem = が、フォルダ内最新のアイテムではなく、その一歩手間のフォルダ取得で終わっていたことだとわかりました。

コード

以上を踏まえてざっくり整理・追記を行うと以下のような感じでしょうか。

Private Sub SaveAttachmentFile2()
'https://teratail.com/questions/173960
    
    Dim myNamespace As Outlook.NameSpace
    Set myNamespace = Outlook.Application.Session
    
    '受信トレイの中の「あさ」フォルダを取得する
    Dim myInbox As Outlook.Folder
    Set myInbox = myNamespace.GetDefaultFolder(olFolderInbox)
    
    Dim childFolder As Outlook.Folder
    Set childFolder = myInbox.Folders.Item("あさ")
    
     
    '見つかったフォルダで一番最後に追加されたもの（≒おそらく最新）を取得する
    Dim objItem As Outlook.MailItem '他の種類のものの可能性もあるので、Objectの方が無難かも
    Set objItem = childFolder.Items.GetLast()
    
    
'    '以下は必要に応じて
'    With childFolder.Items
'        .Sort "ReceivedTime", True '受け取った日時で降順（新しいもの順）にソートする
'        Set objItem = .GetFirst() '最初=一番新しいものを取得
'    End With
    
    Dim strPath As String
    strPath = "C:\保存フォルダ\"
    
    Dim objAttachment As Outlook.Attachment
    For Each objAttachment In objItem.Attachments
        Dim strFile As String
        strFile = strPath & objAttachment.FileName
        objAttachment.SaveAsFile strFile
    Next objAttachment

End Sub

Comments

[ocome85]

正しく動く事は確認しましたが、他の追い方等全て確認させていただきます。

ローカルウィンドウは初めて知りました。
そこらの機能も一度調べる必要がありそうです :)
ありがとうございました。