VBScriptでアプリケーションのバージョン情報を取得したい

Question

前提・実現したいこと

インストールされているアプリケーションの一覧を取得したいです。
その時にアプリケーション名とバージョン情報を取得したいと思っています。

試したこと

「プログラムと機能」からインストールされているアプリケーションの一覧を取得する
を参考にしてアプリケーション名の一覧が取得できることはわかりました。

Option Explicit
 
Dim itm
 
With CreateObject("Shell.Application").Namespace("shell:::{7b81be6a-ce2b-4676-a29e-eb907a5126c5}")
  For Each itm In .Items
    WScript.Echo itm.Name
  Next
End With

そこでできれば

Option Explicit
 
Dim itm
 
With CreateObject("Shell.Application").Namespace("shell:::{7b81be6a-ce2b-4676-a29e-eb907a5126c5}")
  For Each itm In .Items
    WScript.Echo itm.Name
　  WScript.Echo ":"
    WScript.Echo itm.Version
  Next
End With

のようにバージョン情報も取得できないかなと思ったのですが
これについては

オブジェクトでサポートされていないメソッドです："Version"

というエラーメッセージが表示されてしまったので調べたところ
FolderItemオブジェクト
FolderItemオブジェクトの中にはバージョン情報を表示するようなものはないようでした。

しかし、Windowsの『アプリと機能』を見るとアプリケーション名をクリックすればバージョン情報が表示されるので、何とか取れるのではないかと期待しています。

どなたかご存知の方がいらっしゃったら教えてください。

補足情報（FW/ツールのバージョンなど）

Windows
VBScript

Answer 1

.Namespaceメソッドで取得しているShell32.FolderにはGetDetailsOfというメソッドがあります。

FolderItemと番号を指定してファイルの追加情報を取得するものですが、今回の場合にも応用できるようです。

私の手元では番号として4を指定するとバージョンらしき文字列を取得できました。

Private Sub PrintApplicationInfo()
    
    'Shell32 = Microsoft Shell Controls And Automation
    Dim appShell 'As Shell32.Shell
    Set appShell = CreateObject("Shell.Application")
    
    Dim shellFolder 'As Shell32.Folder3
    Set shellFolder = appShell.Namespace("shell:::{7b81be6a-ce2b-4676-a29e-eb907a5126c5}")
    
    Const VersionColumnNo = 4
    
    Dim itm 'As Shell32.FolderItem
    For Each itm In shellFolder.Items()
        Dim ver 'As String
        ver = shellFolder.GetDetailsOf(itm, VersionColumnNo)
        WSH.Echo itm.Name, ver
        
        If False Then
            'バージョン（VersionColumnNo）の番号確認用
            Dim buf 'As String
            Dim i 'As Long
            For i = 1 To 1000 '適当
                buf = shellFolder.GetDetailsOf(itm, i)
                If buf <> "" Then WSH.Echo i, buf
            Next 'i
            Exit For
        End If
        
    Next 'itm
    
End Sub

Comments

[moshi]

タイムスタンプも取得できるのではないかと思い、GetDetailsOfを調べてみたところ
https://docs.microsoft.com/ja-jp/windows/desktop/shell/folder-getdetailsof
GetDetailsOfの第2引数に3を指定すればいいのではないかと思い、実行してみたところサイズが表示されてしまいました。
0～4を指定したところ2だけがエラーとなってしまいました。
しかしタイムスタンプは他のでは出なかったので2を指定するとタイムスタンプが出るはずなのではないかと考えています。
もしわかったらタイムスタンプの取得の仕方も教えていただけるとありがたいです。

[moshi]

すみません。元の質問からずれてしまいますね。
別の質問としてたてなおしました。もしお時間があれば見てみてください。
https://teratail.com/questions/158044
回答ありがとうございました。おかげさまで当初の目的は果たせました！

Answer 2

FileSystemObject オブジェクトのGetFileVersion メソッドで取得できます。
ただし製品バージョンを持っていない実行ファイルもありますが、その場合は取得できません（空文字が返る）

参考：(WSH)VBScriptでバイナリファイルのバージョンを取得したい

path = "c:\windows\explorer.exe"
Set fso = CreateObject("Scripting.FileSystemObject")
ver = fso.GetFileVersion(path)
WScript.Echo "path[" & path & "] FileVersion[" & ver &"]"
' path[c:\windows\explorer.exe] FileVersion[10.0.17134.165]

Comments

[moshi]

なるほどFileSystemObjectというものがあるのですねー
しかし
「pathspec
必ず指定します。指定したファイルの絶対パスまたは相対パスです。」
とあるので、exeのパスがわかないと使うことができないのですね…

どうにか取得したプログラムのパスを取得して、そこを指定してこのオブジェクトを使用するしかないのですかね…