VBA n番目のカンマの位置で文字列を区切りたい

Question

"栃木",85,"山田","1","ﾄﾁｷﾞ,ﾅﾝﾌﾞ",2,"ﾅﾝﾌﾞ,5",5
のようなデータがあったとき、特定のカンマの位置で文字列を区切りたいです。

上記の例でいくと、4番目のカンマの位置（"ﾄﾁｷﾞ,ﾅﾝﾌﾞ"の前）で区切りたいです。
なにかいい方法はありましたら教えて頂きたいです。

Answer 1

関数にしてみました。
バリアント型配列を返すようにしました。
句切り文字（Delimiter）引数は省略可能（省略した場合はカンマ）

Public Function SplitStringNum(src As String, SplitPos As Long, _ 
                  Optional Delimiter As String = ",") As Variant
    Dim pos As Long, i As Long
    pos = 0
    For i = 1 To SplitPos
        pos = InStr(pos + 1, src, Delimiter)
        If pos < 1 Then
            pos = Len(src) + 1
            Exit For
        End If
    Next
    SplitStringNum = Array(Left$(src, pos - 1), Mid$(src, pos + Len(Delimiter)))
End Function

Sub test()
    Dim s As string
    Dim a As Variant
    s = """栃木"",85,""山田"",""1"",""ﾄﾁｷﾞ,ﾅﾝﾌﾞ"",2,""ﾅﾝﾌﾞ,5"",5"
    a = SplitStringNum(s, 5)
    Debug.Print a(0)
    Debug.Print a(1)
End Sub

ただ、csvフォーマットだとしたら、""で囲まれたカンマは無視しないとダメなのだが、それは仕様不明なので無視しました。

Comments

[退会済みユーザー]

ご回答ありがとうございます！また、わざわざコードをご提示頂きありがとうございます…
今回は他の方の回答で解決できたのですが、類似の場面で参考にさせて頂きます！

Answer 2

方法はいくつかあって回答もあがってますが、私からは正規表現を使った例で回答します。

Dim s As String
Dim RE, strPattern As String, r As Range

s = """栃木"",85,""山田"",""1"",""ﾄﾁｷﾞ,ﾅﾝﾌﾞ"",2,""ﾅﾝﾌﾞ,5"",5"

Set RE = CreateObject("VBScript.RegExp")
With RE
    .Pattern = "(.*,.*,.*),(.*,.*,.*,.*,.*,.*)"
    .Global = True
    Set reMatch = .Execute(s)
    Debug.Print reMatch(0).SubMatches(0)
    Debug.Print reMatch(0).SubMatches(1)
End With
Set RE = Nothing

あ、この方法だと「ｎ番目」という動的な対応は難しいですね。

Answer 3

Split(some, ",")で配列にして、Forで0からn-1までまわして、","で連結していく。

だと思いますが、nとUBoundの比較を考えないと,が2つしかないのにnが4とかだとエラーになっちゃいます

Answer 4

InStrを使うと、指定した場所から探し始めて、最初に探す対象文字がある位置を得られます。

    Dim sample As String
    sample = "1,2,3,4,5"
    
    Dim firstPos As Long
    
    ' 1文字目から sampleを探し、"," の位置を返す
    firstPos = InStr(1, sample, ",")
    
    MsgBox (firstPos)   ' 「2」が表示されます

これを指定回数繰り返し、最初の引数を前回見つけた位置の次の文字として「1番目のカンマ、2番目のカンマ……」と探していけばn番目のカンマを探す関数を作れます。そうすれば、n番目のカンマの位置を特定できるので、そこで文字列をカットすればOKですね。
試して見てください。

（実際のプログラムは自力でやってみてください）

Comments

[退会済みユーザー]

ご回答ありがとうございます！
この方法で、一度分割するところまで作ってみます！

[backyard]

papinianusさんのやり方だとsplitを使いますが、私が書いた方法だとsplitは使いません。

下記のような感じでmid関数を使って指定した場所から長さを指定して文字を切り出せばOKかと思います。

------

Dim sample As String
sample = "1,2,3,4,5"

' 4番目のカンマは8文字目、ということが判明した場合
resultstr1 = Mid(sample, 1, 8)
resultstr2 = Mid(sample, 8 + 1, Len(sample) - 8)

MsgBox resultstr1 & " | " & resultstr2

[退会済みユーザー]

すみません、コメントを編集しているうちにご回答頂いていたようで…
わざわざありがとうございます！

先ほどの位置を探す部分をループ処理にし、教えて頂いた方法も含めてやってみようと思います。