日付への変換の仕方を教えてください。

Question

８桁の数字を入力し２０００～２０５０年までの日付変更可能な場合、yyyy/mm/ddを表示させたいです。
このままだとテキストボックス１７になにも表示されません。
原因と解決法を教えていただけないでしょうか。

    Private Sub Button6_Click(sender As Object, e As EventArgs) Handles Button6.Click

        Dim text16 As String = TextBox16.Text
        Dim result As String = ""
        Dim number As Integer = 0

        number = CInt(text16)

        If number >= 19900101 AndAlso number <= 20301231 Then
            If IsDate(TextBox16.Text) Then
                result = CType(Date.Parse(Format(CInt(TextBox16.Text), "0000/00/00")), String)
            End If

        End If

            TextBox17.Text = result

    End Sub

Answer 1

原因：
「8桁の数字がyyyymmdd形式の日付になるかどうか」は IsDate 関数では判定できないからです。

解決方法：
y_waiwai さんの回答にあるように割り算の商と余りを使って解釈するか、TextBox に入力された文字列を適当に区切って扱うか、どちらかかと思います。

入力された文字列を適当に区切る例：

Dim text16 As String = TextBox16.Text
Dim result As String = ""

' 入力された文字列が8文字の場合だけ処理する
If text16.Length = 8 Then
	' 「年」部分（左4桁）
	Dim yearPart = text16.Substring(0, 4)
	' 「月」部分（中2桁）
	Dim monthPart = text16.Substring(4, 2)
	' 「日」部分（右2桁）
	Dim dayPart = text16.Substring(6, 2)
	' 上記3つのパーツを連結して、yyyy/MM/dd 形式っぽくする
	Dim dateText = yearPart & "/" & monthPart & "/" & dayPart
	' 3つを連結した文字列が日付として解釈可能な場合だけ処理する
	If IsDate(dateText) Then
		' 3つを連結した文字列を日付に変換する
		Dim resultDate = Date.Parse(dateText)
		' 変換結果の日付の年部分が2000以上2050以下の場合だけ処理する
		If 2000 <= resultDate.Year AndAlso resultDate.Year <= 2050
			' 変換結果の日付を yyyy/MM/dd 形式の文字列に変換する
			result = resultDate.ToString("yyyy/MM/dd")
		End If
	End If
End If

TextBox17.Text = result

Comments

[tsugfuxr-hdudhd]

丁寧な回答ありがとうございました。

Answer 2

すでにベストアンサーは決まっていますが別解として。

入力する文字列の形式が決まっているのであれば、DateTime.TryParseExactなどを使う手もあります。

Private Sub Button6_Click(sender As Object, e As EventArgs) Handles Button6.Click
    Dim text16 As String = TextBox16.Text

    Const AllowFormat = "yyyyMMdd"
    Dim jpCulture As New System.Globalization.CultureInfo("ja-JP")
    Dim dateTimeStyle = System.Globalization.DateTimeStyles.None

    Dim resultDate As System.DateTime
    If System.DateTime.TryParseExact(text16, AllowFormat, jpCulture.DateTimeFormat, dateTimeStyle, resultDate) Then
        If #2000/1/1# <= resultDate AndAlso resultDate < #2051/1/1# Then
            TextBox17.Text = resultDate.ToString("yyyy/MM/dd")
        Else
            MessageBox.Show("日付が指定範囲外です。" & resultDate.ToString())
        End If
    Else
        MessageBox.Show("日付に変換できません。")
    End If

End Sub

Comments

[tsugfuxr-hdudhd]

勉強になります。
ありがとうございました。

Answer 3

IsDateは日付に変換可能な書式かどうかを判定するものですから、単に日付の範囲として有効なのかを確認したい場合には、最低限日付の書式となっている必要があります。

 If IsDate(Format(CInt(TextBox16.Text), "0000/00/00")) Then

Answer 4

入力した文字列を数値に変換して、

10000で割ったら西暦が出て、
100で割って100の余りを出せば月が出て、
そのまま100の余りを出せば日が出ますね