【VB.ＮＥＴ】様々な日付形式の文字列に、その日付形式に対応した「時間と分」（例00時00分）を追加して出力したいです。

Question

お世話になります。

まず結論から言って、下記の"2019年01月01日 18時28分"の形式の表示にしたいです。

Dim stLastExecDate as string = "2019年01月01日 18時28分"

上記形式にしたいのは、下記文字列の４パターンです。

1. 2019年01月01日
2. 2012/2/1
3. 1-Feb-12
4. 2012-02-01

つまり、どのパターンで入力しても、（日付は何日でもよい）
正規表現でいうと、
"\d{4}年\d\d月\d\d日\s\d\d時\d\d分"
の形式にOutPutされれば問題ないです。

今の現状として、
エクセルのB2セルに
stLastExecDate　となる　値、"2019年01月01日 18時28分"が入力されています。

これをVisualStudioでもいいのですが、
上記１～４の時間部分を除く日付までの入力で、あとは自動で"00時00分"が
加わればよいです。
１から４は日付の形式が米国のものもあるので、時間は米国に合わせます。

String.Containsで("-")や("/")などが含まれているとき別に、
条件分岐をして
String.replace()もしくはString.insert()などを使用すれば実装できるかなと思っていますが、

正規表現を使えばもっと簡単にできるよというのがあれば、知りたくてご質問いたしました。

Imports System
Imports System.Text.RegularExpressions

Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim stLastExecDate As String = "2081年01月03日 18時00分"
        Dim stTestStr As String = "2000-01-03"
        'Dim result As Boolean = Regex.IsMatch(stLastExecDate, "\d{4}年\d{2}月\d\d日\s\d\d時\d\d分")
        'Dim test As Boolean = Regex.IsMatch(stTestStr, "\d{4}.\d\d.\d\d")
        'Console.WriteLine(result)
        'Console.WriteLine(test)
        'stTestStr.Insert(10, "8")
        Console.WriteLine(stTestStr + " 00時00分")
   End Sub
End Class

上記は、このような感じでできるかなと思って記載しています。
何かご不明な点がありましたら、ご質問ください。

ご教示よろしくお願いいたします。

Answer 1

下記にて提示されたフォーマットの変換はできます。
但し、指定されたフォーマット以外でも変換できます。（1-Feb-2012等）

Dim teststring As String() = {"2019年01月01日", "2012/2/1", "1-Feb-12", "2012-02-01"}
Dim OutputDate As DateTime

Dim ci As New Globalization.CultureInfo("en-US")

For Each test In teststring
    If DateTime.TryParse(test, ci, Globalization.DateTimeStyles.NoCurrentDateDefault, OutputDate) Then
        Console.WriteLine($"{test} = {OutputDate:yyyy年MM月dd日 HH時mm分}")
    End If
Next

厳密に行いたいのであれば、DateTime.TryParseExactメソッドを使用して

Dim Formats As String() = {"yyyy年MM月dd日", "yyyy/M/d", "d-MMM-yy", "yyyy-MM-dd"}

If DateTime.TryParseExact(test, Formats , Globalization.DateTimeFormatInfo.InvariantInfo,Globalization.DateTimeStyles.None, OutputDate) Then
    Console.WriteLine($"{test} = {OutputDate:yyyy年MM月dd日 HH時mm分}")
End If

とすればどうでしょうか

Comments

[rara]

早速のご回答ありがとうございます。
こちらでも試してみました！
自分が求めていたのは、まさにこういう感じでした。
ただ、僕の言葉が足りなかったのですが、

Dim stLastExecDate As String() = {"20000102", "2009年01月07日", "2012/2/1", "1-Feb-12", "2012-02-01"}
Dim Formats As String() = {"yyyyMMdd", "yyyy年MM月dd日", "yyyy/M/d", "d-MMM-yy", "yyyy-MM-dd"}
Dim OutputDate As DateTime
Dim ci As New Globalization.CultureInfo("en-US")

For Each dtmDate In stLastExecDate
If DateTime.TryParseExact(dtmDate, Formats, Globalization.DateTimeFormatInfo.InvariantInfo, Globalization.DateTimeStyles.None, OutputDate) Then
Console.WriteLine($"{dtmDate} = {OutputDate:yyyy年MM月dd日 HH時mm分}")
End If

Next

上記コードでいう、１行目の配列でループをされていたのですが、
Dim stLastExecDate As String() = {"20000102", "2009年01月07日", "2012/2/1", "1-Feb-12", "2012-02-01"}
実際には、エクセルを初期パラメータとして読み込み、stLastExecDateに値を代入しています。
そのため、配列ではなくて実際にstLastExecDateの変数に入る値は一つでString型になります。

このString型の変数に、
下記の
Dim Formats As String() = {"yyyyMMdd", "yyyy年MM月dd日", "yyyy/M/d", "d-MMM-yy", "yyyy-MM-dd"}
FormatsのString型の配列のどの形式が入力されても、最終的に
yyyy年MM月dd日 hh時ｍｍ分の形式で、その値をString型変数に代入できればよいので、
ご回答いただきました内容で、ほぼ出力内容は完璧なのですが、
配列ではなくて、一つの変数に最終的に代入させたいです。
勉強不足なところがあり、申し訳ございません。

お手数おかけいたしますが、
ご教示いただけますと幸いです。

お忙しい中、お返事いただきありがとうございます。

[YAmaGNZ]

ループにしたのは、あくまで提示された例を全部変換かけようと用意しただけです。
本質はループの中身だけです。
リンクを張ったTryParseExactメソッドのページを見ていただければ分かるかと思いますが、TryParseExactメソッドの第一引数は変換させる文字列です。
ですので、この部分に変換したい文字列が格納されている変数を指定すればよろしいかと

[rara]

ありがとうございます。

Dim stLastExecDate As String = "2019-01-14"
Dim Formats As String() = {"yyyyMMdd", "yyyy年MM月dd日", "yyyy/M/d", "d-MMM-y", "yyyy-MM-dd", "dd/MM/yyyy", "yy/MM/dd", "yy-MM-dd", "yy年MM月dd日"}
Dim ci As New System.Globalization.CultureInfo("en-US")
Dim OutputDate As DateTime
Dim OutputExecDate As String

If DateTime.TryParseExact(stLastExecDate, Formats, System.Globalization.DateTimeFormatInfo.InvariantInfo, System.Globalization.DateTimeStyles.None, OutputDate) Then
OutputExecDate = $"{OutputDate:yyyy年MM月dd日 HH時mm分}"
Console.WriteLine(OutputExecDate)
End If

上記コードのような形にして、
期待通りの結果が得られました。

あとは、FormatsのPatternをこちらで制限して、
入力形式をある程度絞ります。

ありがとうございます。大変助かりました！

[YAmaGNZ]

CultureInfoはTryParseの時に必要だったので書いてあります。
TryParseExactではDateTimeFormatInfo.InvariantInfoを指定しているので、CultureInfo("en-US")は必要ありません。

[rara]

はい、そこは実際のコードを記載時、
コードを再度入力していたとき("en-US")のところは、TryParseの時に引数で使用していたけど、
TryParseExactでは使用してないと気づきました。

丁寧にご指摘ありがとうございます。