Excel VBAでWord文章から検索語のある段落の前後まで抽出したい

Question

Microsoft Excel/Word Version 2013-2016

フォルダの中にあるWordファイルの中から特定の文字列を探し出し、前後の範囲を広げて抽出した文字列をExcelに出力したいのですが、

objSelection.Paragraphs.first.Range.Text

とすると欲しい範囲までとれません、
行数やページ単位で取得する方法は分かったのですが、チルダが付いた変なファイルを読み込んだ時などにエラーが発生すると致命的な問題が起きることがあるため用いたくありません。

文字列取得範囲を広げて指定する良い方法はないでしょうか?
よろしくお願いします。

Sub DocParagraphGet()
'参考　https://technet.microsoft.com/ja-jp/library/ee692875.aspx

  Dim wdApp As Object  ' Word.Application
  Dim wDoc As Object 'Word.Document
  Dim objFso As Object
  Dim objFolder As Object
  Dim objSelection As Object
  Dim sBookName As String '出力ブック名
  Dim objWb As Workbook
  Dim sOrgPath As String, sRetPath As String, sKeyWord As String
  Dim iParagNum '段落数
  
  
  Set wdApp = CreateObject("Word.Application")
  wdApp.Application.Visible = True '可視化　表示しなければ特に必要なし

  sOrgPath = ThisWorkbook.Sheets("フォーム").Range("B13") & "\"
  sRetPath = ThisWorkbook.Sheets("フォーム").Range("B14") & "\"
  iParagNum = ThisWorkbook.Sheets("フォーム").Range("B15")
  sKeyWord = "規格"
  sBookName = Format(Now, "yymmddhhmm") & "_Wordからの出力" & ".xlsx"
   
  Set objFso = CreateObject("Scripting.FileSystemObject")
  Set objFolder = objFso.GetFolder(sOrgPath)
  Set objWb = Workbooks.Add
  objWb.SaveAs (sRetPath & sBookName)

  objWb.Sheets.Add Before:=Sheets(1)
  r = 0
  For Each f In objFolder.Files
    
    sxx = Right(f.Name, 5)
    If 0 < InStr(sxx, ".doc") Then
      r = r + 1
      objWb.Sheets(1).Cells(r, 1) = f.Name
      Set wDoc = wdApp.documents.Open(sOrgPath & "\" & f.Name, True) '読み取りモードで開く
      Set objSelection = wdApp.Selection
      objSelection.Find.Text = sKeyWord
      objSelection.Find.Forward = True
      If objSelection.Find.Execute Then
        r = r + 1
        objWb.Sheets(1).Cells(r, 2) = objSelection.Paragraphs.first.Range.Text
      Else
        objWb.Sheets(1).Cells(r, 2) = "なし"
      End If
      wdApp.documents.Close
    End If  

   Next f
  
Set objFso = Nothing
Set objFolder = Nothing
Set wdApp = Nothing
  
  
End Sub

Answer 1

「チルダが付いた変なファイル」の話は出ているので、範囲の拡張の話を。

選択範囲の属する段落+前後の1行まで選択範囲を拡張するサンプルです。
MoveStart/MoveEndメソッドを使用することで元の範囲の開始/終了位置を動かしています。

Selection.MoveStart メソッド (Word)

Selection.MoveEnd メソッド (Word)

どの程度範囲を広げれば良いのかわからなかったので、expandCount・expandUnitを適当に調整してください。

'検索後の状態を想定（検索文字列選択状態）
With objSelection
    '選択範囲を段落まで拡張
    'Const wdParagraph = 4
    .Expand wdParagraph
    
    
    '前後に範囲を拡張（例:前後に1行ずつ拡張）
    Const expandCount = 1
    'Const wdLine = 5
    Dim expandUnit As Word.WdUnits
    expandUnit = wdLine
    
    '選択開始位置・終了位置をずらす
    .MoveStart expandUnit, -expandCount
    .MoveEnd expandUnit, expandCount
    
    'Debug.Print .Text
End With 'objSelection

Comments

[s.kono]

回答ありがとうございます。
なぜか
Dim expandUnit As Word.WdUnits
の部分で「ユーザー定義型が定義されていません」とエラーとなります
とりあえず次のコードで欲しいものが取得できました。
Wordのプロパティと定数の意味が良く分からなくて苦労しています。
参照の問題でしょうか? 参照でDLL読み込みエラーが出てしまい参照設定は出来ていません

With objSelection

Const wdLine = 5
.MoveEnd Unit:=wdLine, Count:=2
objWb.Sheets(1).Cells(r, 2) = .Text

End With 'objSelection

[imihito]

`Word.WdUnits`はWordのタイプライブラリ内で定義されている列挙型なので、参照設定が無いとエラーになりますね。
書き忘れていました、すみません。

参照設定が上手くいかない状況、というのはあまり経験がありませんが、Officeのインストールがどこか失敗しているのだと思います。

もしWord側のVBEが動くなら、Word操作部分はそちらで作った上で、型宣言を省く・定数/列挙型を値にしてExcelに移植、というのも手かもしれません。

[s.kono]

参照設定のエラーは社内の担当に投げてみます。Word VBAの概念を知ることが出来て助かりました。ありがとうございます。VBEもExcel側からはよく利用するのですがWordはめったに利用することがないので今度時間のある時に勉強してみます。無事欲しいものが取得できました。ありがとうございます。

Answer 2

チルダが付いた変なファイルを読み込んだ時などにエラーが発生すると致命的な問題が起きることがあるため用いたくありません。

とりあえずこの部分にのみ反応しますと、チルダが付いたファイルはWordが勝手に作成する作業用のファイルです。
なのでこのファイルを検索対象にするのは問題かと。
今のコードでチルダ以外のファイルは問題ないのであれば、チルダのファイルを除外すれば済むような気がします。
ま、問題が起きる起きないに関わらず除外は必須ですね。

If Left(f.Name, 1) <> "~" And 0 < InStr(sxx, ".doc") Then

Comments

[s.kono]

ありがとうございます。条件をかけたときになぜかひっかからなかったのです、今一度良く見てみます。

[s.kono]

ひっかかるようになりました、次にZIPフォルダのファイルに引っかかったり、これも除外しました、今は保護がかかっているファイルがあり、それをどうするか、、、フォルダの中は色々なのでもう「 On Error Resume Next」で飛ばしても良いのかと、、、

Answer 3

「チルダが付いた変なファイル」は、Excelのブックや、Wordの文書を開いている間に自動で作成される隠しファイルです。

ファイル名の頭に[~]が付いてるファイルは処理の対象外とすべきでしょう。

Comments

[s.kono]

はい、うまく除外できなくて除外方法を考え直して見ます。ありがとうございました。

[ExcelVBAer]

その「うまく除外できていない」コードを載せたら？

[s.kono]

出来ました! 隠しファィル表示でも見えないのでおかしくなっていたファイルがいたのかもしれません、親フォルダごと削除して除外をいれたらうまくいきました。正しく検証した結果をお知らせできなくてすみません。

[ExcelVBAer]

ひょっとしたら、システム用のファイルとして認識されているのかもしれませんね。

よくある事なのですが、たまにしかバグにならないので、自分も忘れやすいので
気を付けたいものです。

[s.kono]

コメントありがとうございます。いい経験になりました。